TaskbarEdge() : Returns the side of the monitor the taskbar is on

[SKAN]

Usage example: MsgBox % TaskbarEdge().
Returns one of these values: LTRB (Left, Top, Right, Bottom)
On a multi-monitor setup, you may use WinGetPos or MouseGetPos or SysGet to find X and Y and pass it to TaskbarEdge()
 

---

 
The function
 

Code: Select all

TaskbarEdge( X:=0, Y:=0 ) {                         ; by SKAN on D39F/D39F @ tiny.cc/taskbaredge
Local hMonitor:=VarSetCapacity(var,84,0),  v:=NumPut(40,var,"Int")-4
  hMonitor := DllCall("MonitorFromPoint", "Int64",(X & 0xFFFFFFFF) | (Y << 32), "Int",0, "UPtr")
  DllCall("GetMonitorInfo", "Ptr",hMonitor, "Ptr",v)
  DllCall("GetWindowRect", "Ptr",WinExist("ahk_class Shell_SecondaryTrayWnd"), "Ptr",v+68)
  DllCall("SubtractRect", "Ptr",v+52, "Ptr",v+4, "Ptr",v+68)
  DllCall("GetWindowRect", "Ptr",WinExist("ahk_class Shell_TrayWnd"), "Ptr",v+36)
  DllCall("SubtractRect", "Ptr",v+20, "Ptr",v+52, "Ptr",v+36)
Return NumGet(v+12,"Int")>NumGet(v+28,"Int") ? "R" : NumGet(v+16,"Int")>NumGet(v+32,"Int") ? "B"
  : NumGet(v+20,"Int")>NumGet(v+4,"Int") ? "L" : NumGet(v+24,"Int")>NumGet(v+8,"Int") ? "T" : ""
}

 

---

 
The following is a customized version for ShowMenu()
Call example: ShowMenu( MenuGetHandle("Tray"), False, TrayMenuParams()* )
 

TrayMenuParams()

Code: Select all

TrayMenuParams() {      ; Original function is TaskbarEdge() by SKAN @ tiny.cc/taskbaredge
Local    ; This modfied version to be passed as parameter to ShowMenu() @ tiny.cc/showmenu
  VarSetCapacity(var,84,0), v:=&var,   DllCall("GetCursorPos","Ptr",v+76)
  X:=NumGet(v+76,"Int"), Y:=NumGet(v+80,"Int"),  NumPut(40,v+0,"Int64")
  hMonitor := DllCall("MonitorFromPoint", "Int64",NumGet(v+76,"Int64"), "Int",0, "Ptr")
  DllCall("GetMonitorInfo", "Ptr",hMonitor, "Ptr",v)
  DllCall("GetWindowRect", "Ptr",WinExist("ahk_class Shell_SecondaryTrayWnd"), "Ptr",v+68)
  DllCall("SubtractRect", "Ptr",v+52, "Ptr",v+4, "Ptr",v+68)
  DllCall("GetWindowRect", "Ptr",WinExist("ahk_class Shell_TrayWnd"), "Ptr",v+36)
  DllCall("SubtractRect", "Ptr",v+20, "Ptr",v+52, "Ptr",v+36)
  Loop % (8, offset:=0)
    v%A_Index% := NumGet(v+0, offset+=4, "Int")
Return ( v3>v7 ? [v7, Y, 0x18] : v4>v8 ? [X, v8, 0x24]
       : v5>v1 ? [v5, Y, 0x10] : v6>v2 ? [X, v6, 0x04] : [0,0,0] )
}

[Delta Pythagorean]

Ah, perfect timing! I was working on a quick OSD program and needed to find the taskbar's edge. This'll be quite interesting to work with!

[SKAN]

@Delta Pythagorean

Thanks for the feedback

Some info:

The original RECT of the monitor is @ v+4
immediately followed by the
*Subtracted RECT of the monitor @ v+20

* RECT of the monitor minus RECT of the Taskbar.

You may replace the return line with following for better understanding.

Code: Select all

  Loop % (8, offset:=0)
    v%A_Index% := NumGet(v+0, offset+=4, "Int")
Return (v3>v7 ? "Right" : v4>v8 ? "Bottom" : v5>v1 ? "Left" : v6>v2 ? "Top" : "")