Como fazer o HOTKEY esperar a página carregar Topic is solved

Tire suas dúvidas sobre programação em AutoHotkey

Moderator: Gio

breno_mir
Posts: 1
Joined: 10 Jun 2020, 12:17

Como fazer o HOTKEY esperar a página carregar

10 Jun 2020, 12:27

Olá galera, sou novo no Hotkey e estou terminar uma automação aqui no pc, e preciso de ajuda.
Como fazer o Hotkey reconhecer que a página do Google foi carregada(dependendo da hora, a internet está ruim e demora um pouco mais).
Não queria ficar colocando "sleep, 8000" por ex.
*obs: graveiii o script(automação) utilizando o "AutoScriptWriter(recorder)", acho que o Hotkey é da v1.0.
Desde já agradeço!!!
User avatar
Gio
Posts: 1075
Joined: 30 Sep 2013, 10:54
Location: Brazil

Re: Como fazer o HOTKEY esperar a página carregar  Topic is solved

10 Jun 2020, 19:22

Boa noite Breno_mir.

Seja bem-vindo aos fórums da comunidade do AutoHotkey.

A última versão 1.0.XX foi lançada há mais de dez anos e o AutoScriptWriter não faz mais parte do pacote de instalação do AutoHotkey há muito tempo também, então sugiro que atualize para a versão v1.1+ mais recente, do contrário será difícil lhe ajudar de forma efetiva.

Sobre a sua pergunta "como fazer o autohotkey esperar uma página carregar", pelo que escreveu, principalmente sobre estar usando o AutoScriptWriter, me parece que você está tentando automatizar uma instância de um navegador escrito por terceiros (chrome, firefox, etc) que foi aberta sem nenhum tipo de acesso especial.

Eu realmente acho que esta não é a via mais recomendada para automatizar uma navegação web. Você sabia que o AutoHotkey pode realizar a navegação web de dentro do próprio script por protocolos http e outros meios? Além disso, você pode também utilizar a tecnologia COM (somente disponível nas versões 1.1+) para automatizar uma instância do Internet Explorer com controle quase total e de maneira relativamente fácil.

Exemplo: Rode o script abaixo. Ele vai abrir uma janela do Internet Explorer via COM. Quando esta janela estiver aberta e o primeiro site carregado, o script vai liberar duas hotkeys, nas teclas F2 e F3. Ao pressionar o F2, a instância aberta do IE vai carregar a página do Google e o script vai monitorar para você este carregamento via COM. Além disso, ao apertar F3, o script vai abrir a página dos fórums do AutoHotkey e também vai monitorar o carregamento dela pra você (avisando quando estiver terminado).

Code: Select all

#SingleInstance, Force

ToolTip, Abrindo o Internet Explorer via COM...
ESPERAR := 1
wb := ComObjCreate("InternetExplorer.Application")
wb.Navigate("https://www.autohotkey.com/boards")
wb.Visible := true 
while ((wb.readyState!=4) OR (wb.document.readyState != "complete") OR (wb.busy))
{
	Sleep 10
}
ESPERAR := 0
ToolTip, Pronto para uso. Aperte F2 ou F3 para carregar páginas de exemplo. `nO script vai monitorar o carregamento e informar quando estiver terminado.
Return

#If (ESPERAR = 0)

F2::
ToolTip, Carregando a página do Google...
wb.Navigate("https://www.google.com/")
while ((wb.readyState!=4) OR (wb.document.readyState != "complete") OR (wb.busy)) ; Este while-loop é o que verifica o estado do carregamento.
{
	Sleep 10
}
ToolTip
msgbox, 0, aviso, a página do google terminou de carregar.
Return 

F3::
ToolTip, Carregando a página dos fórums do AutoHotkey...
wb.Navigate("https://www.autohotkey.com/boards")
while ((wb.readyState!=4) OR (wb.document.readyState != "complete") OR (wb.busy)) ; Este while-loop é o que verifica o estado do carregamento.
{
	Sleep 10
}
ToolTip
msgbox, 0, aviso, a página principal dos fórums do autohotkey terminou de carregar.
Return

#If

Temos alguns tutoriais de uso de COM para automatizar o IE nos fórums em inglês. Infelizmente ainda não temos um em português, mas se você tiver alguma dúvida ou quiser um norte para iniciar este aprendizado, sinta-se livre para perguntar abaixo :thumbup:

Return to “Ajuda e Suporte Geral”

Who is online

Users browsing this forum: No registered users and 2 guests