AutoHotkey Community

Sam_ wrote:

lexikos wrote:

SetKeyDelay, -1, -1, -1

The third parameter should be the word "Play" or nothing at all. -1 has no meaning.

Thanks for the catch! I updated my last post.

lexikos wrote:WAZAAAAA, your top post still contains the SetKeyDelay error.

Sam_ wrote:

lexikos wrote:

SetKeyDelay, -1, -1, -1

The third parameter should be the word "Play" or nothing at all. -1 has no meaning.

Thanks for the catch! I updated my last post.

"Nothing at all" (for the third parameter) is the more correct option in this case. If you use the word Play it will only affect SendPlay, which defaults to -1/-1 anyway.

In addition to its uses described at DllCall, this function can also be used to enhance performance when building a string by means of gradual concatenation. This is because multiple automatic resizings can be avoided when you have some idea of what the string's final length will be.

; Optimize by ensuring MyVar has plenty of space to work with.
VarSetCapacity(MyVar, 10240000)  ; ~10 MB
Loop
{
    ...
    MyVar = %MyVar%%StringToConcatenate%
    ...
}

Sam_ wrote:Is it okay to discuss programming techniques that will help "optimize the speed of a script as much as possible" in this topic

WAZAAAAA wrote:GOTTA GO FAST

Sam_ wrote:So, taking the above into account, following the recommendations in the documentation (generally a wise move), and rearranging a bit, we now have:

Code: Select all

#NoEnv
Process, Priority, , H
SetBatchLines, -1
ListLines Off
#KeyHistory 0
SendMode Input
SetTitleMatchMode 2
SetTitleMatchMode Fast
SetKeyDelay, -1, -1, Play
SetMouseDelay, -1
SetWinDelay, 0		; Changed to 0 upon recommendation of documentation
SetControlDelay, 0	; Changed to 0 upon recommendation of documentation
SetDefaultMouseSpeed, 0

; YOUR_SCRIPT_HERE

Edited SetKeyDelay. See next post.

jNizM wrote:

Spoiler

Speedup DllCall's (excluded: "User32.dll", "Kernel32.dll", "ComCtl32.dll" & "Gdi32.dll")

Found in old Forum (Code by Bentschi)

Functions: LoadLibrary() & FreeLibrary()

Code: Select all

LoadLibrary(filename)
{
    static ref := {}
    if (!(ptr := p := DllCall("LoadLibrary", "str", filename, "ptr")))
        return 0
    ref[ptr,"count"] := (ref[ptr]) ? ref[ptr,"count"]+1 : 1
    p += NumGet(p+0, 0x3c, "int")+24
    o := {_ptr:ptr, __delete:func("FreeLibrary"), _ref:ref[ptr]}
    if (NumGet(p+0, (A_PtrSize=4) ? 92 : 108, "uint")<1 || (ts := NumGet(p+0, (A_PtrSize=4) ? 96 : 112, "uint")+ptr)=ptr || (te := NumGet(p+0, (A_PtrSize=4) ? 100 : 116, "uint")+ts)=ts)
        return o
    n := ptr+NumGet(ts+0, 32, "uint")
    loop % NumGet(ts+0, 24, "uint")
    {
        if (p := NumGet(n+0, (A_Index-1)*4, "uint"))
        {
            o[f := StrGet(ptr+p, "cp0")] := DllCall("GetProcAddress", "ptr", ptr, "astr", f, "ptr")
            if (Substr(f, 0)==((A_IsUnicode) ? "W" : "A"))
                o[Substr(f, 1, -1)] := o[f]
        }
    }
    return o
}

FreeLibrary(lib)
{
    if (lib._ref.count>=1)
        lib._ref.count -= 1
    if (lib._ref.count<1)
        DllCall("FreeLibrary", "ptr", lib._ptr)
}

Test Script:

Code: Select all

loops := 1000000
SetBatchLines, -1
global gdiplus := LoadLibrary("gdiplus")
VarSetCapacity(bin, 20, 0)
NumPut(1, bin, 0, "int")
DllCall(gdiplus.GdiplusStartup, "ptr*", token, "ptr", &bin, "ptr", 0)
DllCall(gdiplus.GdipCreateBitmapFromScan0, "int", 1, "int", 1, "int", 0, "int", 0x26200A, "ptr", 0, "ptr*", pBitmap)

start := A_TickCount
loop % loops
    DllCall("gdiplus\GdipBitmapGetPixel", "ptr", pBitmap, "int", 1, "int", 1, "uint*", col)
timeA := A_TickCount-start

start := A_TickCount
loop % loops
    DllCall(gdiplus.GdipBitmapGetPixel, "ptr", pBitmap, "int", 1, "int", 1, "uint*", col)
timeB := A_TickCount-start

DllCall(gdiplus.DisposeImage, "ptr", pBitmap)
DllCall(gdiplus.Cleanup, "ptr", token)
MsgBox % "Normal:`n" timeA "`n`nWith LoadLibrary:`n" timeB "`n`n" timeA/timeB

Result:

Code: Select all

---------------------------
LoadLibrary.ahk
---------------------------
Normal:
1828

With LoadLibrary:
781

2.340589
---------------------------
OK   
---------------------------

Export Table:

Code: Select all

global gdiplus := LoadLibrary("gdiplus")
for name, proc in gdiplus
{
    if (name!="_ptr" && name!="_ref" && name!="__delete")
        MsgBox % name
}

---

Maybe Lexicos can tell us more about it and his pro & contra.

LUCall(lib, func, params*) {
    static LookupTable := {}
    
    if(!Lookuptable[lib][func]) {
        if(!LookupTable[lib])
            LookupTable[lib] := {}
        LookupTable[lib][func] := DllCall("GetProcAddress", Ptr, DllCall("LoadLibrary", Str, lib, Ptr), AStr, func, Ptr)
    }
    
    return DllCall(LookupTable[lib][func], params*)
}

LUCall("Kernel32", "Sleep", "Int", 1000)
LUCall("User32", "MessageBoxA", "UInt", 0, "AStr", "Hello World!", "AStr", "MSGBOX", "UInt", 0)
LUCall("Kernel32", "Sleep", "Int", 1000)

loop_count := 100000
DllCall("GetLastError")
dc_time := 0 ;dllcall ticks
Loop %loop_count% {
    current_tick := A_TickCount
    DllCall("GetLastError")
    dc_time += A_TickCount - current_tick
}
dc_time := dc_time / loop_count

LUCall("Kernel32", "GetLastError")
lc_time := 0 ;lucall ticks
Loop %loop_count% {
    current_tick := A_TickCount
    LUCall("Kernel32", "GetLastError")
    lc_time += A_TickCount - current_tick
}
lc_time := lc_time / loop_count

DllCall("MessageBox", UInt, 0, Str, "dllcall = " . dc_time . ", lucall = " . lc_time, Str, "caption", Int, 0)

#NoEnv
Process, Priority, , H
SetBatchLines, -1
ListLines Off
#KeyHistory 0
SendMode Input
SetTitleMatchMode 2
SetTitleMatchMode Fast
SetKeyDelay, -1, -1, Play
SetMouseDelay, -1
SetWinDelay, 0		; Changed to 0 upon recommendation of documentation
SetControlDelay, 0	; Changed to 0 upon recommendation of documentation
SetDefaultMouseSpeed, 0

LUCall(lib, func, params*) {
    static LookupTable := {}
    
    if(!Lookuptable[lib][func]) {
        if(!LookupTable[lib])
            LookupTable[lib] := {}
        LookupTable[lib][func] := DllCall("GetProcAddress", Ptr, DllCall("LoadLibrary", Str, lib, Ptr), AStr, func, Ptr)
    }
    
    return DllCall(LookupTable[lib][func], params*)
}

LLCall(lib, func, params*) {
    static LookupTable := {}
    if(!Lookuptable[lib])
        Lookuptable[lib] := DllCall("LoadLibrary", Str, lib, Ptr)
    
    return DllCall(func, params*)
}

OptDllCall(lib, func, params*) {
    static
    if(!%func%)
        %func% := DllCall("GetProcAddress", Ptr, DllCall("LoadLibrary", Str, lib, Ptr), AStr, func, Ptr)
    res := DllCall(%func%, params*)
    return (ErrorLevel ? ErrorLevel : res)
}

PingTick() {
    static PrevTick
    DllCall("QueryPerformanceCounter", "Int64*", CurrentTick)
    ElapsedTicks := CurrentTick - PrevTick
    DllCall("QueryPerformanceCounter", "Int64*", PrevTick)
    return ElapsedTicks
}

loop_count := 20000
Loop 3 {    
    LUCall("Kernel32", "GetLastError")
    tick2 := PingTick()
    Loop %loop_count%
        LUCall("Kernel32", "GetLastError")
    tick2 := PingTick()
    
    LLCall("Kernel32", "GetLastError")
    tick3 := PingTick()
    Loop %loop_count%
        LLCall("Kernel32", "GetLastError")
    tick3 := PingTick()
    
    OptDllCall("Kernel32", "GetLastError")
    tick4 := PingTick()
    Loop %loop_count%
        OptDllCall("Kernel32", "GetLastError")
    tick4 := PingTick()
    
    tick1 := PingTick()
    Loop %loop_count%
        DllCall("GetLastError")
    tick1 := PingTick()
    
    DllCall("MessageBox", UInt, 0, Str, tick1 . " μs`n" . tick2 . " μs`n" . tick3 . " μs`n" . tick4 . " μs", Str, "μs counts", Int, 0)
}

Documentation wrote:Performance: In v1.0.48+, the comma operator is usually faster than writing separate expressions, especially when assigning one variable to another (e.g. x:=y, a:=b). Performance continues to improve as more and more expressions are combined into a single expression; for example, it may be 35% faster to combine five or ten simple expressions into a single expression.

a := 1
b := 2
c := 3
d := Function( param )
e := AnotherFunc( d )
return

a := 1
, b := 2
, c := 3
, d := Function( param )
, e := AnotherFunc( d )
return

KuroiLight wrote: EDIT: well seems I made a mistake in not testing these properly before-hand: in that all other ways I've tried are still slower than the built-in dllcall, makes sense actually. (guess Ill be removing some code); I still think one form or another might help with function calls to libraries not yet loaded though, stay clear of lookuptables/dictionaries as those seem to be too slow for ahk though. (strangely enough dynamic variable version was the

• String Function Name: 14.9 ms
  Function Address: 15.5 ms

WAZAAAAA wrote:Replaced the high CPU Sleep function with the "suspend" Sleep method which uses no considerable CPU and makes the code way shorter.

Here's the previous one, for historical reasons I guess:

Spoiler

Code: Select all

sleepz(period := 1, Mode := "P")
{
	static Frequency, MinSetResolution, PID
	if (Mode = "P")
	{
		pBatchLines := A_BatchLines
		SetBatchLines, -1
		if !Frequency
			DllCall("QueryPerformanceFrequency", "Int64*", Frequency)
		DllCall("QueryPerformanceCounter", "Int64*", Start)
		Finish := Start + ( Frequency * (period/1000))
		loop 
			DllCall("QueryPerformanceCounter", "Int64*", Current)
		until (Current >= Finish)
		SetBatchLines, %pBatchLines%
	}
	return
}

sleepz(16.6, "P") ;I just used the CPU intensive precise sleep function to wait exactly 16,6 milliseconds!

dsewq1LYJ wrote:Higher precision but higher usage ?
And may I ask.
What's the lowest delay of the function

WAZAAAAA wrote:

dsewq1LYJ wrote:Higher precision but higher usage ?
And may I ask.
What's the lowest delay of the function

According to my benchmarks:
Sleep default method = low CPU, low precision
Sleep suspend method = low CPU, high precision, issues with SetTimer
Sleep precise method = high CPU, higher precision
But sometimes when using the precise method, it eats so much CPU that it actually ends up slowing everything down, this has happened to a friend of mine too with a weaker PC, that's why I have replaced it with the suspend mode.
You can read more about precise sleeps at RHCP's thread: http://www.autohotkey.com/board/topic/9 ... -function/

I don't understand what do you mean with lowest delay.

;PixelGetColor
PixelGetColor,A,1,1
PixelGetColor,B,2,2
PixelGetColor,C,3,3
if (A=0xFFFFFF)
	foo()
else if (B=0xEEEEEE)
	bar()
else if (C=0xDDDDDD)
	foo()
; Uh...How and .... what ?
PixelSearch,,,1,1,1,1,0xFFFFFF
PixelSearch,,,1,1,1,1,0xEEEEEE
PixelSearch,,,1,1,1,1,0xDDDDDD

;Gdi ? Faster
;....

ozzii wrote:If I understand well something like this:

Code: Select all

PixelSearch,,,1,1,1,1,0xFFFFFF
if !errorlevel
	foo()
PixelSearch,,,1,1,1,1,0xEEEEEE
if !errorlevel
	bar()
PixelSearch,,,1,1,1,1,0xDDDDDD
if !errorlevel
	foo()