Calling one class from another

[djvj11]

I need to create a File object when I create the Process object but how come the msgbox in File class never shows up?

Code: Select all

primaryExe := new Process(emuPath . "\" . executable)
ExitApp

class File
{
	__New(file)
	{
		SplitPath, file, file, path, ext, fileNE, drive
		this.FileDrive := drive
		this.FileName := file
		this.FileNameNoExt := fileNE
		this.FilePath := path
		this.FileExt := ext
		msgbox % A_ThisFunc . ": " . this.FileName
	}

}

class Process
{
	__New(file)
	{
		this.processFile := new File(file)
		msgbox % A_ThisFunc . ": " . this.processFile.FileName
	}
}

[Coco]

It's a variable name conflict. class File creates a super-global variable named "File" which holds a reference to the class object. this.processFile := new File(file) -> File here refers to the function parameter not the class object. Rename the function parameter to something like f or rename the class to something like CFile and your code should work. Btw, AutoHotkey is not case-sensitive when it comes to variable/function names.

[djvj11]

You were right, that was it! Thank you.

That can be a nightmare to troubleshoot w/o a loadtime error in large scripts.