Help with IE COM – loop for correct tag

[menteith]

Hi all,

Thanks for the answer to my latest post I was able to write another piece of my program. I'm stuck again, however.

Code: Select all

<article class="article-detail-description">
                <h1 class="page-heading">
                    Normatywne i empiryczne teorie demokracji
                    <br /><small>Normative and empirical theories of democracy</small>
                </h1>
                 
                <div>
                    <strong>Author(s): </strong>Jane Doe<br /><strong>Subject(s): </strong>Politics / Political Sciences<br />
                    <strong>Published by: </strong>KSIĘGARNIA AKADEMICKA Sp. z o.o.<br/><
                    strong>Keywords: </strong>democracy; norms; evaluation; explanation<br/>
                </div>

I'd like to get some of elements after <strong> .... </strong> tags e.g. Jane Doe.

Here's my attempt. First I look for every strong tag and then look for "Author(s): ". But I cannot get what is after it.

An edit: I'd like to avoid using RegEx.

Code: Select all

IE := ComObjCreate("InternetExplorer.Application")
IE.Visible := false
IE.Navigate("https://www.ceeol.com/search/article-detail?id=343886")
while IE.readyState != 4 || IE.document.readyState != "complete" || IE.busy
Sleep 10

   script_class := IE.document.querySelectorAll("strong") ;get all classes on page
while A_Index < script_class.length
	if InStr(script_class[A_Index].outerHtml,"Author(s): ")
		MsgBox % script_class[A_Index].innerText
ExitApp

[Capn Odin]

Try this, not sure it's the most efficient way possible through.

Code: Select all

OnExit("KillIE")

IE := ComObjCreate("InternetExplorer.Application")
IE.Visible := false
IE.Navigate("https://www.ceeol.com/search/article-detail?id=343886")

while IE.readyState != 4 || IE.document.readyState != "complete" || IE.busy
	Sleep 10

detail := IE.document.getElementsByClassName("article-detail-description")
div := detail[0].getElementsByTagName("div")

MsgBox, % div[0].InnerHTML

RegExMatch(div[0].InnerHTML	, "(?<=</strong>)(\w|\s)*(?=<br>)", Author)
MsgBox, % Author

KillIE(){
	Global IE
	IE.Quit()
}

[menteith]

Thanks. I didn't mention that I'd like to avoid using RegEx:)

[Capn Odin]

Thanks. I didn't mention that I'd like to avoid using RegEx:)

Is this way ok ?

Code: Select all

OnExit("KillIE")

IE := ComObjCreate("InternetExplorer.Application")
IE.Visible := false
IE.Navigate("https://www.ceeol.com/search/article-detail?id=343886")

while IE.readyState != 4 || IE.document.readyState != "complete" || IE.busy
	Sleep 10

detail := IE.document.getElementsByClassName("article-detail-description")
div := detail[0].getElementsByTagName("div")

MsgBox, % div[0].InnerHTML

str := StrSplit(div[0].InnerHTML, "<br>")[1]

Author := SubStr(str, InStr(str, "</strong>") + StrLen("</strong>"))

MsgBox, % Author

KillIE(){
	Global IE
	IE.Quit()
}

[menteith]

Capn Odin

Very nice! Thank you for your swift reply. May I have a request? I'd like to have, say, values after "Author(s): " and "Keywords: " assigned to a variable. For example: x = Andrzej Antoszewski.

Many thanks again!

[ameyrick]

You almost had it with your first try
A_Index starts at 1 not 0

Code: Select all

IE := ComObjCreate("InternetExplorer.Application")
IE.Visible := false
IE.Navigate("https://www.ceeol.com/search/article-detail?id=343886")
while IE.readyState != 4 || IE.document.readyState != "complete" || IE.busy
Sleep 10
 
   script_class := IE.document.querySelectorAll("strong") ;get all classes on page
loop, % script_class.length
	if InStr(script_class[(A_Index-1)].outerHtml,"Author(s): ")
		MsgBox % script_class[(A_Index-1)].innerText
ExitApp

[Capn Odin]

Capn Odin

Very nice! Thank you for your swift reply. May I have a request? I'd like to have, say, values after "Author(s): " and "Keywords: " assigned to a variable. For example: x = Andrzej Antoszewski.

Many thanks again!

Code: Select all

OnExit("KillIE")

IE := ComObjCreate("InternetExplorer.Application")
IE.Visible := false
IE.Navigate("https://www.ceeol.com/search/article-detail?id=343886")

while IE.readyState != 4 || IE.document.readyState != "complete" || IE.busy
	Sleep 10

detail := IE.document.getElementsByClassName("article-detail-description")
div := detail[0].getElementsByTagName("div")

MsgBox, % div[0].InnerHTML

str := StrSplit(div[0].InnerHTML, "<br>")

Authors := SubStr(str[1], InStr(str[1], "</strong>") + StrLen("</strong>"))

for index, val in str{
	if(InStr(val, "Keywords: ")){
		Keywords := StrReplace(val, "<strong>Keywords: </strong>")
		Break
	}
}

MsgBox, % Authors "`n" Keywords

KillIE(){
	Global IE
	IE.Quit()
}

[menteith]

Thanks! I did some tests and it works:) One strange thing is that when I use:

Code: Select all

for index, val in str{
	if(InStr(val, "Author(s): ")){
		Authors := StrReplace(val, "<strong>Author(s): </strong>")
		Break
	}
}

String starts with a tab or two.
The following gives the expected result:

Code: Select all

for index, val in str{
	if(InStr(val, "Published by: ")){
		pub := StrReplace(val, "<strong>Published by: </strong>")
		Break
	}
}

[menteith]

You almost had it with your first try
A_Index starts at 1 not 0

Code: Select all

IE := ComObjCreate("InternetExplorer.Application")
IE.Visible := false
IE.Navigate("https://www.ceeol.com/search/article-detail?id=343886")
while IE.readyState != 4 || IE.document.readyState != "complete" || IE.busy
Sleep 10
 
   script_class := IE.document.querySelectorAll("strong") ;get all classes on page
loop, % script_class.length
	if InStr(script_class[(A_Index-1)].outerHtml,"Author(s): ")
		MsgBox % script_class[(A_Index-1)].innerText
ExitApp

Thank you. I have seen a lot of your post about COM and I even use you modified version of IEGet;)

The thing is that mine code works but I'd like to get what is after "Author(s): " not ""Author(s): "" itself. You can check a reply by Capn Odin. One strange thing is bugging me, thought. Care to tell me why the following code gives the correct result but with one or two spaces (or maybe tabs) before it?

Code: Select all

for index, val in str{
	if(InStr(val, "Author(s): ")){
		Authors := StrReplace(val, "<strong>Author(s): </strong>")
		Break
	}
}

Thanks!

[ameyrick]

On my phone right now will look at it again later.

As for the tabs and spaces... If they exist in the html source, they will be in the result string as they are valid characters. You will have to test for them and remove them.

[ameyrick]

no_whitespace()

Code: Select all

OnExit("KillIE")
 
IE := ComObjCreate("InternetExplorer.Application")
IE.Visible := false
IE.Navigate("https://www.ceeol.com/search/article-detail?id=343886")
 
while IE.readyState != 4 || IE.document.readyState != "complete" || IE.busy
	Sleep 10
 
detail := IE.document.getElementsByClassName("article-detail-description")
div := detail[0].getElementsByTagName("div")
 
MsgBox, % div[0].InnerHTML

MsgBox, % no_whitespace(div[0].InnerHTML)
 
str := StrSplit(div[0].InnerHTML, "<br>")

for index, val in str{
	if(InStr(val, "Author(s): ")){
		Authors := StrReplace(val, "<strong>Author(s): </strong>")
		Authors := no_whitespace(Authors)
		Break
	}
}

for index, val in str{
	if(InStr(val, "Keywords: ")){
		Keywords := StrReplace(val, "<strong>Keywords: </strong>")
		Break
	}
}
 
MsgBox, % Authors "`n" Keywords

no_whitespace(s){
	x:="", r:="", i:=0, spc:=0
	MatchList := Chr(10) "," Chr(13) "," Chr(32) "," A_Space "," A_Tab
	StringSplit, ch, s
	loop % ch0
	{
		if (i < 1)
			if ch%A_Index% in %MatchList%
				continue
		i+=1
		if ch%A_Index% in %MatchList%
			spc+=1
		if (spc > 1){
			i-=1
			continue 
		} else 
			spc:=0		
		x.= ch%A_Index%
	}
	global ch:=
	StringSplit, ch, x
	a:=ch0
	i:=0
	loop, % ch0
	{
		if (a = 0)
			break
		if (i < 1)
			if ch%a% in %MatchList%
			{
				a-=1
				continue 
			}
		i+=1
		r:= ch%a% r
		a-=1
	}
	global ch:=
	return r
} ;written by ameyrick

KillIE(){
	Global IE
	IE.Quit()
}

[menteith]

no_whitespace()

Code: Select all

OnExit("KillIE")

}

Thank you! Much appreciated!