Simple text search from text-file?

[Peter2]

I think that's this is nearly a standard solution, so maybe there exists some plug&play script?

- Read a predefined text-file
- search all strings containing *mysearch*
- list them to user
- user clicks to input/paste it

If a code like this exists I would be happy for a hint/link

Peter

[MaxAstro]

Untested!

Code: Select all

FilePath := "complete path to the string-containing file goes here"

^a::
	InputBox, SearchString, , % "Input string to search."
	ResultList := []
	ChosenString := ""
	Loop, Read, %FilePath%
		if (InStr(A_LoopReadLine, SearchString))
			ResultList.Push(A_LoopReadLine)
	if (!ResultList.Length)
	{
		MsgBox % "No match found!"
		return
	}
	Gui, DisplayResults:New
	Gui, Add, Text, , % "Click on a line to select it."
	for key, value in ResultList
	{
		if (key = 1)
			Gui, Add, Radio, gSelectResult vChosenString, %value%
		else
			Gui, Add, Radio, gSelectResult, %value%
	Gui, DisplayResults:Show
	return
	
SelectResult:
	Gui, DisplayResults:Submit
	Send % ResultList[ChosenString]
	return

[Peter2]

Great-thanks. Here is the tested version.

Code: Select all

    FilePath := "complete path to the string-containing file goes here"
^a::
    InputBox, SearchString, , % "Input string to search."
    ResultList := []
    ChosenString := ""
    Loop, Read, %FilePath%
    {
        if (InStr(A_LoopReadLine, SearchString))
        {
            ResultList.Push(A_LoopReadLine)
        }
    }
    if (!ResultList.Length())
    {
        MsgBox % "No match found!"
        return
    }
    Gui, DisplayResults:New,-MaximizeBox -MinimizeBox  , Search results
    Gui, Add, Text, w250, % "Click on a line to select and type it."
    for key, value in ResultList
    {
        if (key = 1)
            Gui, Add, Radio, gSelectResult vChosenString, %value%
        else
            Gui, Add, Radio, gSelectResult, %value%
    }
    Gui, DisplayResults:Show
    return
    
SelectResult:
    Gui, DisplayResults:Submit
    Send % ResultList[ChosenString]
    return

[MaxAstro]

Glad that worked for you, it was pretty much off the top of my head.

[Peter2]

... off the top of my head.

There must be a lot of AHK in it ...

[glogin]

What would the script look like if they referred to the text string that would be in the script?

Thank you!