Basic Array Stuff Topic is solved

[magicinmath]

Hey I'm trying to figure out how to read from a given window instead of a path. I tried ControlGetText, WinGetText instead, but didn't work ... Not sure what the command would be and how to relate the array object to it.

Code: Select all

^!+.::

	Array := Object()
	Array[j] := A_LoopField
	Array[j, k] := A_LoopReadLine

	ArrayCount := 0       
                 
	Loop, Read, path\file		;this is the line I'd like to change to access an unsaved notepad rather than read from a saved file.
	{
		ArrayCount += 1
		Array[ArrayCount] := A_LoopReadLine
	}

	Loop %ArrayCount%
	{

		MsgBox % Array[A_Index]
	}

Return

Thanks for your help.

[Xeno234]

Code: Select all

f3::
	ControlGetText, var, edit1, ahk_class Notepad
	arr := strsplit(var, "`n")
	/* or
	arr := []
	loop, parse, var, `n
		arr.push(A_LoopField)
	*/	
	loop % arr.length()
		msgbox % arr[a_index]
return

[pneumatic]

"For dummies" version...

Code: Select all

^!F3::

	Array := Object()
	ControlGetText, NotepadText, Edit1, Untitled - Notepad   ;Use Window Spy to get the names of "Edit1" and "Untitled - Notepad" ; see image
	
    ArrayCount := 0             
	Loop, parse, NotepadText, `n, `r	
	{
		ArrayCount := ArrayCount + 1
		Array[ArrayCount] := A_LoopField
	}

	Loop %ArrayCount%
	{
		MsgBox % Array[A_Index]
	}

return

[magicinmath]

This is so helpful. I really appreciate the "for dummies" version and I learned a lot, especially showing me what the heck edit1 meant.
I have so many applications for that Thank you again.