Function/Return is not returning a value Topic is solved

[noob3467]

;for some reason this does not return any value
[code]
ButttonChoice := FirstGui()
msgbox %ButttonChoice%
ExitApp

FirstGui() {
Gui, +LastFound
GuiHWND := WinExist()
Gui, -SysMenu +Owner
Gui, Add, Button, w90 y10 gFirstB1 Default, One
Gui, Add, Button, w90 y+10 gFirstB2, Two
Gui, Add, Button, w90 y+10 gFirstB3, Three
Gui, Add, Button, w90 y+10 gFirstB4, Four
Gui, Add, Button, w90 y+10 gFirstExit, Exit
Gui, Show,, Buttontest
Return
WinWaitClose, ahk_id %GuiHWND%

FirstB1:
Gui, Destroy
Return 1
FirstB2:
Gui, Destroy
Return 2
FirstB3:
Gui, Destroy
Return 3
FirstB4:
Gui, Destroy
Return 4
FirstExit:
ExitApp
}
[/code]

[uname]

Code: Select all

ButttonChoice := FirstGui()
msgbox %ButttonChoice%
ExitApp

FirstGui() {
    static firsGuiButton

    Gui New, -SysMenu +Owner
    Gui Add, Button, w90 y10 gButtonEventHandler Default, One
    Gui Add, Button, w90 y+10 gButtonEventHandler, Two
    Gui Add, Button, w90 y+10 gButtonEventHandler, Three
    Gui Add, Button, w90 y+10 gButtonEventHandler, Four
    Gui Add, Button, w90 y+10 gButtonEventHandler, Exit
    Gui Show,, Buttontest
    
    loop
        Sleep 100
    until firsGuiButton

    Gui Destroy
    return {One: 1, Two: 2, Three: 3, Four: 4, Exit: -1}[firsGuiButton], firsGuiButton := ""

ButtonEventHandler:
    firsGuiButton := A_GuiControl
    return
}