[SOLVED] Better way to calc uptime

[jNizM]

Is there a better (faster, Resource-saving) way to calc the uptime?

Code: Select all

MsgBox, % "Uptime: " FormatSeconds(DllCall("GetTickCount") / 1000)
MsgBox, % "Uptime: " FormatSeconds(DllCall("GetTickCount64") / 1000)

FormatSeconds(NumberOfSeconds, TimeFormat = "") {
    if !TimeFormat
        TimeFormat = HH:mm:ss
    Time = 19990101
    Time += %NumberOfSeconds%, Seconds
    FormatTime, Output1, %Time%, %TimeFormat%
	FormatTime, Output2, %Time%, YDay
    return Output2-1 "d:" Output1
}

[Zelio]

It seems the best option and easy (like example of documentation), or maybe find a dynamic library to do it, or a machine code...

[just me]

Maybe not better, but different:

Code: Select all

FormatDuration(NumberOfSeconds, Format := "d'd':hh:mm:ss") {
   ; http://msdn.microsoft.com/en-us/library/windows/desktop/dd318091(v=vs.85).aspx
   VarSetCapacity(Out, 128, 0)
   DllCall("Kernel32.dll\GetDurationFormat", "UInt", 0x400
                                           , "UInt", 0
                                           , "Ptr", 0
                                           , "Int64", NumberOfSeconds * 10000000
                                           , "WStr", Format
                                           , "WStr", Out
                                           , "Int", 64)
   Return Out
}