Reverse array Topic is solved

[masheen]

How to reverse array that get:

Code: Select all

oArray := []
oArray[1] := 1
oArray[7] := 2
oArray[8] := 3

Msgbox, % oArray[1] " " oArray[7] " " oArray[8] ; 1 2 3

ReverseArray(oArray)

Msgbox, % oArray[1] " " oArray[7] " " oArray[8] ; 3 2 1


ReverseArray(oArray){
	.... ;???
	.... ;???
	.... ;???
}

[KernelKross]

Code: Select all

ReverseArray(oArray)
{
	Array := Object()
	For i,v in oArray
		Array[oArray.Length()-i+1] := v
	Return Array
}

Or use ByRef to change the passed variable upon return.

Code: Select all

ReverseArray(ByRef oArray)
{
	Array := Object()
	For i,v in oArray
		Array[oArray.Length()-i+1] := v
	Return Array
}

[masheen]

Code: Select all

ReverseArray(oArray)
{
	Array := Object()
	For i,v in oArray
		Array[oArray.Length()-i+1] := v
	Return Array
}

Or use ByRef to change the passed variable upon return.

Code: Select all

ReverseArray(ByRef oArray)
{
	Array := Object()
	For i,v in oArray
		Array[oArray.Length()-i+1] := v
	Return Array
}

Dont work

Code: Select all

oArray := []
oArray[1] := 1
oArray[7] := 2
oArray[8] := 3


oArray := ReverseArray(oArray)

Msgbox, % oArray[1] " " oArray[7] " " oArray[8] ; 3 1 <--------------- ???


ReverseArray(oArray)
{
	Array := Object()
	For i,v in oArray
		Array[oArray.Length()-i+1] := v
	Return Array
}

[jeeswg]

Code: Select all

q:: ;reverse array
oArray := {}
oArray[1] := 1
oArray[7] := 2
oArray[8] := 3

Msgbox, % oArray[1] " " oArray[7] " " oArray[8] ; 1 2 3

ReverseArray(oArray)

Msgbox, % oArray[1] " " oArray[7] " " oArray[8] ; 3 2 1
return

ReverseArray(oArray)
{
	oArray2 := oArray.Clone()
	oTemp := {}
	for vKey in oArray
		oTemp.Push(vKey)
	vIndex := oTemp.Length()
	for vKey in oArray
		oArray[vKey] := oArray2[oTemp[vIndex--]]
	oArray2 := oTemp := ""
}

[Helgef]

I think you could simplify it jeeswg,

Code: Select all

; Not tested
rev(arr){
	local k, o:=[]
	for k in arr.clone()
		o[k] := arr.pop()
	return o
}

Edit 1 a): Avoids cloning,

Code: Select all

revB(arr){
	local t,k,v,o
	t:=[],o:=[]
	for k in arr
		t[A_Index] := k
	for k, v in t
		o[v] := arr.pop()
	return o
}

Edit 1 b): You do not need to clear local variables before the function returns.

[jeeswg]

@Helgef:
- The nature of masheen's original function request required editing the object 'ByRef', rather than getting a new array returned.
- Does your function handle objects with non-numeric key names? Pop only works on numeric key names AFAIK. [EDIT:] Hmm, the documentation didn't explicitly state this.
- Yes, I'm 50/50 about whether I should clear local variables at the end, for style reasons, and for the situation where you copy out code from a function for use in the main body.of the script.

Code: Select all

q:: ;pop
vOutput := ""
oArray := {}
oArray.a := "A"
oArray.b := "B"
oArray.c := "C"
oArray.Pop()
vOutput := ""
for vKey, vValue in oArray
	vOutput .= vKey " " vValue "`r`n"
MsgBox, % vOutput

vOutput := ""
oArray := ["one","two","three"]
oArray.a := "A"
oArray.b := "B"
oArray.c := "C"
oArray.Pop()
vOutput := ""
for vKey, vValue in oArray
	vOutput .= vKey " " vValue "`r`n"
MsgBox, % vOutput
return

[Helgef]

- Sure, one can add byref and assign arr:=o instead of returning o.
- No. If this extraordinary case is desirable, your function is fine, but you should not use push when you cannot set the capacity beforehand. (Although, I find it unlikely someone would reverse large (sparse) arrays, so it would probably never matter)

Hmm, the documentation didn't explicitly state this.

Explicitly implict:

it is equivalent to the following:
Value := Object.RemoveAt(Object.Length())

- If it is your style, go ahead

for the situation where you copy out code from a function for use in the main body.of the script.

Blasphemy

[gmoises]

Sometimes it is important to use 'Local'

Code: Select all

Reverse(Arr) {
	Local
	Rev := Object()
	For Ix, Val in Arr
		Rev.InsertAt(1, Val)
	Return Rev
}

[jNizM]

This is what I got in my lib -> https://github.com/jNizM/AHK_Scripts/blob/master/src/arrays/RevArr.ahk

[Chunjee]

.reverse is also a method in the biga.ahk library I've been working on (.reverse docs)

Code: Select all

A := new biga()

A.reverse(["a", "b", "c"])
; => ["c", "b", "a"]

A.reverse([{"foo": "bar"}, "b", "c"])
; => ["c", "b", {"foo": "bar"}]

A.reverse([[1, 2, 3], "b", "c"])
; => ["c", "b", [1, 2, 3]]

[swagfag]

huh, i thought clones were more expensive than that.
so far it looks like @Helgef's first solution is the simplest, most performant and also conforming to spec
@jeeswg's comes second, while also being correct
and the rest are either unoptimized(insertat 1 big no no) or mangle the indices

in fact, if u clone twice in helgef's function, u get a pretty nice, cheap, correct, immutable array reversal

Code: Select all

rev(arr){
	local k, o:=[]
	brr := arr.clone()
	for k in arr.clone()
		o[k] := brr.pop()
	return o
}