Checked groupbox

[pneumatic]

Hi

Is it possible to achieve a checked groupbox like this



The article where this image is from mentions the following technique:

1. check whether the CheckBox is inside the GroupBox and, if it is, move it into the GroupBox‘s parent
2. move the CheckBox to the front of the stacking order so it doesn’t end up behind the GroupBox.

Is it possible to perform these steps in ahk?

Thanks

[wolf_II]

I think to do this: move it into the GroupBox‘s parent, you have to have a parent-child relationship between Gui elements.
In VBA, I remember having seen those. In AHK not so much built-in but possible to add yourself, I think.

[Delta Pythagorean]

You're going to have to use a normal checkbox without any text and do some gLabels in order to do what you want to do.

[BoBo]

As Delta has already said, simply positioning a "nameless" checkbox relatively close to a section label and you should be done.
This one will eliminate a "keeping an already selected option even if its checkbox has been unchecked meanwhile" (something you see in your breakfast section):

Spoiler

Code: Select all

	Gui, Add, CheckBox, vCB1 gCB,% "Lunch"
	Gui, Add, Radio, xp14 	yp20	vRB1 disabled checked0,% "Sandwich"
	Gui, Add, Radio, xp 	yp20	vRB2 disabled checked0,% "Soup"
	Gui, Add, Radio, xp		yp20	vRB3 disabled checked0,% "Rack of Godzilla"
	Gui, Show,, `t
	Return

CB:
	Gui, Submit, NoHide
	rbSet(CB1)		
	SoundBeep
	Return
	
	
rbSet(status) {
	Loop 3 {
		GuiControl, enable%status%, RB%A_Index%
		GuiControl,, RB%A_Index%, 0
		}
	}

[wolf_II]

Try this:

Code: Select all

#NoEnv
#SingleInstance, Force

    Gui, Add, GroupBox, w260 h100 Section
    Gui, Add, Checkbox, xs+5 ys gonCB_Click Checked hwndhCB1, Breakfast
    Gui, Add, Radio, xs+20 ys+20 w100 hwndhRB11, Toast
    Gui, Add, Radio, y+12 w100 hwndhRB12, Pancakes
    Gui, Add, Radio, y+12 w100 hwndhRB13, Pickles

    Gui, Add, GroupBox, xm w260 h100 Section
    Gui, Add, Checkbox, xs+5 ys gonCB_Click Checked hwndhCB2, Lunch
    Gui, Add, Radio, xs+20 ys+20 w100 hwndhRB21, Sandwich
    Gui, Add, Radio, y+12 w100 hwndhRB22, Soup
    Gui, Add, Radio, y+12 w100 hwndhRB23, Rack of Lamb
    Gui, Show

    Children := {}
    Children.Push({hwnd: hCB1})
    Children.Push({hwnd: hCB2})

    Children[1].Push(hRB11)
    Children[1].Push(hRB12)
    Children[1].Push(hRB13)

    Children[2].Push(hRB21)
    Children[2].Push(hRB22)
    Children[2].Push(hRB23)

Return

GuiClose:
ExitApp



;-------------------------------------------------------------------------------
onCB_Click(hwnd, GuiEvent, EventInfo, ErrLevel := "") {
;-------------------------------------------------------------------------------
    global Children
    SetFormat, Integer, h
    GuiControlGet, state,, % hwnd += 0
    Loop, 2
        If Children[A_Index].hwnd = hwnd {
            Index := A_Index
            Break
        }
    For each, Child in Children[Index]
        If Not (Child = hwnd)
            GuiControl, % (state ? "Enable":"Disable"), %Child%
}

Maybe that is all you need?

[BoBo]

Try this: ... Maybe that is all you need?

That's cool! Would you mind to sort out how to reset the RB section once you uncheck an already selected section? I've already created my own code (see above). But your's looks much more sophisticated. I'm always trying to get something new from those samples. Thx

[wolf_II]

Hi BoBo! Sure thing. I was about to mention that I prefer to have a named CheckBox, it is not intuitive to click on some text next to a checkbox and nothing happens.

Have you got an example how you would like that to happen?
example: uncheck => all radios will be cleared.

Code: Select all

;-------------------------------------------------------------------------------
onCB_Click(hwnd, GuiEvent, EventInfo, ErrLevel := "") {
;-------------------------------------------------------------------------------
    global Children
    SetFormat, Integer, h
    GuiControlGet, state,, % hwnd += 0
    Loop, 2
        If Children[A_Index].hwnd = hwnd {
            Index := A_Index
            Break
        }
    For each, Child in Children[Index]
        If Not (Child = hwnd) {
            GuiControl,, %Child%, 0 ; <<<< clear 
            GuiControl, % (state ? "Enable":"Disable"), %Child%
        }
}

[BoBo]

@ wolf_II
"Have you got a example how you would like that to happen?". If you look at my spoilered code above you'll get the idea
"example: uncheck => all radios will be emptied." Yep, that's how I've done it. Thought that would be kinda common approach to clear a section eg. to prevent that no previously selected item will be "ordered" by mistake?!

[pneumatic]

Thanks for the solutions.

My main concern wasn't actually with the management of child controls (I was already doing that manually in an unsophisticated way) but rather to ensure the checkbox gets drawn on top of the groupbox. It seems the basic rule is that as long as the checkbox is added after the groupbox, it should appear on top of the groupbox. But I'm worried that this is a bit of a hack and will flicker or appear underneath on certain versions of windows , or on certain themes, or just different brand GPU's.

Is "move the CheckBox to the front of the stacking order so it doesn’t end up behind the GroupBox" equivalent to just adding the checkbox after the groupbox, or is there some Dll function that can explicitly move a control to the top of the stacking order?