multiple file rename

[almatrah]

Hi Everybody

I found nice script example on the archived forum https://autohotkey.com/board/topic/7671 ... ing-files/.

Code: Select all

debug := true ; change this to false to have it actually rename the files..

#IfWinActive, ahk_class ExploreWClass
#IfWinActive, ahk_class CabinetWClass
f1::  ; remove first 12 chars from beginning of filenames
  SendInput, ^c
  Loop, Parse, clipboard, `n, `r
    Loop, % A_LoopField
      FileMove( A_LoopFileFullPath, SubStr( A_LoopFileName, 12) )
return

f2::  ; add timestamp to beginning of filenames
  FormatTime, dateStamp, YYYYMMDDHH24MISS, yyyy-MM-dd_
  SendInput, ^c
  Loop, Parse, clipboard, `n, `r
    Loop, % A_LoopField
      FileMove( A_LoopFileFullPath, dateStamp A_LoopFileName )
return
#IfWinActive

FileMove(fileFullPath, newFileName){
  global debug
  If debug
    Msgbox, Renaming: `n%fileFullPath%`n`nTo:`n%newFileName%
  Else
    FileMove, %fileFullPath%, %newFileName%
}

The problem is I have to double hit hotkey to run script. Why? What is the reason?

[trust_me]

Not sure but try this:

Code: Select all

debug := true ; change this to false to have it actually rename the files..

#If (WinActive( "ahk_class ExploreWClass") or WinActive( "ahk_class CabinetWClass"))

f1::  ; remove first 12 chars from beginning of filenames
  SendInput, ^c
  Loop, Parse, clipboard, `n, `r
    Loop, % A_LoopField
      FileMove( A_LoopFileFullPath, SubStr( A_LoopFileName, 12) )
return

f2::  ; add timestamp to beginning of filenames
  FormatTime, dateStamp, YYYYMMDDHH24MISS, yyyy-MM-dd_
  SendInput, ^c
  Loop, Parse, clipboard, `n, `r
    Loop, % A_LoopField
      FileMove( A_LoopFileFullPath, dateStamp A_LoopFileName )
return
#If

FileMove(fileFullPath, newFileName){
  global debug
  If debug
    Msgbox, Renaming: `n%fileFullPath%`n`nTo:`n%newFileName%
  Else
    FileMove, %fileFullPath%, %newFileName%
}

[tmplinshi]

Because the system need time to complete the copy.

Code: Select all

Clipboard := "" ; Clear the clipboard
SendInput, ^c
ClipWait, 2

I suggest using another approach that does not affect the clipboard.

Code: Select all

debug := true ; change this to false to have it actually rename the files..

#If (WinActive( "ahk_class ExploreWClass") or WinActive( "ahk_class CabinetWClass"))

f1::  ; remove first 12 chars from beginning of filenames
  Loop, Parse, % Explorer_GetSelection(), `n, `r
    Loop, % A_LoopField
      FileMove( A_LoopFileFullPath, SubStr( A_LoopFileName, 12) )
return

f2::  ; add timestamp to beginning of filenames
  FormatTime, dateStamp, YYYYMMDDHH24MISS, yyyy-MM-dd_
  Loop, Parse, % Explorer_GetSelection(), `n, `r
    Loop, % A_LoopField
      FileMove( A_LoopFileFullPath, dateStamp A_LoopFileName )
return
#If

FileMove(fileFullPath, newFileName){
  global debug
  If debug
    Msgbox, Renaming: `n%fileFullPath%`n`nTo:`n%newFileName%
  Else
    FileMove, %fileFullPath%, %newFileName%
}

Explorer_GetSelection()
{
	WinGetClass, class, A
	if (class ~= "Progman|WorkerW")
	{
		ControlGet, files, List, Selected Col1, SysListView321, A
		files := RegExReplace(files, "`am)^", A_Desktop "\")
	}
	else if (class ~= "(Cabinet|Explore)WClass")
	{
		hwnd := WinExist("A")
		for window in ComObjCreate("Shell.Application").Windows
			if (window.hwnd = hwnd)
			{
				for item in window.Document.SelectedItems
					files .= item.path "`n"
				break
			}
	}
	return Trim(files, "`n")
}