GroupBox Control Covers Tab Control Topic is solved

Get help with using AutoHotkey and its commands and hotkeys
elmo
Posts: 101
Joined: 09 Oct 2013, 09:08

GroupBox Control Covers Tab Control

13 Sep 2018, 12:54

Hello forum,

Surprised I am seeing this for the first time ... feels like it should have popped up somewhere. Anyway, a GroupBox control covers the selectors for an adjacent Tab control. Any thoughts or advice on how to resolve are appreciated.

Code: Select all

#SingleInstance , Force

Gui , 1:New  ,  , GroupBox Munges Tabs
Gui , 1:Margin , 8 , 8
Gui , 1:Add  , GroupBox  ,   x0008   y0008 w0256 h0032 , GroupBox Title
Gui , 1:Add  , Tab3      ,   x0016   y0032 w0240 h0080 , A|B
Gui , 1:Tab  , A
Gui , 1:Add  , Text      ,   x0024   y0072 Border      , Tabs UNDER GroupBox`nis UNexpected
Gui , 1:Tab  , B
Gui , 1:Tab
Gui , 1:Add  , Text      ,   x0128   y0032 Border      , Text OVER GroupBox`nas expected
Gui , 1:Show
return

GuiClose:
ExitApp
return
x-groupbox-munges-tabs-a.png
(6.55 KiB) Downloaded 83 times
User avatar
TheDewd
Posts: 1408
Joined: 19 Dec 2013, 11:16
Location: USA

Re: GroupBox Control Covers Tab Control

13 Sep 2018, 14:52

elmo wrote:...feels like it should have popped up somewhere.
Your feels are correct.
https://autohotkey.com/board/topic/9646 ... -groupbox/
Image Bulldozer - Sokoban inspired game from 1994 recreated in AutoHotkey.
elmo
Posts: 101
Joined: 09 Oct 2013, 09:08

Re: GroupBox Control Covers Tab Control

13 Sep 2018, 17:22

@TheDewd

Hmmm, after following the link you provided, now I "feel like" this must be a long standing issue and there is no solution. Bummer. Will move on to some other method. Thank you.
User avatar
Alguimist
Posts: 371
Joined: 05 Oct 2015, 16:41
Contact:

Re: GroupBox Control Covers Tab Control  Topic is solved

13 Sep 2018, 18:20

elmo wrote:I "feel like" this must be a long standing issue and there is no solution.
How about this:

Code: Select all

; Generated by AutoGUI 2.5.2
#SingleInstance Force
#NoEnv
SetWorkingDir %A_ScriptDir%
SetBatchLines -1

Gui Add, GroupBox, hWndhGrp x27 y15 w307 h80, GroupBox
Gui Add, Tab3, hWndhTab x70 y37 w225 h160, Tab 1|Tab 2
Gui Tab

Gui Show, w620 h420, Window

SendMessage 0xB, 0, 0,, ahk_id %hGrp% ; WM_SETREDRAW
WinSet Redraw,, ahk_id %hTab%
DllCall("SetWindowPos", "Ptr", hTab, "Ptr", 0, "Int", 0, "Int", 0, "Int", 0, "Int", 0, "UInt", 0x3)

; Or:
/*
DllCall("SetWindowPos", "Ptr", hGrp, "Ptr", hTab, "Int", 0, "Int", 0, "Int", 0, "Int", 0, "UInt", 0x3)
WinSet Redraw,, ahk_id %hTab%
*/
Return

GuiEscape:
GuiClose:
    ExitApp
elmo
Posts: 101
Joined: 09 Oct 2013, 09:08

Re: GroupBox Control Covers Tab Control

21 Sep 2018, 19:49

@Alguimist

Apologies for delay responding, just found your response and tested. Wow, that works !!! It is almost like you are an Autohotkey GUI Alchemist :bravo:

Return to “Ask For Help”

Who is online

Users browsing this forum: Aaron0824, Bing [Bot], magnus, RubbeH and 43 guests