FormatTime | ddd | showing day isn't working Topic is solved

[fohrums]

# SPECIFICATION

Code: Select all

autohotkeyahk_1.1.30
win10_home_1803.17134.285

I'm unable to show Weekday when using FormatTime (see below for example). I actually run this short ahk-code on another computer that's Win7 and it appears without problem. But, on my win10 machine it doesn't recognize it.

Code: Select all

!+2::
  FormatTime, datetime,, yyyyMMdd@HHmmss-ddd
  SendInput %datetime%
  Return

## PROBLEM:

* Date Formats aren't recognized and only Time Formats are recognized. What would cause this to happen?
+ If I were to use the script it'll output 20181002@053900-ddd when it should be 20181002@053900-TUE (notice the appending weekday)

[jeeswg]

This is the problem:
FormatTime - Syntax & Usage | AutoHotkey
https://autohotkey.com/docs/commands/FormatTime.htm

If Format contains date and time elements together, they must not be intermixed. In other words, the string should be dividable into two halves: a time half and a date half. For example, a format string consisting of "hh yyyy mm" would not produce the expected result because it has a date element in between two time elements.

Here is a workaround. Cheers.

Code: Select all

!+2::
  datetime := A_Now
  FormatTime, ddd, % datetime, ddd
  FormatTime, datetime, % datetime, yyyyMMdd@HHmmss-
  SendInput, % datetime ddd
  return

[ThewarII]

Thanks Jeeswg.
That also i want to say.
Or you also don't realy need use datetime := A_Now
Because you use current time.

Code: Select all

!+2::
FormatTime, ddd,, ddd
FormatTime, datetime,, yyyyMMdd@HHmmss-
SendInput, % datetime ddd
Return

[jeeswg]

- Hello ThewarII. What you say is true, however, if you use the approach that doesn't store the variable, and you run the script at midnight, you could get a mismatch.
- These situations are unlikely, but they do happen and are avoidable. Cheers.

[fohrums]

This is the problem (link to from FormatTime - Syntax & Usage | AutoHotkey):
https://autohotkey.com/docs/commands/FormatTime.htm
If Format contains date and time elements together, they must not be intermixed. Here is a workaround:

Code: Select all

!+2::
  datetime := A_Now
  FormatTime, ddd, % datetime, ddd
  FormatTime, datetime, % datetime, yyyyMMdd@HHmmss-
  SendInput, % datetime ddd
  return

I'd say that it was an easy mistake to not have seen this Thank-You jeeswg for you're explanation and input aswell
I would however love to see the weekday in all caps but my attempt doesn't work (i've inserted the StringUpper line):

Code: Select all

  datetime := A_Now
  FormatTime, ddd, % datetime, ddd
  FormatTime, datetime, % datetime, yyyyMMdd@HHmmss-
  StringUpper, datetime, datetime
  SendInput, % datetime ddd
  return

[jeeswg]

For upper case. 2 variants. Cheers.

Code: Select all

!+2::
  datetime := A_Now
  FormatTime, ddd, % datetime, ddd
  FormatTime, datetime, % datetime, yyyyMMdd@HHmmss-
  SendInput, % datetime Format("{:U}", ddd)
  return

;!+2::
  datetime := A_Now
  FormatTime, ddd, % datetime, ddd
  StringUpper, ddd, ddd
  FormatTime, datetime, % datetime, yyyyMMdd@HHmmss-
  SendInput, % datetime ddd
  return

[ThewarII]

- Hello ThewarII. What you say is true, however, if you use the approach that doesn't store the variable, and you run the script at midnight, you could get a mismatch.
- These situations are unlikely, but they do happen and are avoidable. Cheers.

hello, why you say that?
It also use automatic get current time like A_Now without put it in.
It only difference it get 2 times of time in very little time of second time.
And with your hand put hotkey, it's very long time of that time.
That I understand.

[jeeswg]

- The date can change between running the two FormatTime lines. This might seem minor, but it's an avoidable bug. Perhaps a daylight-saving time change could still cause an error in my script.
- The same principle, retrieving the date multiple times and hoping it will still be the same, can have more severe side effects depending on the situation.
- This fails quite regularly for example: A_Now A_MSec. As does this: A_Hour ":" A_Min ":" A_Sec.
combining date variables is unreliable - AutoHotkey Community
https://autohotkey.com/boards/viewtopic.php?f=5&t=36338

[ThewarII]

- The date can change between running the two FormatTime lines. This might seem minor, but it's an avoidable bug. Perhaps a daylight-saving time change could still cause an error in my script.
- The same principle, retrieving the date multiple times and hoping it will still be the same, can have more severe side effects depending on the situation.
- This fails quite regularly for example: A_Now A_MSec. As does this: A_Hour ":" A_Min ":" A_Sec.
combining date variables is unreliable - AutoHotkey Community
https://autohotkey.com/boards/viewtopic.php?f=5&t=36338

oh your script is longer than you showed in there
It's okay.
You need use store variables.