append callstack to handled and unhandled exceptions
Posted: 26 Oct 2018, 14:20
quoth lexikos the wise
...
However, AHK's default error dialog seems to limit the string length allotted for the exception.Extra property, thus the full callstack (as can be seen by uncommenting MsgBox % Trace in the code above) is not shown:
One could of course write their own dialog (using MsgBox or Gui) to display the info from the exception object, but then they would have to come up with a way to retrieve the lines around the one that caused the error. I imagine this would be non-trivial with compiled scripts...
For handled exceptions, you could do something like the following:
However, there are some drawbacks I haven't figured out how to work around. As lexikos said, "If you catch an exception, the stack has already unwound to your handler" so I need to retrieve the callstack before reaching the catch block. Again, as lexikos said "If you throw the exception, you can get the call stack and attach it to the exception before throwing", which is what I have done in the example above. However, how do I achieve a similar result when the error is triggered by something like %cause% := error in the first example and not an exception object I generate and throw explicitly?
If anyone has alternate ways to approach this, or has any code improvements or suggestions, I'd love to hear them!
Sincerely,
Sam.
What I'd like is for every exception object to contain the callstack that lead to the error/exception being thrown. However, I have failed to come up with a robust solution I am happy with. The only method of retrieving the callstack that I have found is Coco's nifty Traceback() function (altered a bit to suit my needs). However, it seems it does not work on compiled scripts, so there's thatlexikos wrote: ↑28 Sep 2018, 19:41You can obtain the call stack whenever you want by calling Exception in a loop as demonstrated elsewhere.
[...] If you throw the exception, you can get the call stack and attach it to the exception before throwing. If you catch an exception, the stack has already unwound to your handler, so getting it at that point might not be useful. For unhandled exceptions, you can register a callback with the new OnError function. The callback is called before the stack unwinds.
Improvements to exception handling are being planned for v2.
...
For unhandled exceptions, I have come up with this:lexikos wrote: ↑02 Feb 2015, 04:28Exception(x, some_negative_number) relies on the debugger's call stack, since AutoHotkey doesn't maintain a call stack as such just for script execution. The debugger code is omitted from AutoHotkeySC.bin, which becomes the executable part of each compiled script. Therefore, this function won't work in compiled scripts.
... with the possible exception of scripts compiled from AutoHotkey_H.exe, since they are based on a complete AutoHotkey executable.
Code: Select all
Global A_Quote:=Chr(34)
OnError("Traceback")
Main()
ExitApp
Main(){
f()
}
a() {
b()
}
b() {
c()
}
c() {
%cause% := error
}
f() {
a()
}
Traceback(exception:="",actual:=0){
i:=0, trace:="Traceback (most recent call first):`r`n", n:=actual?0:A_AhkVersion<"2"?1:2
Loop {
e:=Exception(".",offset:=-(A_Index+n))
If (e.What=offset)
Break
trace.=" File " A_Quote e.File A_Quote ", line " e.Line ", in " e.What "`r`n"
}
;MsgBox % Trace
If IsObject(exception)
{
exception.Extra.="`n`n" trace
Return 0
}
Return trace
}For handled exceptions, you could do something like the following:
Code: Select all
Global A_Quote:=Chr(34)
OnError("Traceback")
Main()
ExitApp
Main(){
try {
f()
} catch e {
ThrowMsg(16,"Error!","Exception thrown!`n`nWhat = " e.what "`nFile = " e.file "`nLine = " e.line "`nMessage = " e.message "`nExtra = " e.extra)
}
}
a() {
b()
}
b() {
c()
}
c() {
throw { what: (IsFunc(A_ThisFunc)?"function: " A_ThisFunc "()":"") A_Tab (IsLabel(A_ThisLabel)?"label: " A_ThisLabel:""), file: A_LineFile, line: A_LineNumber, message: "", extra: "`n`n" Traceback()}
}
f() {
a()
}
Traceback(exception:="",actual:=0){
i:=0, trace:="Traceback (most recent call first):`r`n", n:=actual?0:A_AhkVersion<"2"?1:2
Loop {
e:=Exception(".",offset:=-(A_Index+n))
If (e.What=offset)
Break
trace.=" File " A_Quote e.File A_Quote ", line " e.Line ", in " e.What "`r`n"
}
; MsgBox % trace
If IsObject(exception)
{
exception.Extra.="`n`n" trace
Return 0
}
Return trace
}
;;;;; Core Background Functions ;;;;;
ThrowMsg(Options="",Title="",Text="",Timeout=""){
If (Title="") AND (Text="") AND (Timeout=""){
Gui +OwnDialogs
MsgBox % Options
}
Else{
Gui +OwnDialogs
MsgBox, % Options , % Title , % Text , % Timeout
}
}If anyone has alternate ways to approach this, or has any code improvements or suggestions, I'd love to hear them!
Sincerely,
Sam.