How to insert IDs of customers as KEYS and names of customers as VALUES in an Associative Array? Topic is solved

[Sabestian Caine]

Hello Friends..


Please look at these codes-

Code: Select all

str=
(
10058	JAMES MARTIEN
920098	SABESTIAN CAINE
6500042	DAVID MAC JONESLEY
)
; The above is a very long list. Above three lines are just a sample..

for key, value in StrSplit(str, "`n")
{
	
	RegExMatch(value, "mi)(\d+)\s(\w.*)", obj)
	MsgBox % obj1 "`n" obj2
}

In the above codes, you can see that str contains a small list of customer ids and customer names. obj1 and obj2 contains the id number and customer name of each field respectively. I want to convert the data of str into associative array and then retrieve the customer id and customer name by for loop. Namely, I want that the key of array should contain the customer id and value of array should contain the name of customer. However, I can solve my purpose using obj1 and obj2, but I want to use key-value pair in associative array.

like this (Imaginary/dummy codes)-

Code: Select all

str=
(
10058	JAMES MARTIEN
920098	SABESTIAN CAINE
6500042	DAVID MAC JONESLEY
)

for key, value in StrSplit(str, "`n")
{
	
	RegExMatch(value, "mi)(\d+)\s(\w.*)", obj)
	Array:= {obj1 : obj2}
}

for key, value in Array
	msgbox % key "`n" value   ; here key should show the customer ID and value should show the name of customer

Please tell me how to do that?

Thanks a lot...

[swagfag]

Code: Select all

str=
(
10058	JAMES MARTIEN
920098	SABESTIAN CAINE
6500042	DAVID MAC JONESLEY
)

Array := {}
for key, row in StrSplit(str, "`n")
{
	CustomerInfo := StrSplit(row, "`t") ; if ur list is tab-separated, which it seemingly is
	id := CustomerInfo[1]
	name := CustomerInfo[2]
	Array[id] := name
}

for id, name in Array
	msgbox % clipboard := id ": " name

[TheDewd]

Code: Select all

#SingleInstance, Force

str =
(
10058	JAMES MARTIEN
920098	SABESTIAN CAINE
6500042	DAVID MAC JONESLEY
)

MyArray := {}

Loop, Parse, str, `n
{
	RegExMatch(A_LoopField, "mi)(\d+)\s(\w.*)", obj)
	MyArray[obj1] := obj2	
}

; Using For Loop
For CustID, CustName In MyArray {
	MsgBox, % CustID " - " CustName
}

; Using Customer ID
MsgBox, % MyArray.10058

[Sabestian Caine]

Code: Select all

#SingleInstance, Force

str =
(
10058	JAMES MARTIEN
920098	SABESTIAN CAINE
6500042	DAVID MAC JONESLEY
)

MyArray := {}

Loop, Parse, str, `n
{
	RegExMatch(A_LoopField, "mi)(\d+)\s(\w.*)", obj)
	MyArray[obj1] := obj2	
}

; Using For Loop
For CustID, CustName In MyArray {
	MsgBox, % CustID " - " CustName
}

; Using Customer ID
MsgBox, % MyArray.10058

Thanks dear TheDewd ... This is what i was wanting...

I was also very close to this. I got by here-

Code: Select all

str=
(
10058	JAMES MARTIEN
920098	SABESTIAN CAINE
6500042	DAVID MAC JONESLEY
)

a:= {}
for key, value in StrSplit(str, "`n")
{
	
	RegExMatch(value, "mi)(\d+)\s(\w.*)", obj)
	a.obj1:= obj2  ; here I was making mistake... i should have written a[obj1]:=obj2
	
}
for key, value in a
	MsgBox % key "`n" value

Anyway, Thanks you so much for your kind help and support....

Take care...

[Sabestian Caine]

Code: Select all

str=
(
10058	JAMES MARTIEN
920098	SABESTIAN CAINE
6500042	DAVID MAC JONESLEY
)

Array := {}
for key, row in StrSplit(str, "`n")
{
	CustomerInfo := StrSplit(row, "`t") ; if ur list is tab-separated, which it seemingly is
	id := CustomerInfo[1]
	name := CustomerInfo[2]
	Array[id] := name
}

for id, name in Array
	msgbox % clipboard := id ": " name

Thanks dear swagfag.... Your way of converting str to array is also great.... Thank you so much sir...

[Odlanir]

Or even shorter:

Code: Select all

str=
(
10058	JAMES MARTIEN
920098	SABESTIAN CAINE
6500042	DAVID MAC JONESLEY
)

for id, name in Array := Object(StrSplit(str, ["`n","`t"])*)
	msgbox % clipboard := id ":" name

ExitApp