How to instantly duplicate the current line (i.e. make a copy of current line & paste in next line) M S Word and Notepad Topic is solved

[Sabestian Caine]

Hello Friends..


As we can instantly duplicate the current line in Scite and AHK Studio with the help me shortcut keys like ctrl+D and f2 respectively, I want any similar way to duplicate the current line for MS Word and notepad. Presently, I have mapped the default keys to duplicate the current line. Please see these codes-

Code: Select all

send {Home}  ; brings the cursor to the starting of the line
Sleep 100
send +{End}  ; selects the entire line
Sleep 100
send ^c  ; copies the text
Sleep 100
send {down}  ; goes to the next line
Sleep 100
send ^v     ; pastes the text at next line

However, the above codes are working fine, but I want more professional way to do that. Like in scite it provides the facility to duplicate the current line by shortcut key ctrl+d and in AHK studio it has built in shortcut key f2.

Please tell me how to do this in MS Word and in Notepad?


Thanks a lot...

[FredOoo]

Code: Select all

#SingleInstance force
#Persistent

^+d::  ; Duplicate
	send {Home}  ; brings the cursor to the starting of the line
	Sleep 10
	send +{End}  ; selects the entire line
	Sleep 10
	send ^c  ; copies the text
	Sleep 10
	send {End}  ; goes to the end of line
	Sleep 10
	send {Enter}  ; creates a new line
	Sleep 10
	send ^v     ; pastes the text at next line
	return
	

But this one duplicates a line but not a paragraphe.

[pureby]

the above codes are working fine, but I want more professional way to do that. Like in scite it provides the facility to duplicate the current line by shortcut key ctrl+d and in AHK studio it has built in shortcut key f2.

Please tell me how to do this in MS Word and in Notepad?

The script you posted seems to do exactly what you want in the most efficient way. So what do you mean by "more professional way"? If you want the script to only work in Notepad (not in other apps), then you should add the following lines to the end and beginning of your script:

Code: Select all

	#IfWinActive ahk_exe C:\Windows\System32\notepad.exe
		YOUR_SCRIPT_HERE
	#IfWinActive

I hope this helps. Otherwise, please explain better what it is exactly that you want to achieve?

[Sabestian Caine]

the above codes are working fine, but I want more professional way to do that. Like in scite it provides the facility to duplicate the current line by shortcut key ctrl+d and in AHK studio it has built in shortcut key f2.

Please tell me how to do this in MS Word and in Notepad?

The script you posted seems to do exactly what you want in the most efficient way. So what do you mean by "more professional way"? If you want the script to only work in Notepad (not in other apps), then you should add the following lines to the end and beginning of your script:

Code: Select all

	#IfWinActive ahk_exe C:\Windows\System32\notepad.exe
		YOUR_SCRIPT_HERE
	#IfWinActive

I hope this helps. Otherwise, please explain better what it is exactly that you want to achieve?

Hello dear pureby...

My codes are just the mapping of inbuilt shortcut keys. They are not instantly duplicating the line and thus not showing more professional approach.

You can understand it by simple example-
Suppose, you want to insert text in some edit field then there are numerous ways to do this in autohotkey. One way is to just put your cursor in that edit field then use sendinput, some text . Second way is to use ControlSetText command which works more efficiently and professionally. I have the same concern with above codes. I hope you have understood what I mean..

Secondly, Please look at this gif-

ram4.gif (43.65 KiB) Viewed 2430 times

in the above clip you can clearly see that how instantly we can duplicate current line Scite. I want such kind of thing. I know this can be by Autohotkey, but how? don't know..

Thanks a lot..

[jeeswg]

I've been using the following:

Code: Select all

#IfWinActive ahk_class Notepad
^d:: ;notepad - send text - duplicate line
ControlGet, hCtl, Hwnd,, Edit1, A
ControlGet, vLineNum, CurrentLine,,, % "ahk_id " hCtl
ControlGet, vText, Line, % vLineNum-1,, % "ahk_id " hCtl
Control, EditPaste, % vText,, % "ahk_id " hCtl
return
#IfWinActive

#IfWinActive ahk_class OpusApp ;word
^d:: ;word - send text - duplicate line
SendInput, {Up}{Home}+{End}
oWd := ComObjActive("Word.Application")
vText := RTrim(oWd.Selection.Text, "`r`n")
SendInput, {Down}{End}
oWd.Selection.TypeText(vText)
oWd := ""
return
#IfWinActive

[Odlanir]

At the moment I got only an old Word 2003 to test it but this works in this version

Code: Select all

f8::
   oWord := ComObjActive("Word.Application")
   selection := oWord.selection
   Selection.HomeKey(wdLine:=5)
   Selection.EndKey(wdLine, wdExtend:=1)
   currentline := Selection.Range
   Selection.HomeKey(wdLine)
   Selection.TypeText(currentline.text)
return

[Sabestian Caine]

I've been using the following:

Code: Select all

#IfWinActive ahk_class Notepad
^d:: ;notepad - send text - duplicate line
ControlGet, hCtl, Hwnd,, Edit1, A
ControlGet, vLineNum, CurrentLine,,, % "ahk_id " hCtl
ControlGet, vText, Line, % vLineNum-1,, % "ahk_id " hCtl
Control, EditPaste, % vText,, % "ahk_id " hCtl
return
#IfWinActive

#IfWinActive ahk_class OpusApp ;word
^d:: ;word - send text - duplicate line
SendInput, {Up}{Home}+{End}
oWd := ComObjActive("Word.Application")
vText := RTrim(oWd.Selection.Text, "`r`n")
SendInput, {Down}{End}
oWd.Selection.TypeText(vText)
oWd := ""
return
#IfWinActive

Thanks dear jeeswg... Your codes are working almost excellent, however the codes for notepad are not working desired.... Thanks a lot sir...

[Sabestian Caine]

At the moment I got only an old Word 2003 to test it but this works in this version

Code: Select all

f8::
   oWord := ComObjActive("Word.Application")
   selection := oWord.selection
   Selection.HomeKey(wdLine:=5)
   Selection.EndKey(wdLine, wdExtend:=1)
   currentline := Selection.Range
   Selection.HomeKey(wdLine)
   Selection.TypeText(currentline.text)
return

Thank you so much dear Odlanir... these codes for ms word are working great without any issue... Thank you sir...