AutoHotkey Community

Code: Select all

#NoEnv
SetBatchLines -1
SetTitleMatchMode 2

key := "{Space}"
exe := "ahk_exe zsnesw.exe"
hwnd := WinExist(exe)
if !hwnd
{
	MsgBox Hwnd not found. Exiting.
	ExitApp
}

logFile := "zsnes.log"
log := FileOpen(logFile, "w")
OnExit("openLogFile")
openLogFile() {
	global
	log.Close()
	Run % logFile
}

Controls := ["", "ahk_parent"]
WinTitles := ["ZSNES", "ahk_class ZSNES", exe, "ahk_id " hwnd]
SendModes := ["Event", "Play", "Input"]
KeyDelays := [-1, 0, 100]
PressDurations := KeyDelays
PlayParams := ["", "Play"]

testsTotal := 1
for each, Setting in [Controls, WinTitles, SendModes, KeyDelays, PressDurations, PlayParams]
	testsTotal *= Setting.Count()

for each, ctrl in Controls
{
	for each, title in WinTitles
	{
		for each, mode in SendModes
		{
			for each, delay in KeyDelays
			{
				for each, duration in PressDurations
				{
					if (mode ~= "Event|Play")
					{
						for each, playParam in PlayParams
							test(ctrl, title, mode, delay, duration, playParam)
					}
					else
						test(ctrl, title, mode, delay, duration)
				}
			}
		}
	}
}

ExitApp
Esc::ExitApp

test(ctrl, title, mode, delay, duration, playParam := "") {
	static i := 0

	global testsTotal, key, log

	SendMode % mode
	SetKeyDelay % delay, % duration, % playParam

	MsgBox % test := Format("
	(LTrim
		Test #{} of {}
		SendMode {}
		SetKeyDelay {}, {}{}
		ControlSend, {}, {}, {}
		------------------------------------------

	)", ++i, testsTotal, mode, delay, duration
	, playParam ? ", " playParam : "", ctrl, key, title)
	
	Loop 10
		ControlSend % ctrl, % key, % title

	log.Write(test)
}