Regex help: Match everything after

[leesho]

I'm stuck and could use a push in the right direction! Given the following text:

This is garbage: This is not

I would like to be able to copy the entire line, then paste everything after the colon:

This is not

I have the following script which almost works:

Code: Select all

^!V::              ;Ctrl-Alt-V 'Special Paste'

Haystack := Clipboard
Needle := "[^:]+$"

RegExMatch(Haystack, Needle, Match)
Clipboard := Match

Send, ^V
return

The problem is, I want to paste everything after the colon and the space that follows the colon. Right now this script pastes the space, too(I've placed an underline character to illustrate the problem):

_This is not

Any help? Thanks.

[swagfag]

Code: Select all

RegExMatch("This is garbage: This is not", "[^:]*: \K.*", match)
MsgBox % match

match anything that isnt a colon, the colon, the space - discard them. match whatever is left.

[guest3456]

i tend to just capture the pattern:

Code: Select all

Haystack := "This is garbage: This is not"
Needle := ":\s(.*)$"      ; find the colon ":" and a space "\s" and then capture everything after into subpattern1
RegExMatch(Haystack, Needle, match)
MsgBox % match1         ; match1

[digidings]

Another solution with look-behind assertion:

Code: Select all

^!V::              ;Ctrl-Alt-V 'Special Paste'

Haystack := Clipboard
Needle := "(?<=:)\s*(?<Keep>.+)$"

RegExMatch(Haystack, Needle, TextTo)
Clipboard := TextToKeep

Send, ^V
return