Help for making copies from youtube pages Topic is solved

[asad41163]

Hello to all colleagues
Is there a way to make copy videos titles from the YouTube page?
So that i can translate it in google translate.
Because Google's website translation service does not work with YouTube.
Thanks in advance.

[gregster]

The title of the youtube video in the active tab is usually part of the wintitle of the browser window - that's probably the easiest way to get video title, instead of automating your browser...

[boiler]

I took it to mean that you had a results list of a search in YouTube and you wanted to extract all the titles. The following does that with YouTube results in Chrome when it is the active window. Press F1 and wait until you see the MsgBox saying it has copied the titles to the clipboard.

Code: Select all

SetTitleMatchMode, 2

#If WinActive(" - YouTube")
F1::
	Clipboard := ""
	Send, {Control down}u{Control up} ; view source
	Sleep, 2000
	Send, {Control down}ac{Control up} ; copy all
	ClipWait, 1
	HTML := Clipboard
	if ErrorLevel
	{
		SoundBeep ; error signal
		return
	}
	Send, {Control down}w{Control up}
	Needle = (?<="title":{"runs":\[{"text":")([^"]+)
	Start := 1
	TextOut := ""
	while (Found := RegExMatch(HTML, Needle, Match, Start))
	{
		TextOut .= Match1 "`n"
		Start := Found + StrLen(Match1) + 1
	}
	Clipboard := TextOut
	MsgBox,, YouTube Titles, Titles have been copied to clipboard, 2
return

There are some extraneous "titles" at the bottom that don't seem like an issue, but they could be removed if you like.

[asad41163]

Welcome, dear colleagues
Mr: gregster
I mean all the video titles on the page, not just the main video title, which is in the browser’s title bar.. Thank you very much for the fast response ..





Mr: Mr. boiler
Thank you very much, I appreciate this help and this wonderful effort .., this is exactly what I wanted..