if statement necessary here? Topic is solved

[Scr1pter]

Hey guys,

I'm back after a long AHK pause
I guess I lost some skills

Anyway, in my script I call a function and depending on the value, it should output values inside of a MessageBox.

Code: Select all

F1::
A = 212
1 = 966
letter = %A%
digit = %1%
MsgBox, %letter%, %digit%
return

F2::
Click_On_Field("A1")
return

F3::
Click_On_Field_New("A1")
return

Click_On_Field(field)
{
  StringTrimLeft, digit, field, 1
  StringTrimRight, letter, field, 1
  
  if letter = A
  {
    letter = 212
  }
  if letter = B
  {
    letter = 329
  }
  if digit = 1
  {
    digit = 966
  }
  if digit = 2
  {
    digit = 855
  }
  
  MsgBox, %letter%, %digit%
}

Click_On_Field_New(field)
{
  StringTrimLeft, digit, field, 1
  StringTrimRight, letter, field, 1
  A = 212
  1 = 966
  MsgBox, %letter%, %digit%
}

The 1st function works, but is there a way that I can omit the if statement to get the same results, like I tried in the 2nd function?
The F1 and the F2 script show the correct result.
F3 only shows A and 1, but not the values which are assigned to them.

How to code the F3 script so that it shows 212 and 966 instead of A and 1?
Or is the if block really necessary?

Thanks for any help!

[Hellbent]

This?

Code: Select all

Click_On_Field(field)
{
  	StringTrimLeft, digit, field, 1
  	StringTrimRight, letter, field, 1
	letter := ( letter = "A" ) ? ( 212 ) : ( letter = "B" ) ? ( 329 ) : ( "" ) 
	digit := ( digit = 1 )?( 966 ):(digit = 2 ) ? ( 855 ) : ( "" )   
  	MsgBox, %letter%, %digit%
}

Also, i'd advise against using simple numbers as variable names.

[Xtra]

Code: Select all

F3::Click_On_Field("A1")

Click_On_Field(field)
{
    static fields := {A1: "212,966", A2: "212,855", B1: "329,966", B2: "329,855"}
    ;~ Click % fields[field]
    MsgBox % fields[field]
}

[guest3456]

F3 only shows A and 1, but not the values which are assigned to them.

How to code the F3 script so that it shows 212 and 966 instead of A and 1?

you need a double-deref.

dereferencing %letter% only returns "A", so we need to then deref the result of that. you can think of it like %(%letter%)%. but, that syntax is invalid in AHK

here are 3 examples of working syntax:

Code: Select all

Click_On_Field_New(field)
{
  StringTrimLeft, digit, field, 1
  StringTrimRight, letter, field, 1
  A = 212
  1 = 966
  MsgBox, % %letter% . "-" . %digit%

  lettervalue := %letter%
  digitvalue := %digit%
  MsgBox, %lettervalue% - %digitvalue%

  lettervalue2 = % %letter%
  digitvalue2 = % %digit%
  MsgBox, %lettervalue2% -- %digitvalue2%
}

all of your code uses regular old style assignments with =, rather than expression assignements with :=, so probably the last example is what you want

[Scr1pter]

Thank you, guys!

Xtra's idea is interesting, however, it would require that I'll do it for all 64 fields.
For this reason I used the A - H and 1 - 8 way.
By combining them, I'll achieve all 64 fields (8x8)

guest3456's post makes sense too, however, I chose Hellbent's code.
Works perfectly - I'll write down this method.

Cheers!