[SOLVED] Calling function with SetTimer

[vasili111]

How to make this work?

Code: Select all

a := 12
SetTimer, z(a), -0

z(a)
{
	MsgBox, % a
}

[ameyrick]

Code: Select all

a := 12
SetTimer, z, -0
Return

z:
SetTimer, z, off
result := z(a)
Return

z(a)
{
	MsgBox, % a
}

[tmplinshi]

Code: Select all

#Persistent

a := 12
fn := Func("z").Bind(a)
SetTimer, %fn%, -0

z(a)
{
    MsgBox, % a
}

Code: Select all

#Persistent

a := 12
fn := ObjBindMethod(myClass, "z", a, "bbb")
SetTimer, %fn%, -0

class myClass {
	z(a, b) {
		MsgBox, % a "`n" b
	}
}

[vasili111]

Thank you for help
Solved.

[Guest10]

what are the advantages of tmplinshi's over ameyrick's. tmplinshi's looks overly complicated!

[vasili111]

what are the advantages of tmplinshi's over ameyrick's. tmplinshi's looks overly complicated!

At that time I need to directly call function in SetTimer without label so tmplinshi's examples at that situation are very useful. I need to use SetTimer inside another function.

[Guest10]

when i run this, it says:
Error: Target label does not exist.
---> SetTimer, %fn%, -0
The current thread will exit.

Code: Select all

#Persistent
#SingleInstance Force
#NoEnv

a := 12
fn := Func("z").Bind(a)
SetTimer, %fn%, -0

z(a)
{
    MsgBox, % a
}

[tmplinshi]

when i run this, it says:
Error: Target label does not exist.
---> SetTimer, %fn%, -0
The current thread will exit.

Code: Select all

#Persistent
#SingleInstance Force
#NoEnv

a := 12
fn := Func("z").Bind(a)
SetTimer, %fn%, -0

z(a)
{
    MsgBox, % a
}

Requires AutoHotkey v1.1.20+.

[Guest10]

thanks, upgraded AHK from 19 to 22, and now it works!

[pk23]

Code: Select all

#Persistent

a := 12
fn := Func("z").Bind(a)
SetTimer, %fn%, -0

z(a)
{
    MsgBox, % a
}

Code: Select all

#Persistent

a := 12
fn := ObjBindMethod(myClass, "z", a, "bbb")
SetTimer, %fn%, -0

class myClass {
	z(a, b) {
		MsgBox, % a "`n" b
	}
}

only login for saying thank you!