Close all scripts except two?

[scriptor2016]

Greetings all

Using a seperate script (I will call this the "Master" script), I want to be able to shut down all running scripts except two of them. These two are:

1. The "Master" script itself
2. "MyScript.ahk"

Maybe it would look something like this:

Code: Select all

;Master.ahk

z::
Keep "Master.ahk" alive ;which is in essence this script
Keep "MyScript.ahk" alive
Close all other running scripts
Return

I have some code which is able to keep "Master.ahk" alive but closes all other scripts. I'm unable to find a way to keep one additional script alive as well before closing the rest.

[gregster]

I imagine that showing said code could help potential helpers to help you (faster)...

[scriptor2016]

whoops, sorry!! Geez I totally meant to follow up with the code but got distracted..

Code: Select all

keepIT := "Master.ahk" ;keep this script alive but close all others
for process in ComObjGet("winmgmts:").ExecQuery("Select * from Win32_Process where name = 'Autohotkey.exe' and not CommandLine like '%" keepIT "%' ")
process, close, % process.ProcessId

I didn't write this, in fact I can't remember where it came from but it closes all other scripts except Master.ahk

[gregster]

No problem - but that should help. Try

Code: Select all

keepIT := "Master.ahk" ;keep this script alive but close all others
keepIT2 := "MyScript.ahk"

for process in ComObjGet("winmgmts:").ExecQuery("Select * from Win32_Process where name = 'Autohotkey.exe' 
and not (CommandLine like '%" keepIT "%' or Commandline like '%" keepIT2 "%')")
	process, close, % process.ProcessId			; or for testing: msgbox % process.ProcessId " " process.CommandLine

Edit: script names fixed.

[teadrinker]

Another approach:

Code: Select all

DetectHiddenWindows, On
SetTitleMatchMode, RegEx
WinGet, ahkWindows, List, ahk_class ^AutoHotkey$,, i)Master.ahk|MyScript.ahk
Loop % ahkWindows
   WinKill, % "ahk_id " . ahkWindows%A_Index%

[scriptor2016]

Thanks guys!

I tested both approaches and they both work perfectly.