RegExMatch with Mode 3 returns 0 occurances in string Topic is solved

[BurnerPhone]

Code: Select all

String =
(
Lorem. ipsum dolor. sit 
amet, consectetur. 
adipiscing elit, sed. do 
eiusmod.
)

RegExMatch(String, "O)\.", dotArray)
numberOfDots := dotArray.Count()
msgbox % numberOfDots ; returns 0

Trying to count dots in clipboard and it always returns 0. Can't understand why it's not working.
Got a string with dots - check
Escaped dot as regex pattern - check
Array with mode 3 to return .count - check

Can anyone point out what's wrong?

[HotKeyIt]

You need to use () for subpattern:

Code: Select all

String =
(
Lorem. ipsum dolor. sit 
amet, consectetur. 
adipiscing elit, sed. do 
eiusmod.
)

RegExMatch(String, "O)(\.)?.*(\.)?.*(\.)?.*(\.)?.*(\.)?.*(\.)?.*(\.)?.*(\.)?.*", dotArray)
numberOfDots := dotArray.Count()
msgbox % numberOfDots ; returns 0

[teadrinker]

Code: Select all

String =
(
Lorem. ipsum dolor. sit 
amet, consectetur. 
adipiscing elit, sed. do 
eiusmod.
)

RegExReplace(String, "\.",, numberOfDots)
msgbox % numberOfDots

[teadrinker]

Or

Code: Select all

StrReplace(String, ".",, numberOfDots)
msgbox % numberOfDots

[BurnerPhone]

You need to use () for subpattern:

Code: Select all

String =
(
Lorem. ipsum dolor. sit 
amet, consectetur. 
adipiscing elit, sed. do 
eiusmod.
)

RegExMatch(String, "O)(\.)?.*(\.)?.*(\.)?.*(\.)?.*(\.)?.*(\.)?.*(\.)?.*(\.)?.*", dotArray)
numberOfDots := dotArray.Count()
msgbox % numberOfDots ; returns 0

Thank you for the answer.
But why it returns as much patters as you've posted inside RegExNeedle rather than dot count?
It returns 8, and there's only 5 dots in String.

[BurnerPhone]

Or

Code: Select all

StrReplace(String, ".",, numberOfDots)
msgbox % numberOfDots

Haven't thought about using replace function without replace itself.
Thanks!
Still, I don't understand why RegExMatch doesn't work

[boiler]

Still, I don't understand why RegExMatch doesn't work

As HotKeyIt pointed out, it’s because you haven’t identified any subpatterns.

Match.Count(): Returns the overall number of subpatterns.

Even if you put parentheses around it, it wouldn’t give you a count because that just provides one matching subpattern. It is a count of the number of subpatterns that matched as in HotKeyIt’s example. RegExMatch doesn’t find multiple matches at once, so the count wouldn’t be multiple.

[teadrinker]

To get all occurences of the pattern you have to use a cycle:

Code: Select all

String =
(
Lorem. ipsum dolor. sit 
amet, consectetur. 
adipiscing elit, sed. do 
eiusmod.
)
res := []
while RegExMatch(String, "O)\.", m, m ? m.Pos + m.Len : 1)
   res.Push(m[0])
MsgBox, % res.Count()