Different images gives same MD5 - why? Topic is solved

[Albireo]

From a PDF file, 3 different images are identified and created. (in this case logo, text, and ...)
One image is in jpg format and the two other is in ppm format.
the two ppm files is converted to jpg (with irfanView cmd)
Then the MD5-values is read on this three files - but all three got the same MD5-value.
how? / why?

Code: Select all

	Loop Files, % temp.dir "\" tmpImage.name "-" temp.allJpg, F
	{	tmpImage["name" A_Index] := A_LoopFileName
		tmpImage["md5_" A_Index] := Calc_MD5(A_LoopFileName)
		MsgBox ,, %A_ScriptName% - Rad %A_LineNumber%, % A_LoopFileName "`n" Calc_MD5(A_LoopFileName)
	}

function Calc_MD5

Code: Select all

Calc_MD5(_VarAddress )
{	; Version 16 nov 2020
	; https://autohotkey.com/board/topic/77408-md5-function-for-comparing-images/
	; By Rseding91
	Static Hex = "123456789ABCDEF0"
	
	FileGetSize _VarSize, % _VarAddress
	Ptr := A_PtrSize ? "Ptr" : "Uint"
	, VarSetCapacity(MD5_CTX,104,0)
	, DllCall("advapi32\MD5Init",Ptr,&MD5_CTX)
	, DllCall("advapi32\MD5Update",Ptr,&MD5_CTX,Ptr,_VarAddress,"UInt",_VarSize)
	, DllCall("advapi32\MD5Final",Ptr,&MD5_CTX)

	Loop,16
		N := NumGet( MD5_CTX,87+A_Index,"Char"), MD5 .= SubStr(Hex,N>>4,1) . SubStr(Hex,N&15,1)
	Return MD5
}

[Smile_]

Is there a possibility to share these images?

[teadrinker]

The function is wrong, check here.
Perhaps this one is correct:

Code: Select all

filePath := "D:\Images\MyPicture.png"
File := FileOpen(filePath, "r")
File.Pos := 0
File.RawRead(buff, len := File.Length)
File.Close()

MsgBox, % Calc_MD5(&buff, len)

Calc_MD5(pData, size)
{
   VarSetCapacity(MD5_CTX, 104, 0)
   DllCall("advapi32\MD5Init", "Ptr", &MD5_CTX)
   DllCall("advapi32\MD5Update", "Ptr", &MD5_CTX, "Ptr", pData, "UInt", size)
   DllCall("advapi32\MD5Final", "Ptr", &MD5_CTX)
   loop 16
      md5 .= Format("{:02x}", *(&MD5_CTX + 87 + A_Index))
   Return md5
}

[Albireo]

Thank you!
I don't know how to handle buff / &buff - what happens?

Is it possible to put open / close the file in the function() Calc_MD5? (like this)

Code: Select all

Calc_MD5(file)
{	File := FileOpen(file, "r")
	File.Pos := 0
	File.RawRead(buff, len := File.Length)
	File.Close()

   VarSetCapacity(MD5_CTX, 104, 0)
   DllCall("advapi32\MD5Init", "Ptr", &MD5_CTX)
   DllCall("advapi32\MD5Update", "Ptr", &MD5_CTX, "Ptr", pData, "UInt", size)
   DllCall("advapi32\MD5Final", "Ptr", &MD5_CTX)
   loop 16
      md5 .= Format("{:02x}", *(&MD5_CTX + 87 + A_Index))
   Return md5
}

( the use of Calc_MD5 can be performed with only one instruction )

[teadrinker]

Code: Select all

Calc_MD5(filePath)
{	
   File := FileOpen(filePath, "r")
   File.Pos := 0
   File.RawRead(buff, len := File.Length)
   File.Close()

   VarSetCapacity(MD5_CTX, 104, 0)
   DllCall("advapi32\MD5Init", "Ptr", &MD5_CTX)
   DllCall("advapi32\MD5Update", "Ptr", &MD5_CTX, "Ptr", &buff, "UInt", len)
   DllCall("advapi32\MD5Final", "Ptr", &MD5_CTX)
   loop 16
      md5 .= Format("{:02x}", *(&MD5_CTX + 87 + A_Index))
   Return md5
}

[Albireo]

Yes!
But how can I get a MD5-value if the image is missing?
Now it always seems to be d41d8cd98f00b204e9800998ecf8427e When the image is missing.
Would have been better if the MD5 value became 0 or nothing.

Maybe like this

Code: Select all

Calc_MD5(filePath)
{	; Version 8 maj 2021
	; https://www.autohotkey.com/boards/viewtopic.php?f=76&t=90278&p=398512#p398512
	; By teadrinker
   If !FileExist(filepath)
		Return "0"
		
	File := FileOpen(filePath, "r")
   File.Pos := 0
   File.RawRead(buff, len := File.Length)
   File.Close()

   VarSetCapacity(MD5_CTX, 104, 0)
   DllCall("advapi32\MD5Init", "Ptr", &MD5_CTX)
   DllCall("advapi32\MD5Update", "Ptr", &MD5_CTX, "Ptr", &buff, "UInt", len)
   DllCall("advapi32\MD5Final", "Ptr", &MD5_CTX)
   loop 16
      md5 .= Format("{:02x}", *(&MD5_CTX + 87 + A_Index))
   Return md5
}

[teadrinker]

As I understand, d41d8cd98f00b204e9800998ecf8427e is a md5 of an empty buffer.