RegExMatch with multiple subpatterns

[T-Rock]

Hi there,

I try to come along with RegExMatch, but I don't get it ...

Code: Select all

; here is the string:
str := "W12345.12 blablabla bla M00000.00 bla"

; the RegExMatch captures only the first subpattern:
FileAppend, % RegExMatch(str, "([WM][0-9]{5}\.[0-9]{2})", Match) ; shows 1 because RegExMatch found something
FileAppend, % Match1 "`n", * ; shows W12345.12
FileAppend, % Match2 "`n", * ; is empty but should be M00000.00

I can't figure out, what's missing ...

[mikeyww]

What's missing: another pattern enclosed in parentheses.

Code: Select all

str := "W12345.12 blablabla bla M00000.00 bla", RegExMatch(str, "([WM].+?) .*([WM].+?) ", match)
Send %match1% %match2%

[T-Rock]

Hi mikeyww,

thanks for the quick response and your solution.
I have many of those strings, in which the number of these substrings (like W12345.67) can vary.
So instaed of having the same number of subpatterns, is there a way to define one general pattern which matches all the substrings?
That was my first intention to do so ...

[teadrinker]

Code: Select all

str := "W12345.12 blablabla bla M00000.00 bla"

MsgBox, % res := RTrim( RegExReplace(str, "s).*?([WM]\d{5}\.\d{2}).*?(?=(?1)|$)", "$1`n"), "`n" )

arr := StrSplit(res, "`n")
for k, v in arr
   MsgBox, % v

[mikeyww]

Here is one way-- but not as nice as teadrinker's (or maybe I stole this from teadrinker earlier...)!

Code: Select all

str := "W12345.12 blablabla bla M00000.00 bla"
While pos := RegExMatch(str, "[WM].+?(?= )", match, pos ? pos + 1 : 1)
 Send %match%`n

[T-Rock]

Thank you very much for your help mikeyww and teadrinker.
I was just thinking I should loop through the string by splitting it with the space as delimiter and use always one pattern for these substrings.

That gives me some homework to understand what your solutions are actually doing ...

[mikeyww]

That would work, too; you could use Loop. You are seeing something comparable in the examples here, though teadrinker's looks at the sequences of digits and dots.