Strange object behavior with dynamic name Topic is solved

[doubledave22]

How is Test_Object visible when we call it with a dynamic name of %name%_Object and not visible when we call it directly like Test_Object. It even breaks if we call both in a row. I expect the dynamic call to also fail but it doesnt for some reason. Bug or intended?

Code: Select all

#SingleInstance Force

Build_Object()

return

Build_Object()
{
	global
	
	Test_Object := { Test1: "Red", Test2: "Yellow"}
}

^t::
Test_Object()
return

Test_Object()
{ 
	name := "Test"
	
	msgbox, % %name%_Object.Test1 ; will display "Red" ?? how
	;~ msgbox, % Test_Object.Test1  ; no output
}

this is the "common source of confusion" isnt it... i feel silly

[boiler]

You have a problem with your premise. Neither works in your function as you currently have it because of variable scope. If you make the function global, then both work.

[mikeyww]

I found this interesting because the following displays, "Red".

Code: Select all

Build_Object(), Test_Object()

Build_Object()
{
	global
	Test_Object := { Test1: "Red", Test2: "Yellow"}
}

Test_Object()
{ 
	name := "Test"
	msgbox, % %name%_Object.Test1
}

[doubledave22]

No i understand that. I don't want the object to be global however in the example I posted I am getting "Red" in the message box. Running Version 1.1.33.02. So am I not crazy?

[doubledave22]

Same behavior on regular variables as well:

Code: Select all

Build_Object(), Test_Object()

Build_Object()
{
	global
	Test_Var := "Hello"
}

Test_Object()
{ 
	name := "Test"
	msgbox, % %name%_Var
}

[boiler]

Both MsgBoxes display "Red":

Code: Select all

#SingleInstance Force

Build_Object()

return

Build_Object()
{
	global
	
	Test_Object := { Test1: "Red", Test2: "Yellow"}
}

^t::
Test_Object()
return

Test_Object()
{ 
	global
	name := "Test"
	
	msgbox, % %name%_Object.Test1
	msgbox, % Test_Object.Test1
}

[teadrinker]

Within a function (unless force-local mode is in effect), any dynamic variable reference such as Array%i% always resolves to a local variable unless no variable of that name exists, in which case a global is used if it exists.