[solved] Edit: activate label only if it user have changed it

[Azevedo]

Hi,

In the example below, how do I check if the edit has modified by the user?
The edit may have been changed via code (another part of the program) and I want to trigger MyLabel only if the user has typed something in it.

Code: Select all

Gui, Add, Edit, vMyTxt gMyLabel

MyLabel:
 ; how do I check if the user typed something?
return

Thanks

[TLM]

Actually what you have will trigger the label every time something is typed into the control

Code: Select all

Gui, Add, Edit, vMyTxt gMyLabel
Gui, Show
Return

MyLabel:
GuiControlGet, Text,, MyTxt
msgbox % Text
Return

GuiClose:
ExitApp

[Azevedo]

"MyTxt" can be changed either by the user input OR by a function/label in the script. I only want "MyLabel" to be triggered when the user inputs.

[gilliduck]

It's not elegant, but it may be a starting point for you. One of the more experienced people on here will probably have a cleaner method of doing so, but here's what I came up with quickly.

Code: Select all

#SingleInstance, Force

EditText := "Initial Text"

Gui, Font, s14
Gui, Add, Edit, vEdit1 gMyLabel, % EditText
Gui, Add, Button, gChange, Auto Change Text
Gui, Show
Return

GuiClose:
ExitApp

MyLabel:
GuiControlGet, Edit1
If (Edit1 != EditText)
	MsgBox % "Label Changed"
Return

Change:
EditText := "New Text"
GuiControl,,Edit1, % EditText
Return

[Azevedo]

I'll use that.
Thanks gilli

[just me]

Code: Select all

#NoEnv
Edit1Label := "MyLabel"
Gui, Add, Edit, w400 vEdit1 g%Edit1Label%, Initial Text!
Gui, Add, Button, gChange, Auto Change Text
Gui, Show, , Test
Return

GuiClose:
ExitApp

MyLabel:
GuiControlGet, Edit1
MsgBox, 0, %A_ThisLabel%, %Edit1%
Return

Change:
GuiControl, -g, Edit1
GuiControl, , Edit1, Changed by %A_ThisLabel%!
GuiControl, +g%Edit1Label%, Edit1
Return

[Azevedo]

Thanks!