is there anything wrong with this script?

[zxibs]

i just wanna try moving the mouse left and right smoothly 7 times using send mode input

Code: Select all

SendMode Input
1::a
2::d

direction := true
Rcount := 0
Lcount := 0
Dcount := 0

c::
Loop
 {
   if direction
     {
       direction = false
       Loop
         {
           Lcount = Lcount - 1
           MouseMove, %Lcount%, 0, 0, R 
           Sleep, 25
         } Until Lcount = -150
       Dcount = Dcount + 1
     }
   else if (direction = false)
     {
       direction = true
       Loop
         {
           Rcount = Rcount + 1
           MouseMove, %Rcount%, 0, 0, R 
           Sleep, 25
         } Until Rcount = 150
       Dcount = Dcount + 1
     }
 } until Dcount = 7
return

[mikeyww]

If the script works, then there is nothing wrong with it. Lines 5-8 are unreachable and will never execute. You can prove that by inserting some additional display or MsgBox lines there.

If "direction" is null, then it is neither "true" nor "false". Case in point:

Code: Select all

2::d

direction := false

c::
If (direction = false)
 Send x
Return

Explained: auto-execute

[zxibs]

If the script works, then there is nothing wrong with it. Lines 5-8 are unreachable and will never execute. You can prove that by inserting some additional display or MsgBox lines there.

If "direction" is null, then it is neither "true" nor "false". Case in point:

Code: Select all

2::d

direction := false

c::
If (direction = false)
 Send x
Return

Explained: auto-execute

yeah the loop works but it doesn't move my mouse

[Rohwedder]

Hallo,
is this how it should work?:

Code: Select all

SendMode Input
direction := true
Dcount := 0
Return
1::a
2::d
c::
Loop
{
	if direction
	{
		direction := false
		Lcount := 0
		Loop
		{
			Lcount := Lcount - 1
			MouseMove, -1, 0, 0 , R
			Sleep, 25
		}
		Until Lcount = -150
		Dcount := Dcount + 1
	}
	else if (direction = false)
	{
		direction := true
		Rcount := 0
		Loop
		{
			Rcount := Rcount + 1
			MouseMove, 1, 0, 0, R
			Sleep, 25
		}
		Until Rcount = 150
		Dcount := Dcount + 1
	}
}
until Dcount = 7
return

[zxibs]

it finally worked here's the script

Code: Select all

SendMode Input
direction := true
Rcount := 0
Lcount := 0
Dcount := 0
return

c::
Loop
 {
   if direction
     {
       Loop
         {
           Lcount := Lcount - 1
           MouseMove, %Lcount%, 0, 0, R 
           Sleep, 25
         } Until Lcount = -25
       Lcount := 0
       Dcount := Dcount + 1
       direction := false
     }
   else if (direction = false)
     {
       Loop
         {
           Rcount := Rcount + 1
           MouseMove, %Rcount%, 0, 0, R 
           Sleep, 25
         } Until Rcount = 25
       Rcount := 0
       Dcount := Dcount + 1
       direction := true
     }
 } until Dcount = 7

Rcount := 0
Lcount := 0
Dcount := 0
direction := true

return

1::a
2::d

^E::ExitApp

[Rohwedder]

Just a suggestion. Use A_Index

Code: Select all

SendMode Input
direction := true
return

c::
Loop, 7 ;Dcount
{
	if direction
	{
		Loop, 25 ;Lcount
		{
			MouseMove, -A_Index, 0, 0, R
			Sleep, 25
		}
	}
	else
	{
		Loop, 25 ;Rcount
		{
			MouseMove, A_Index, 0, 0, R
			Sleep, 25
		}
	}
	direction := !direction
}
direction := true
return

1::a
2::d

^E::ExitApp