Get TimeZone time from Google Topic is solved

[rc76]

I understand there is way to compute the time for specific timezone by manually add/minus UTC time.

However there are cases with Day Light Savings, and its rules may change from time to time.

I am wondering, whether it is possible to compute the time for a specific city/timezone directly from Internet/Google?

For example:

00.png (135.72 KiB) Viewed 1269 times

[mikeyww]

Code: Select all

MsgBox, 64, Tokyo time   , % time("Asia/Tokyo")
MsgBox, 64, New York time, % time("America/New_York")

time(area) {
 WinHttp := ComObjCreate("WinHttp.WinHttpRequest.5.1")
 WinHttp.Open("GET", "http://worldtimeapi.org/api/timezone/" area, false), WinHttp.Send()
 RegExMatch(WinHttp.ResponseText, """datetime"":.+?T\K[\d:]+", time)
 Return time
}

[rc76]

This works perfectly! Thank you @mikeyww

[KingPresLii]

Code: Select all

MsgBox, 64, Tokyo time   , % time("Asia/Tokyo")
MsgBox, 64, New York time, % time("America/New_York")

time(area) {
 WinHttp := ComObjCreate("WinHttp.WinHttpRequest.5.1")
 WinHttp.Open("GET", "http://worldtimeapi.org/api/timezone/" area, false), WinHttp.Send()
 RegExMatch(WinHttp.ResponseText, """datetime"":.+?T\K[\d:]+", time)
 Return time
}

this only gives time, how to show date like september 6, 2022. please?

[mikeyww]

Code: Select all

tokyo := dateTime("Asia/Tokyo")
ny    := dateTime("America/New_York")
MsgBox, 64, Tokyo time   , % dateFix(tokyo.date) "`n`nat`n`n" tokyo.time
MsgBox, 64, New York time, % dateFix(ny.date)    "`n`nat`n`n" ny.time

dateTime(area) {
 WinHttp := ComObjCreate("WinHttp.WinHttpRequest.5.1")
 WinHttp.Open("GET", "http://worldtimeapi.org/api/timezone/" area, false), WinHttp.Send()
 RegExMatch(WinHttp.ResponseText, """datetime"":""([\d-]+)T([\d:]+)", m)
 Return {date: m1, time: m2}
}

dateFix(date) {
 FormatTime, date, % StrReplace(date, "-"), MMMM d, yyyy
 Return date
}

[BoBo]

viewtopic.php?f=10&t=35122
viewtopic.php?f=10&t=35108
viewtopic.php?f=5&t=28355

JFTR.