overriding inherited property with value Topic is solved

[sirksel]

I know one can override a calculated property in a subclass by simply redefining the calculated property. Is there any way to revert back from a calculated to non-calculated property (value property or member access or whatever the correct term is)? I've tried various ways, but I keep getting the "property is read-only error". I'm guessing there's a way to do this, but I haven't figured it out. Illustrative code below:

Code: Select all

class top {
  someprop => 'somecalc'
  ; and other features
}
class special extends top {
  someprop := ''
  __new(val) {
    this.someprop := val
  }  ;wants to override someprop but keep other features of top
}
s := special.new(10)
msgbox s.someprop

Any help would be much appreciated!

[swagfag]

yes, use .DefineProp()

[FredOoo]

Code: Select all

class top {
  someprop => 'somecalc'
}

class special1 extends top {
  __new(val) {
    this._someprop := val
  }
  someprop => this._someprop
  test() => super.someprop ; if top.someprop is still there
}
print "== s1 =="
s1 := special1.new(10)
print s1.someprop   ; 10
print s1.test()     ; someprop

class special2 extends top {
  __new(val) {
    this.DefineProp( 'someprop', { Value: val } )
  }
  test() => super.someprop
}
print "== s2 ==" ; ★ no need of _someprop ★
s2 := special2.new(10)
print s2.someprop   ; 10
print s2.test()     ; someprop

 

print

Code: Select all

print( text:='' ){
    static stdOut := 0
    if !stdOut {
        ;; Open
        dllCall("AllocConsole")
        stdOut := fileOpen("*", "w `n")
        ;; Move
        hwnd := dllCall("GetConsoleWindow")
        winWait( 'ahk_id ' hwnd )
        winMove( 0, 0,,, 'ahk_id ' hwnd )
        ;; Title
        splitPath a_ScriptName,,,, o_NameNoExt
        title := o_NameNoExt " • Print"
        BUFFER := BufferAlloc( 2*(strLen( title ))+1 )
        strPut( title, BUFFER.ptr )
        dllCall("SetConsoleTitle", 'Ptr',BUFFER.ptr )
        ;; Close
        onClose := callbackCreate(()=>(a_IconHidden:=true),'F',0)
        dllCall("SetConsoleCtrlHandler", 'Ptr',onClose, 'Int',true)
    }
    stdOut.writeLine( text )
    stdOut.read(0) ;flush
}