Zwei Fenster per Hotkey verstecken und wieder sichtbar machen

Stelle Fragen zur Programmierung mit Autohotkey

Moderator: jNizM

hansherb
Posts: 4
Joined: 07 Jun 2018, 05:48

Zwei Fenster per Hotkey verstecken und wieder sichtbar machen

15 Mar 2019, 08:50

Hallo zusammen, :)

ich habe ein kleines Problem. Es geht um ein Skript welches per Hotkey ein bestimmtes Fenster einer Anwendung versteckt
und wieder sichtbar macht.
Das Script fuktioniert super! Jetzt wollte ich es erweitern sodas es mit dem einen Tastendruck zwei Fenster (werden durch ProcessExe := "" festgelegt)
versteckt und wieder sichtbar macht. Leider funktioniert es nicht.. Könnte mir bitte jemand helfen?

Code: Select all

#NoEnv
SetBatchLines, -1

ProcessExe := "#32770" && "Class 2" ; mit einer classe funktioniert es.. wie füge ich eine zweite hinzu?


HiddenWindows := [] ; leeres Array für die IDs der versteckten Fenster anlegen
Return
; ================================================================================================================================
; Hide - sichtbare Fenster der Anwendung verstecken
; ================================================================================================================================
F8::
DetectHiddenWindows, Off ; nur zur Verdeutlichung, ist Standard
While (WinID := WinExist("ahk_class " . ProcessExe))
{
   WinHide
   HiddenWindows.Push(WinID) ; WinID an das HiddenWindows Array anhängen
}
Return
; ================================================================================================================================
; Show - versteckte Fenster wieder anzeigen
; ================================================================================================================================
F9::
DetectHiddenWindows, On
For Each, WinID In HiddenWindows
   If WinExist("ahk_id " . WinID)
      WinShow
HiddenWindows := [] ; Array leeren
Return
Vielen Dank


Grüße
wolf_II
Posts: 2425
Joined: 08 Feb 2015, 20:55

Re: Zwei Fenster per Hotkey verstecken und wieder sichtbar machen

15 Mar 2019, 08:58

Versuch mal:

Code: Select all

#NoEnv
SetBatchLines, -1

ProcessExe := ["#32770", "Class 2"] ; füge eine zweite hinzu mit array


HiddenWindows := [] ; leeres Array für die IDs der versteckten Fenster anlegen
Return
; ================================================================================================================================
; Hide - sichtbare Fenster der Anwendung verstecken
; ================================================================================================================================
F8::
DetectHiddenWindows, Off ; nur zur Verdeutlichung, ist Standard
for each, P in ProcessExe
    While (WinID := WinExist("ahk_class " . P))
    {
       WinHide
       HiddenWindows.Push(WinID) ; WinID an das HiddenWindows Array anhängen
    }
Return
; ================================================================================================================================
; Show - versteckte Fenster wieder anzeigen
; ================================================================================================================================
F9::
DetectHiddenWindows, On
For Each, WinID In HiddenWindows
   If WinExist("ahk_id " . WinID)
      WinShow
HiddenWindows := [] ; Array leeren
Return
Ich hoffe das hilft.

Return to “Ich brauche Hilfe”

Who is online

Users browsing this forum: No registered users and 7 guests