WheelUp-, WheelDown-Hotkey wegen defektem Scrollrad - V2 Topic is solved

[divanebaba]

Hallo.
Das Scrollrad meiner Maus ist defekt. Beim Scrollen scrollt es manchmal kurz in die andere Richtung.
Zum Beheben dieses Problems habe ich folgenden Code geschrieben.
Die Variablendeklarierung ist überraschenderweise ziemlich kompliziert gewesen und ich habe sie folgendermaßen gelöst.

Funktion des Scripts ist ganz einfach.
Wenn zuvor in eine bestimmte Richtung gescrollt wurde, wird ein einzelnes entgegengesetztes Signal einfach verschluckt.
Variable "dd2" wird wie eine Art Merker verwendet.

Code: Select all

global dd := "d"
global dd2 := "d"

$WheelDown::
{
global dd := "d"
if (dd = "d" && dd2 = "d")
	sendinput "{Wheeldown}"
global dd2 := "d"
}

$WheelUp::
{
global dd := "u"
if (dd = "u" && dd2 = "u")
	sendinput "{WheelUp}"
global dd2 := "u"
}

Ich finde den Code, auch wenn er bisher reibungslos funktioniert, irgendwie seltsam und wüsste gerne, wie man professioneller mit diesen "globalen" Variablen umgeht.

[Nussbeisser]

Hallo,
Ich wäre bei der Variablen so vorgegangen:

Code: Select all

 dd := "d"
dd2 := "d"

$WheelDown::
{
global
dd := "d"
if (dd = "d" && dd2 = "d")
	sendinput "{Wheeldown}"
dd2 := "d"
}

$WheelUp::
{
global
dd := "u"
if (dd = "u" && dd2 = "u")
	sendinput "{WheelUp}"
dd2 := "u"
}

[divanebaba]

Hallo @Nussbeisser.
Dein Vorschlag sieht besser aus und funktioniert, soweit ich das erkennen kann, genausogut.
Vielen Dank.

[just me]

Moin,

in v2 sind auch Hotkeyroutinen Funktionen. Man kann sie für mehrere Hotkeys 'stacken' und mit eigenen statischen Variablen ausstatten.

Code: Select all

#Requires AutoHotkey v2.0

$WheelDown::
$WheelUp::
{
   Static PreviousWheel := ""
   If (PreviousWheel = ThisHotkey)
      Send("{" . SubStr(ThisHotkey, 2) . "}")
   PreviousWheel := ThisHotkey
}

Ist das nicht wunderbar?
(Kein falscher Neid, in v1 könnte man das ähnlich lösen)

[Noitalommi_2]

Hi.

In dem Fall könnte man die statische Variable weglassen und stattdessen A_PriorHotkey nutzen.

Code: Select all

$WheelDown::
$WheelUp:: {

	if A_PriorHotkey = ThisHotkey
		Send "{" SubStr(ThisHotkey, 2) "}"
}

Der allererste Send-Befehl geht damit zwar ins Leere, da A_PriorHotkey zu Beginn noch leer ist. Sollte aber eigentlich nicht stören, falls doch dann ginge dies:

Code: Select all

$WheelDown::
$WheelUp:: {

	if (k := ThisHotkey) = ((p := A_PriorHotkey)?p:k)
		Send "{" SubStr(k, 2) "} "
}

[divanebaba]

Hallo zusammen.
Wirklich erstaunlich, welche professionellen Lösungsmöglichkeiten es gibt.
Ich habe mich für den ersten Vorschlag von Noitalommi_2 entschieden, da dieser verständlicher ausgeführt ist.
Vielen Dank für die Codebeispiele.