Hallo,
ich fange grade an mit AHK und Pulover´s Macro Creator zu arbeiten.
Nun suche ich einen Weg den Computernamen oder den Benutzernamen auszulesen.
Gibt es dafür einen Befehl?
Ich kann leider keinen finden.
Beste Grüße
Joker
Computername auslesen
Moderator: jNizM
Re: Computername auslesen
Versuch mal dies:
Ich hoffe, das hilft.
Edit: die Funktion get_ComputerName gibt nur den Namen des Arbeitsplatzes zurück. sorry
Code: Select all
MsgBox, % A_UserName
MsgBox, % get_ComputerName()
;-------------------------------------------------------------------------------
get_ComputerName() { ; read from registry
;-------------------------------------------------------------------------------
Static CLSID := "Software\Microsoft\Windows\CurrentVersion\Explorer\CLSID"
Static CLSID_COMPUTER := "{20D04FE0-3AEA-1069-A2D8-08002B30309D}"
RegRead, ComputerName, HKCU, %CLSID%\%CLSID_COMPUTER%
Return, ComputerName
}
Edit: die Funktion get_ComputerName gibt nur den Namen des Arbeitsplatzes zurück. sorry
Last edited by wolf_II on 27 Apr 2016, 12:03, edited 1 time in total.
- hoppfrosch
- Posts: 443
- Joined: 07 Oct 2013, 04:05
- Location: Rhine-Maine-Area, Hesse, Germany
- Contact:
Re: Computername auslesen
Easiest way would be:
Code: Select all
EnvGet, OutputVar, COMPUTERNAME
MsgBox % A_Username " on " OutputVar
Re: Computername auslesen
[AHK] v2.0.5 | [WIN] 11 Pro (Version 22H2) | [GitHub] Profile
Re: Computername auslesen
Danke für Eure Hife.
Wusste nicht das es dazu passende Variablen gibt.
Danke.
Wusste nicht das es dazu passende Variablen gibt.
Danke.
Re: Computername auslesen
Beispiele mit A_Variables
Code: Select all
MODIFIED=20150225
;- A_VARIABLE
;------------------------------------------------------------------------
#NoEnv ; Recommended for performance and compatibility with future AutoHotkey releases.
#Warn
SendMode Input ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir, %A_ScriptDir%
SetTitleMatchMode 2
SetBatchLines, -1
FormatTime, Suomi , L1035, dddd MMMM yyyy-MM-dd
Filename1=AHK-A_Variables User=%a_username% Computer=%a_computername% %a_osversion% AHK-Version=%a_ahkversion% %suomi%
url=http://www.netikus.net/show_ip.html ;- to show public IP-address
Adr:= UrlDownloadToVar( URL ) ;- desactivate this when no internetconnection
Gui,2:default
Gui,2: -DPIScale
Gui,2:Font,s12 , Lucida Console
Gui,2:Color,Black
wa:=A_screenwidth
ha:=A_screenHeight
LH :=(ha*89 )/100 ;- LV height
GH :=(ha*93 )/100 ;- GUI height
LW :=(wa*98.5)/100 ;- LV width
GW :=(wa*99 )/100 ;- GUI width
T1 :=(wa*12)/100
T2 :=(wa*10)/100
T3 :=(wa*75)/100
t2a:=(t1+t2)
Gui,2: Add, ListView,grid backgroundGray cWhite x2 y2 h%LH% w%lw% gMyLV1 vLV1 +altsubmit -multi, Name|AHK-A_Variable|Show Result ( open Info/Folder/File with mouse-click )
LV_ModifyCol(1, T1), LV_ModifyCol(2, T2), LV_ModifyCol(3, T3) ;- column width
Gui,2:show,x1 y1 h%gh% w%gw%,%filename1%
gosub,smalltools
gosub,e4xvar
e5x:= % ShellFolder()
e6x=%e4x%%e5x%
gosub,fillx
return
FileExit:
2Guiclose:
exitapp
;--------------------------
fillx:
Gui,2:submit,nohide
Gui,2:ListView, LV1
LV_Delete()
GuiControl, -Redraw, LV1
loop,parse,e6x,`n,`r
{
y=%a_loopfield%
if y=
continue
LV_Add("", StrSplit(y,",")*)
}
LV_ModifyCol(1, "Logical SortAsc")
GuiControl, +Redraw, LV1
return
;----------------------------
mylv1:
Gui,2:ListView, LV1
if A_GuiEvent = Normal
{
LV_GetText(C1,A_EventInfo,1)
LV_GetText(C2,A_EventInfo,2)
LV_GetText(C3,A_EventInfo,3)
stringmid,C3a,C3,1,3
stringmid,C3b,C3,1,2
MouseGetPos,x,y
{
;if x>%T2a%
{
if (c3a="C:\" or c3b="::")
{
run,%c3%
return
}
else
{
msgbox, 262208,INFO ,C1=%c1%`nC2=%c2%`nC3=%c3%
return
}
return
}
}
}
return
;-------------------------------
smalltools:
SysGet, VirtualWidth , 78
SysGet, VirtualHeight, 79
EnvGet, EnvGetVar, Path ;- see #Noenv
return
;-------- http://www.autohotkey.com/forum/topic36688.html ---
;MsgBox % ShellFolder() ; To retrieve all
;MsgBox % ShellFolder( "My Pictures" ) ; To retrieve Pictures folder
;return
ShellFolder( VN="" ) {
v:=""
Static Subkey:="Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders"
If ( VN="")
{
Loop, HKCU, %SubKey%, 0
{ VarSetCapacity( Spaces,30,32 )
RegRead, Value, HKCU, %SubKey%, %A_LoopRegName%
v .= ((v<>"") ? "`n" : "" ) (A_LoopRegName) ",RegRead," Value
}
} Else
RegRead, V, HKCU, %SubKey%, %VN%
Return V
}
UrlDownloadToVar(URL) {
WebRequest := ComObjCreate("WinHttp.WinHttpRequest.5.1")
WebRequest.Open("GET", URL)
WebRequest.Send()
Return WebRequest.ResponseText
}
e4xVar:
e4x=
(
MyComputer,CLSID,::{20d04fe0-3aea-1069-a2d8-08002b30309d}
MyNetworkPlaces,CLSID,::{208d2c60-3aea-1069-a2d7-08002b30309d}
NetworkConnections,CLSID,::{7007acc7-3202-11d1-aad2-00805fc1270e}
Printers,CLSID,::{2227a280-3aea-1069-a2de-08002b30309d}
RecycleBin,CLSID,::{645ff040-5081-101b-9f08-00aa002f954e}
ScheduledTasks,CLSID,::{d6277990-4c6a-11cf-8d87-00aa0060f5bf}
ahk-Version,a_ahkversion,%a_ahkversion%
unicode,a_IsUnicode,%a_IsUnicode%
ipaddress-1 private,a_ipaddress1,%a_ipaddress1%
ipaddress-2,a_ipaddress2,%a_ipaddress2%
ipaddress-3,a_ipaddress3,%a_ipaddress3%
ipaddress-4,a_ipaddress4,%a_ipaddress4%
ipaddress-0 public,www.netikus.net,%adr%
64-bit,a_Is64bitOS,%a_Is64bitOS%
ahk-path,a_ahkpath,%a_ahkpath%
ahk-scriptfullpath,a_scriptfullpath,%a_scriptfullpath%
ahk-HWND,a_scriptHwnd,%a_scriptHwnd%
ptr-size,a_ptrsize,%a_ptrsize%
appdata,a_appdata,%a_appdata%
appdatacommon,a_appdatacommon,%A_appdatacommon%
personal mydocuments,a_mydocuments,%A_mydocuments%
programfiles,a_programfiles,%A_programfiles%
programs,a_programs,%A_programs%
programsCommon,a_programsCommon,%A_programsCommon%
start Menu,a_StartMenu,%A_StartMenu%
startMenuCommon,a_StartMenuCommon,%a_StartMenuCommon%
startup,a_Startup,%A_Startup%
startupCommon,a_StartupCommon,%A_StartupCommon%
temp,a_Temp,%A_Temp%
username,a_username,%A_username%
DATE,a_YYYY-A_MM-a_DD a_hour:a_min:a_sec,%A_YYYY%-%A_MM%-%a_DD% %a_hour%:%a_min%:%a_sec%
DATE_NOW,a_now,%a_now%
DATE_UTC,a_nowUTC,%a_nowUTC%
desktop,a_desktop,%A_desktop%
desktopcommon,a_desktopcommon,%A_desktopcommon%
computername,a_computername,%A_computername%
windir,a_windir,%a_windir%
language,a_language,%a_language%
iconhidden,a_iconhidden,%a_iconhidden%
ahk-scriptworkingdir,a_workingdir,%a_workingdir%
admin,a_IsAdmin,%a_IsAdmin%
osType,a_OsType,%a_OsType%
osversion,a_osversion,%a_osversion%
ScreenWidthVirtual,,%VirtualWidth%
ScreenHeightVirtual,,%VirtualHeight%
ScreenWidth,A_ScreenWidth,%A_ScreenWidth%
ScreenHeight,A_ScreenHeight,%A_ScreenHeight%
ScreenDPI,A_ScreenDPI,%A_ScreenDPI%
ErrorLast,A_LastError,%A_LastError%
Envget,Envget,_%envgetvar%
)
return
;================= END script ===========================
Re: Computername auslesen
Die Funktion get_ComputerName() gibt bei mir (W 7) nur eine leere msgbox zurück. sorry?wolf_II wrote:Versuch mal dies:
...
MsgBox, % get_ComputerName()
Re: Computername auslesen
Die Funktion ist unglücklich benannt. Sollte wohl eher get_ArbeitsPlatzName() heissen, oder get_MyComputerName().
Ich nutze sie, um, nachdem der Arbeitsplatz auf Win7 umbenannt wurde, für ein externes Programm (Total Commander) automatisch eine individuelle Konfiguration zu starten.
Versuch mal, den Arbeitsplatz in "Test" umzubenennen. Möglicherweise fehlt in der Registry ein Eintrag, falls der Arbeitsplatz noch nie umbenannt wurde, Ich bin mir aber nicht sicher.
Ich nutze sie, um, nachdem der Arbeitsplatz auf Win7 umbenannt wurde, für ein externes Programm (Total Commander) automatisch eine individuelle Konfiguration zu starten.
Versuch mal, den Arbeitsplatz in "Test" umzubenennen. Möglicherweise fehlt in der Registry ein Eintrag, falls der Arbeitsplatz noch nie umbenannt wurde, Ich bin mir aber nicht sicher.
Who is online
Users browsing this forum: No registered users and 58 guests