MButton mit Shift & MButton vertauschen Topic is solved

[Cyplex]

Hi.
Ich möchte die Maus und Key Kombination Shift & MButton mit einfach MButton vertauschen. Irgendwie komme ich da nicht weiter.
Ich dachte es geht einfach mit:

Code: Select all

MButton::+MButton
+MButton::MButton

Aber so gehts nicht.

Jetzt haben ich mit:

Code: Select all

~MButton::Send {Shift Down}
~MButton UP::Send {Shift Up}

wenigstens die halbe Miete. Aber das oben genannte bekomme ich einfach nicht hin.
Bin dankbar für Hilfe.

Edit ............
Noch vergessen: Ich brauche hier nicht nur einen Klick, sondern die Funktion muß, so lange wie die Tasten gedrückt sind, bestehen.

[Rohwedder]

Hallo,
versuchs mal mit:

Code: Select all

#InstallKeybdHook
~*MButton::SendInput {Blind}{Shift Down}
~*MButton UP::SendInput {Blind}{Shift Up}
#IF GetKeyState("Shift","P")
~*MButton::SendInput {Blind}{Shift Up}
~*MButton UP::SendInput {Blind}{Shift Down}
#IF

oder mit:

Code: Select all

#InstallKeybdHook
~*MButton::SendInput,% GetKeyState("Shift","P")?"{Blind}{Shift Up}":"{Blind}{Shift Down}"
~*MButton UP::SendInput,% GetKeyState("Shift","P")?"{Blind}{Shift Down}":"{Blind}{Shift Up}"

[Cyplex]

Danke für die Hilfe. Die {Blind} Option haben ich gestern erst entdeckt. Mein Ansatz war dann:

Code: Select all

~+MButton::Send {Blind}{Shift Up}

Damit erhalte ich ein ähnliches Ergebnis. Ähnlich, weil es leider auch nicht ganz klappt. Die Shift Taste drückt sich nach ca 1 Sek. wieder von selbst und beendet den Hotkey, obwohl die Tasten noch gedrückt sind. Es funktioniert dann auch erst wieder wenn ich Shift physisch los lasse und wieder drücke.

Fehlt im ersten Codeblock nach dem 2ten #IF noch was?

[just me]

Moin,

das allein stehende #IF beendet die bedingte Ausführung von Hotfkeys.

[Cyplex]

Alles klar, danke. Leider hat dies den selben Effekt wie schon genannt. Nach 1 Sek funktioniert der Hotkey nicht mehr. Es kommt mit vor als wäre das genau die Zeit bis die Tastenwiederholung anschlägt. Aber Shift hat doch eigentlich gar keine, oder?

[just me]

Ich habe mich bisher nur wenig mit Hotkeys beschäftigt, wenn ich sie unbedingt für einfache Ablaufsteuerungen brauchte. Ich kann Dir deshalb leider nicht helfen.

[Rohwedder]

Hallo,
noch ein Versuch:

Code: Select all

#InstallKeybdHook
~*MButton::SendInput {Blind}{Shift DownR}
~*MButton UP::SendInput {Blind}{Shift Up}
#IF GetKeyState("Shift","P")
~*MButton::SendInput {Blind}{Shift Up}
~*MButton UP::SendInput {Blind}{Shift DownR}
#IF GetKeyState("MButton","P")
*Shift::SendInput {Blind}{Shift Up}
*Shift Up::SendInput {Blind}{Shift DownR}
#IF

[Cyplex]

My Hero! Damit klappt es so wie es soll.
Mit if's und KeyStates hatte ich auch schon experimentiert, aber ohne rechten Erfolg. Da muß ich mir nochmal in der Duku durchlesen was genau Du da gemacht hast.
Nochmals vielen Dank für die Hilfe.