Umlaute werden nicht erkannt

[Folllast]

Hallo,

ich habe einen Script, der einen Befehl an die Eingabekonsole sendet und das Ergebnis ausgibt.
Das Problem ist, dass dabei die Umlaute verloren gehen. Wenn ich den befehl direkt in die Eingabeaufforderung eingebe, werden die Umlaute korrekt angezeigt.

Hier der Auszug aus dem Programm, das verantwortlich ist.

Code: Select all

MsgBox % RunWaitEin(string)
RunWaitEin(Befehl) {
shell := ComObjCreate("WScript.Shell")
exec := shell.Exec(ComSpec " /C " Befehl)
return exec.StdOut.ReadAll()
}

[nnnik]

Welche AHK Version verwendest du? Also Unicode oder Ansi?

[Folllast]

ANSI 32 Bit

[effel]

hey
ich habe leider keine antwort für dich, nur eine frage

kann man die eingabeaufforderung auch hidden aufrufen?

[nnnik]

Versuch mal Unicode 32 bit zu verwenden - dann sollte es klappen.

[gregster]

kann man die eingabeaufforderung auch hidden aufrufen?

Es geht

Code: Select all

RunWait, %ComSpec% /c dir c:\ >C:\Users\g\Desktop\dir.txt, , hide	; leitet Ergebis von "dir c:\" in txt-Datei um

mit der hide Option.

[effel]

hallo gregster,
danke, war mir bekannt.

ich meinte im code von Folllast

[just me]

Moin,

die gute alte ComSpec-Console verwendet in der Standardeinstellung einen sogenannten OEM-Zeichensatz. Der hat die deutschen Umlaute auf anderen Zeichenpositionen. Du kannst ihn in den 'Einstellungen' des Consolenfensters finden. Normalerweise ist das die Codepage, die von folgender API-Funktion geliefert wird:

Code: Select all

OEMCP := DllCall("GetOEMCP", "UInt")

Die in OEMCP zurückgegebene Nummer kann z.B. mit der Funktion StrGet() als Option "CP" . OEMCP genutzt werden.

[gregster]

ich meinte im code von Folllast

Sorry, ist leider etwas Offtopic, aber so geht's mit gewissen Abwandlungen (und einem Umweg für die Ausgabe):

Spoiler

Code: Select all

MsgBox % RunWaitOne("dir c:\")

RunWaitOne(command) {
	OldClip := Clipboard 
    ; WshShell object: http://msdn.microsoft.com/en-us/library/aew9yb99
    shell := ComObjCreate("WScript.Shell")
	exec := shell.Run(ComSpec " /C " command " | clip", 0, True )
	output := Clipboard
	Clipboard := OldClip
    return output
}

Hier wird das Clipboard genutzt, man könnte auch ne (ggf. temporäre) txt-Datei verwenden - aber dann wäre es wahrscheinlich witzlos im Vergleich zur RunWait-Variante. Infos von dieser Diskussion: https://stackoverflow.com/questions/32297699/hide-command-prompt-window-when-using-exec

[effel]

ist garnicht so offtopic, mit der letzten version sind auch die umlaute dargestellt

Ping wird ausgefhrt fr 8.8.8.8 mit 32 Bytes Daten:

Ping wird ausgeführt für 8.8.8.8 mit 32 Bytes Daten:

[gregster]

ist garnicht so offtopic, mit der letzten version sind auch die umlaute dargestellt

Ping wird ausgefhrt fr 8.8.8.8 mit 32 Bytes Daten:

Ping wird ausgeführt für 8.8.8.8 mit 32 Bytes Daten:

Stimmt, ist mir auch gerade aufgefallen (bei mir war es Datenträger vs. Datentr„ger). Wunderbar

[just me]

Moin,

meiner Meinung nach besteht der Sinn der WScript.Shell Methode hauptsächlich darin, das umgebende System möglichst unangetastet zu lassen. Zum umgebenden System zählt für mich auch die Zwischenablage, deshalb hier folgende Alternative, die auch zu funktionieren scheint:

Code: Select all

#NoEnv
MsgBox % RunWaitEin("ping 8.8.8.8")
ExitApp

RunWaitEin(Befehl) {
   Static OEMCP := "CP" . DllCall("GetOEMCP", "UInt")
   shell := ComObjCreate("WScript.Shell")
   exec := shell.Exec(ComSpec " /C " Befehl)
   result := exec.StdOut.ReadAll()
   If (A_IsUnicode) {
      VarSetCapacity(oemstr, StrPut(result, "CP0"), 0)
      StrPut(result, &oemstr, "CP0")
   }
   Return StrGet(A_IsUnicode ? &oemstr : &result, OEMCP)
}

Für die Clipboard-Methode braucht es den Umweg über die WScript.SHell nicht:

Code: Select all

#NoEnv
MsgBox % RunWaitEinClip("ping 8.8.8.8")
ExitApp

RunWaitEinClip(Befehl) {
   SavedClip := ClipboardAll
   RunWait, %ComSpec% /c %Befehl% | Clip, , Hide
   Result := Clipboard
   Clipboard := SavedClip
   Return Result
}

Übrigens: Zum Sichern der kompletten Zwischenablage sollte es OldClip := ClipboardAll sein.