@just me
Ich bin ein großer Fan von deine Erklärungen und Tutorials, danke nochmal für die super Erklärung, habe eingebaut und Dateien konnte ich Problemlos kopieren.
Nachdem ich 10 verschiedene Textstellen aus verschiedene quellen (url, Dateien, Dateiname, Textpassagen aus wikipedia, Text aus Editor und Word) kopiert habe, trat der Fehler wieder auf
@haichen
werde jetzt auf 100 erhöhen
Critical Error: Invalid memory read/write Topic is solved
Moderator: jNizM
Re: Critical Error: Invalid memory read/write Topic is solved
Moin,
schade! Dann kommt jetzt mein letzter Versuch: Wir holen uns den Text über die API-Funktionen. Ich glaube zwar eher nicht, dass das hilft, aber man weiß ja nie. Der AHK-Sourcecode enthält jedenfalls einige Hinweise auf immer mal wieder aufgetretene Probleme mit dem Clipboard.
schade! Dann kommt jetzt mein letzter Versuch: Wir holen uns den Text über die API-Funktionen. Ich glaube zwar eher nicht, dass das hilft, aber man weiß ja nie. Der AHK-Sourcecode enthält jedenfalls einige Hinweise auf immer mal wieder aufgetretene Probleme mit dem Clipboard.
Code: Select all
ZwischenablageG(Type) {
If !(Type = 1) Or !Clipboard_HasText()
Return
ClipAlt := Clipboard_GetText()
If (ClipAlt = "")
Return
...
}
; -------------------------------------------
Clipboard_HasText() {
Static CF_NATIVETEXT := A_IsUnicode ? 13 : 1 ; CF_UNICODETEXT = 13, CF_TEXT = 1
Return DllCall("IsClipboardFormatAvailable", "UInt", CF_NATIVETEXT, "UInt")
}
; -------------------------------------------
Clipboard_GetText() {
Static CF_NATIVETEXT := A_IsUnicode ? 13 : 1 ; CF_UNICODETEXT = 13, CF_TEXT = 1
ClipText := ""
If DllCall("OpenClipboard", "Ptr", 0, "UInt") {
If (HMEM := DllCall("GetClipboardData", "UInt", CF_NATIVETEXT, "UPtr")) {
Chrs := DllCall("GlobalSize", "Ptr", HMEM, "Ptr") >> !!A_IsUnicode
If (PMEM := DllCall("GlobalLock", "Ptr", HMEM, "UPtr")) {
ClipText := StrGet(PMEM, Chrs)
DllCall("GlobalUnlock", "Ptr", HMEM)
}
}
DllCall("CloseClipboard")
}
Return ClipText
}
Re: Critical Error: Invalid memory read/write
Hallo just me,
ich habe mit dem Clipboard_GetText() und ClipBoard rumgespielt. Dabei habe ich beim Kopieren in der Schleife immer mal woanders hingeklickt.
Mit einer Clipboardzuweisung kam es immer dann zu Abstürzen wenn ich SendInput anstelle von Send verwendet habe. Ein Sleep nach der Zuweisung hat die Abstürze verhindert.
Deine Funktion ist nie abgestürzt!
ich habe mit dem Clipboard_GetText() und ClipBoard rumgespielt. Dabei habe ich beim Kopieren in der Schleife immer mal woanders hingeklickt.
Mit einer Clipboardzuweisung kam es immer dann zu Abstürzen wenn ich SendInput anstelle von Send verwendet habe. Ein Sleep nach der Zuweisung hat die Abstürze verhindert.
Deine Funktion ist nie abgestürzt!
Code: Select all
#Persistent
#NoEnv
SetBatchLines, -1
;stürzt ab mit SendInput
;ein sleep verhindert abstürze
;stürzt mit send nicht ab:
o::
i:=0
loop, 1000
{
SendInput, +{Right}^c
x:=Clipboard
;sleep, 10
tooltip % i++ " " x
}
return
;stürzt nicht ab:
p::
i:=0
loop, 1000
{
Send, +{right}^c
x:=Clipboard_GetText()
tooltip % i++ " " x
}
return
return
Clipboard_GetText() {
Static CF_NATIVETEXT := A_IsUnicode ? 13 : 1 ; CF_UNICODETEXT = 13, CF_TEXT = 1
ClipText := ""
If DllCall("OpenClipboard", "Ptr", 0, "UInt") {
If (HMEM := DllCall("GetClipboardData", "UInt", CF_NATIVETEXT, "UPtr")) {
Chrs := DllCall("GlobalSize", "Ptr", HMEM, "Ptr") >> !!A_IsUnicode
If (PMEM := DllCall("GlobalLock", "Ptr", HMEM, "UPtr")) {
ClipText := StrGet(PMEM, Chrs)
DllCall("GlobalUnlock", "Ptr", HMEM)
}
}
DllCall("CloseClipboard")
}
Return ClipText
}
Re: Critical Error: Invalid memory read/write
Moin haichen,
danke für's Testen. Schaun wir mal, ob KHA's Probleme damit auch verschwinden.
danke für's Testen. Schaun wir mal, ob KHA's Probleme damit auch verschwinden.
Re: Critical Error: Invalid memory read/write
Hallo ihr beiden, vielen Dank für die Arbeit und Mühe!
Habe es eingebaut, bis jetzt funktioniert es Tadellos ohne abstürze.
Werde jetzt damit ein paar Tage arbeiten, dann habe ich die Gewissheit
Habe es eingebaut, bis jetzt funktioniert es Tadellos ohne abstürze.
Werde jetzt damit ein paar Tage arbeiten, dann habe ich die Gewissheit
Re: Critical Error: Invalid memory read/write
Nutze jetzt eine Woche lang, 0 abstürze. Nochmal vielen Dank
Who is online
Users browsing this forum: No registered users and 60 guests