Timer-GUI mit Parameterübergabe

Stelle Fragen zur Programmierung mit Autohotkey

Moderator: jNizM

User avatar
roady1969
Posts: 7
Joined: 16 Jul 2019, 05:00

Timer-GUI mit Parameterübergabe

25 Sep 2020, 03:29

Hallo liebe Forenmitglieder,

nach vielen Monden habe ich mich wieder mit AHK beschaeftigt und musste feststellen, dass ich vieles verlernt habe... Daher bin ich wieder einmal bei Euch gelandet und hoffe auf eine Loesung.

An sich versuche ich ein kleines kompilierbares Script zu erstellen, was ich spaeter aus einer Batch heraus aufrufen kann. Bei diesem shell execute moechte ich einen Parameter uebergeben der eine Zeit angibt (z.B. "100" fuer 100 Sekunden). Das AHK Script soll dann einfach diesen Parameter auswerten und ueber eine einfache kleine GUI diese Zeit "rueckwaerts" als "Timerablauf" darstellen.

Nichts weiter soll passieren.

Also an sich brauche ich nur ein kleines grafisches Fenster, was die Zeit vom Parameter aufnimmt, dann im Fenster darstellt und dort (aktualisiert) rueckwaerts herunterzaehlt.

Ich bin zu bloed (leider) dazu, da ich so vieles wohl vergessen haben.
Kann mir jemand hierzu codeschnipsel bzw. den code benennen, der so was ermoeglicht?

Waeer Euch sehr bunden,
Lieben Gruss & Danke!
R.
just me
Posts: 7576
Joined: 02 Oct 2013, 08:51
Location: Germany

Re: Timer-GUI mit Parameterübergabe

25 Sep 2020, 06:42

Moin,

Du hast Glück. Ich hatte sowieso eine Mondfahrt gebucht und habe Im aktuellen Mond auf dessen Rückseite folgendes Skript gefunden:

Code: Select all

#NoEnv
SetBatchLines, -1
Titel := "Timer Skript"
; Das Skript erwartet einen Kommandozeilenparameter mit der Anzahl der Sekunden als positive Ganzzahl.
Sekunden := GetParam()
If (Sekunden = 0) {
;  Falls eine Fehlermeldung gewünscht ist
   MsgBox, 16, %Titel%
         , Das Skript benötigt einen Kommandozeilenparameter mit der Anzahl der Sekunden als positive Ganzzahl.
   ExitApp
}
Gui, +ToolWindow
Gui, Font, s72 cNavy, Consolas
Gui, Add, Text, Center vTimer, %Sekunden%
Gui, Show, , %Titel%
Sleep, 1
S := A_TickCount
SetTimer, CountDown, 10
Return

GuiClose:
Return

CountDown:
   T := A_TickCount - S
   If (T > 1000) {
      S += 1000
      Sekunden--
      GuiControl, , Timer, %Sekunden%
      If (Sekunden < 1)
         ExitApp
   }
Return

GetParam() {
   If (A_Args.Length() = 1) {
      Sekunden := A_Args[1]
      If Sekunden Is Integer
         If (Sekunden > 0)
            Return Sekunden
   }
   Return 0
}
BoBo
Posts: 4111
Joined: 13 May 2014, 17:15

Re: Timer-GUI mit Parameterübergabe

26 Sep 2020, 06:23

Du hast Glück. Ich hatte sowieso eine Mondfahrt gebucht
[sherlocked]Nun, gestehen Sie! Peter(chen): "Yep, it's me, just me!"[/sherlocked] :lol:
User avatar
roady1969
Posts: 7
Joined: 16 Jul 2019, 05:00

Re: Timer-GUI mit Parameterübergabe

29 Sep 2020, 02:36

LIEBEN herzlichen Dank. Das haette ich jetzt in der Tat in der Schnelle nicht hinbekommen.

Und grundsaetzlich glaube ich macht das Teil, was es soll.

ABER Allein testen kann ich es nicht.
Denn wenn ich es ueber die CMD z.B. mit zeitzaehler.ahk 10 aufrufe oder zuvor compiliere und dann mit zeitzaehler.exe 10 aufrufe, so meldet er, dass es keinen Kommandozeilenparameter bekommen hat.

Was mache ich noch falsch?

Wie uebergebe ich den Parameter?
User avatar
haichen
Posts: 561
Joined: 09 Feb 2014, 08:24

Re: Timer-GUI mit Parameterübergabe

29 Sep 2020, 02:58

test.bat

Code: Select all

start "" "Pfad\zu\zeitzaehler.exe" 100
just me
Posts: 7576
Joined: 02 Oct 2013, 08:51
Location: Germany

Re: Timer-GUI mit Parameterübergabe

29 Sep 2020, 03:01

Moin,

welche AHK-Version läuft bei Dir?
User avatar
haichen
Posts: 561
Joined: 09 Feb 2014, 08:24

Re: Timer-GUI mit Parameterübergabe

29 Sep 2020, 05:35

Hi just me,
falls du mich meinst, ich habe immer die neueste AHK-Version.
User avatar
haichen
Posts: 561
Joined: 09 Feb 2014, 08:24

Re: Timer-GUI mit Parameterübergabe

29 Sep 2020, 05:36

Ach so, wg A_Args.
just me
Posts: 7576
Joined: 02 Oct 2013, 08:51
Location: Germany

Re: Timer-GUI mit Parameterübergabe

29 Sep 2020, 05:52

Hallo haichen,

nöh (ich meinte roady1969) und ja! ;)
User avatar
roady1969
Posts: 7
Joined: 16 Jul 2019, 05:00

Re: Timer-GUI mit Parameterübergabe

29 Sep 2020, 09:33

Version: 1.1.21.03
KHA
Posts: 263
Joined: 21 Aug 2018, 11:11

Re: Timer-GUI mit Parameterübergabe

29 Sep 2020, 10:04

A_Args funktioniert mit v1.1.27+
just me
Posts: 7576
Joined: 02 Oct 2013, 08:51
Location: Germany

Re: Timer-GUI mit Parameterübergabe

29 Sep 2020, 10:40

Wenn Du nicht updaten kannst oder willst:

Code: Select all

GetParam() {
   Local Sekunden ; macht die Variablen 0, 1, ... zu globalen Variablen
   If 0 = 1
   {
      Sekunden = %1%
      If Sekunden Is Integer
         If (Sekunden > 0)
            Return Sekunden
   }
   Return 0
}
User avatar
roady1969
Posts: 7
Joined: 16 Jul 2019, 05:00

Re: Timer-GUI mit Parameterübergabe

06 Oct 2020, 04:47

perfekt! genau so!

Jungs, DANKE SEHR!

Return to “Ich brauche Hilfe”

Who is online

Users browsing this forum: No registered users and 3 guests