Lautschrift vorlesen lassen

[Rohwedder]

Hallo,
auf Wikipedia wird häufig die Aussprache in IPA-Lautschrift präsentiert, z.B. ʃaʁ.dɔ.nɛ auf https://de.wikipedia.org/wiki/Chardonnay. Ich höre sie mir dann auf http://ipa-reader.xyz/ mit der Stimme von Marlene [German] an.
Meine jetzige Methode, copy/paste in den IPA Reader im Hintergrund, ist zu laienhaft um es hier zu zeigen. Kann es jemand besser?

[BoBo]

Auf der Seite des Readers ist die Story zur "Maschine dahinter" verlinkt: https://cuttlesoft.com/blog/pronouncing-things-with-amazons-polly/
Das ganze scheint API basierend aufgesetzt?! Vielleicht lassen sich ja ein paar AHK-Koryphäen zu dem Thema motivieren?

[KHA]

Hallo,
auf Wikipedia wird häufig die Aussprache in IPA-Lautschrift präsentiert, z.B. ʃaʁ.dɔ.nɛ auf https://de.wikipedia.org/wiki/Chardonnay. Ich höre sie mir dann auf http://ipa-reader.xyz/ mit der Stimme von Marlene [German] an.
Meine jetzige Methode, copy/paste in den IPA Reader im Hintergrund, ist zu laienhaft um es hier zu zeigen. Kann es jemand besser?

Ich weiß es nicht, ist das hier besser?

Code: Select all

#NoEnv
#Warn
#SingleInstance, Force
SetWorkingDir %A_ScriptDir% 

IPASchrift := "ʃaʁ.dɔ.nɛ"

nBytes := Base64Dec(DateiHerunterladen(IPASchrift), Bin)
File := FileOpen("Audio.mp3", "w")
File.RawWrite(Bin, nBytes)
File.Close()
Sleep, 1500
SoundPlay, Audio.mp3,1


DateiHerunterladen(IPA, Stimme := "Marlene"){
PostData := "{""text"":""" IPA """,""voice"":""" Stimme """}"
oHTTP := ComObjCreate("WinHttp.WinHttpRequest.5.1")
oHTTP.Open("POST", "https://iawll6of90.execute-api.us-east-1.amazonaws.com/production" , False)
oHTTP.SetRequestHeader("User-Agent", "Mozilla/5.0 (Windows NT 10.0; Win64; x64; rv:94.0) Gecko/20100101 Firefox/94.0")
oHTTP.SetRequestHeader("Referer", "http://ipa-reader.xyz/")
oHTTP.SetRequestHeader("Accept-Language", "de,en-US;q=0.7,en;q=0.3")
oHTTP.SetRequestHeader("Accept-Encoding", "gzip, deflate, br")
oHTTP.SetRequestHeader("Content-Type", "application/json")
oHTTP.SetRequestHeader("Content-Length", "42")
oHTTP.SetRequestHeader("Origin", "http://ipa-reader.xyz")
oHTTP.SetRequestHeader("Connection", "keep-alive")
oHTTP.SetRequestHeader("Sec-Fetch-Site", "cross-site")
oHTTP.SetRequestHeader("TE", "trailers")
oHTTP.Send(PostData)
Return % AudioDatei  := Trim(StrReplace(oHTTP.responseText,"\n"), """")
}

Base64Dec( ByRef B64, ByRef Bin ) {  ; By SKAN / 18-Aug-2017
Local Rqd := 0, BLen := StrLen(B64)                 ; CRYPT_STRING_BASE64 := 0x1
  DllCall( "Crypt32.dll\CryptStringToBinary", "Str",B64, "UInt",BLen, "UInt",0x1
         , "UInt",0, "UIntP",Rqd, "Int",0, "Int",0 )
  VarSetCapacity( Bin, 128 ), VarSetCapacity( Bin, 0 ),  VarSetCapacity( Bin, Rqd, 0 )
  DllCall( "Crypt32.dll\CryptStringToBinary", "Str",B64, "UInt",BLen, "UInt",0x1
         , "Ptr",&Bin, "UIntP",Rqd, "Int",0, "Int",0 )
Return Rqd
}

[Rohwedder]

Na, und ob das besser ist!

Wird eine Anfrage bei Amazons text-to-speech service gestellt und so getan als ob diese von http://ipa-reader.xyz/ käme?
Aber egal! Hauptsache es funktioniert.
Vielen herzlichen Dank!

[BoBo]

@Rohwedder - wenn du zwar das Wort, aber keine Lautschrift hast (jedoch die Sprache weißt) kannst du es auch mal so probieren:
viewtopic.php?f=76&t=97323

[Rohwedder]

Danke für den Hinweis!
Die Seite https://cloud.google.com/text-to-speech/#section-2 ist prima! Bei korrekter Sprache ist der Unterschied zur IPA-Lautschrift-Aussprache vernachlässigbar.
Leider hat sich das Skript von teadrinker bei mir nicht bewährt.
Google hat mich auf dem Kieker und vercaptchart mir alles. Zum Glück gibt es noch Bing.