Simple Color Dialog

Post your working scripts, libraries and tools for AHK v1.1 and older
User avatar
joedf
Posts: 8940
Joined: 29 Sep 2013, 17:08
Location: Canada
Contact:

Simple Color Dialog

01 Oct 2013, 17:57

Here's another example AutoHotkey script... (Fully commented)
100% AutoHotkey, no dllcalls or gdi+
This time, it's a colour dialog!
 
Revision 1

Code: Select all

;
; AutoHotkey Version: 1.1.12.00
; Language:       English
; Dev Platform:   Windows 7 Home Premium x64
; Author:         Joe DF  |  http://joedf.co.nr  |  [email protected]
; Date:           August 20th, 2013
;
; Script Function:
;	Color Dialog Example script.
;

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
#Warn  ; Recommended for catching common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.
;<<<<<<<<  HEADER END  >>>>>>>>>

;Set starting default value to RGB(44,197,89), Just a random colour
RGBval:=RGB(Rval:=44,Gval:=197,Bval:=89)

;Create Color Dialog GUI
Gui, Add, Text, x0 y10 w40 h20 +Right, Red
Gui, Add, Text, x0 y30 w40 h20 +Right, Green
Gui, Add, Text, x0 y50 w40 h20 +Right, Blue
Gui, Add, Slider, x40 y10 w190 h20 AltSubmit +NoTicks +Range0-255 vsR gSliderSub, %Rval%
Gui, Add, Slider, x40 y30 w190 h20 AltSubmit +NoTicks +Range0-255 vsG gSliderSub, %Gval%
Gui, Add, Slider, x40 y50 w190 h20 AltSubmit +NoTicks +Range0-255 vsB gSliderSub, %Bval%
Gui, Add, Edit, x230 y10 w45 h20 gEditSub veR +Limit3 +Number, %Rval%
Gui, Add, UpDown, Range0-255 vuR gUpDownSub, %Rval%
Gui, Add, Edit, x230 y30 w45 h20 gEditSub veG +Limit3 +Number, %Gval%
Gui, Add, UpDown, Range0-255 vuG gUpDownSub, %Gval%
Gui, Add, Edit, x230 y50 w45 h20 gEditSub veB +Limit3 +Number, %Bval%
Gui, Add, UpDown, Range0-255 vuB gUpDownSub, %Bval%
Gui, Add, Progress, x285 y10 w60 h60 +Border Background%RGBval% vpC
Gui, Add, Text, x285 y10 w60 h60 +Border vtP cWhite +BackgroundTrans, Preview
Gui, Add, Button, x120 y80 w110 h20 vbS gButtonSub, Copy to Clipboard
Gui, Show, w351 h105, Simple Color Dialog
return

EditSub:
	;Get Values
	GuiControlGet,Rval,,eR
	GuiControlGet,Gval,,eG
	GuiControlGet,Bval,,eB
	;Set preview
	gosub set
	;Make Everything else aware
	GuiControl,,uR,%Rval%
	GuiControl,,uG,%Gval%
	GuiControl,,uB,%Bval%
	GuiControl,,sR,%Rval%
	GuiControl,,sG,%Gval%
	GuiControl,,sB,%Bval%
return

UpDownSub:
	;Get Values
	GuiControlGet,Rval,,uR
	GuiControlGet,Gval,,uG
	GuiControlGet,Bval,,uB
	;Set preview
	gosub set
	;Make Everything else aware
	GuiControl,,eR,%Rval%
	GuiControl,,eG,%Gval%
	GuiControl,,eB,%Bval%
	GuiControl,,sR,%Rval%
	GuiControl,,sG,%Gval%
	GuiControl,,sB,%Bval%
return

SliderSub:
	;Get Values
	GuiControlGet,Rval,,sR
	GuiControlGet,Gval,,sG
	GuiControlGet,Bval,,sB
	;Set preview
	gosub set
	;Make Everything else aware
	GuiControl,,eR,%Rval%
	GuiControl,,eG,%Gval%
	GuiControl,,eB,%Bval%
	GuiControl,,uR,%Rval%
	GuiControl,,uG,%Gval%
	GuiControl,,uB,%Bval%
return

set:
	;Convert values to Hex
	RGBval:=RGB(Rval,Gval,Bval)
	;Display Tooltip
	ToolTip Red: %Rval%`nGreen: %Gval%`nBlue: %Bval%`nHex: %RGBval%
	;Make tooltip disappear after 375 ms (3/8th of a second)
	SetTimer, RemoveToolTip, 375
	;Apply colour to preview
	GuiControl,+Background%RGBval%,pC
return

RemoveToolTip:
	SetTimer, RemoveToolTip, Off ;Turn timer off
	ToolTip ;Turn off tooltip
return

ButtonSub:
	;Remove '0x' prefix to hex color code, saving it directly to the clipboard
	StringReplace,Clipboard,RGBval,0x
	;Display Last selected values... (these values can later be used), and Notify the user
	MsgBox,64,Simple Color Dialog,RGB: (%Rval%, %Gval%, %Bval%)`nHex: %RGBval%`nCopied to Clipboard!
	;Skip Directly GuiClose
GuiClose:
	;Exit This Example script
	ExitApp

;Function to convert Decimal RGB to Hexadecimal RBG, Note: '0' (zero) padding is unnecessary
RGB(r, g, b) {
	;Shift Numbers
	var:=(r << 16) + (g << 8) + b
	;Save current A_FormatInteger
	OldFormat := A_FormatInteger
	;Set Hex A_FormatInteger mode
	SetFormat, Integer, Hex
	;Force decimal number to Hex number
	var += 0
	;set original A_FormatInteger mode
	SetFormat, Integer, %OldFormat%
	return var
}
Image
Cheers! :D
Last edited by joedf on 11 Oct 2013, 09:11, edited 1 time in total.
Image Image Image Image Image
Windows 10 x64 Professional, Intel i5-8500, NVIDIA GTX 1060 6GB, 2x16GB Kingston FURY Beast - DDR4 3200 MHz | [About Me] | [About the AHK Foundation] | [Courses on AutoHotkey]
[ASPDM - StdLib Distribution] | [Qonsole - Quake-like console emulator] | [LibCon - Autohotkey Console Library]
User avatar
xZomBie
Posts: 256
Joined: 02 Oct 2013, 02:57

Re: Simple Color Dialog

10 Oct 2013, 03:07

Hi! I just got a little time on my computer a few days ago and tried this script. It's awesome but one little thing that got really irritated is the every time I press the button Copy to Clipboard, the script will exit which is what you wanted it to do but since I am using it to get the hexadecimal code for the colours multille times I need to add the "Return" before the line GuiClose but nevermind that. I found this on the internet 《★☆http://html-color-codes.info/#HTML_Color_Picker☆★》 and I thouht maybe you could add a Edit for users to key In the hexadecimal code to see what colour comes out. Again, great script. Thank you. Sorry for this long post here.
User avatar
joedf
Posts: 8940
Joined: 29 Sep 2013, 17:08
Location: Canada
Contact:

Re: Simple Color Dialog

10 Oct 2013, 10:17

Oh ok, but Yeah just replace the ExitApp keyword with Return, and you're done!
Image Image Image Image Image
Windows 10 x64 Professional, Intel i5-8500, NVIDIA GTX 1060 6GB, 2x16GB Kingston FURY Beast - DDR4 3200 MHz | [About Me] | [About the AHK Foundation] | [Courses on AutoHotkey]
[ASPDM - StdLib Distribution] | [Qonsole - Quake-like console emulator] | [LibCon - Autohotkey Console Library]
Guest10
Posts: 578
Joined: 01 Oct 2013, 02:50

Re: Simple Color Dialog

10 Oct 2013, 14:58

very, very impressive & useful. something i was looking 4!
Alex
Posts: 3
Joined: 16 Oct 2013, 14:11

Re: Simple Color Dialog

16 Oct 2013, 14:45

SnowFlakes wrote:I thouht maybe you could add a Edit for users to key In the hexadecimal code to see what colour comes out. Again, great script. Thank you. Sorry for this long post here.
Check out my script, you can enter a hex code and see the color and more http://www.autohotkey.com/boards/viewtopic.php?f=6&t=302.
User avatar
joedf
Posts: 8940
Joined: 29 Sep 2013, 17:08
Location: Canada
Contact:

Re: Simple Color Dialog

16 Oct 2013, 15:10

Lol, Competition I see... ;)
Image Image Image Image Image
Windows 10 x64 Professional, Intel i5-8500, NVIDIA GTX 1060 6GB, 2x16GB Kingston FURY Beast - DDR4 3200 MHz | [About Me] | [About the AHK Foundation] | [Courses on AutoHotkey]
[ASPDM - StdLib Distribution] | [Qonsole - Quake-like console emulator] | [LibCon - Autohotkey Console Library]
Alex
Posts: 3
Joined: 16 Oct 2013, 14:11

Re: Simple Color Dialog

16 Oct 2013, 15:15

Nah, completely different purpose of the script. :)

Edit: I looked more closely at your script and I see some similarity's.
User avatar
joedf
Posts: 8940
Joined: 29 Sep 2013, 17:08
Location: Canada
Contact:

Re: Simple Color Dialog

16 Oct 2013, 15:32

Well, actually the goal of my script is to show basic usage of autohotkey.
It is an Example script, it is fully commented especially for that matter.
;) to help people :)
Image Image Image Image Image
Windows 10 x64 Professional, Intel i5-8500, NVIDIA GTX 1060 6GB, 2x16GB Kingston FURY Beast - DDR4 3200 MHz | [About Me] | [About the AHK Foundation] | [Courses on AutoHotkey]
[ASPDM - StdLib Distribution] | [Qonsole - Quake-like console emulator] | [LibCon - Autohotkey Console Library]
User avatar
Sjc1000
Posts: 39
Joined: 02 Oct 2013, 02:07

Re: Simple Color Dialog

19 Oct 2013, 23:57

Nice RGB function. I've been looking for one of these for a while.. Mind if i re-make this function?
Please find me on the IRC if you have any questions, I'm never on the forum anymore.
User avatar
joedf
Posts: 8940
Joined: 29 Sep 2013, 17:08
Location: Canada
Contact:

Re: Simple Color Dialog

20 Oct 2013, 02:39

@sjc1000 sure! ;) post it here if you want to! :)
Image Image Image Image Image
Windows 10 x64 Professional, Intel i5-8500, NVIDIA GTX 1060 6GB, 2x16GB Kingston FURY Beast - DDR4 3200 MHz | [About Me] | [About the AHK Foundation] | [Courses on AutoHotkey]
[ASPDM - StdLib Distribution] | [Qonsole - Quake-like console emulator] | [LibCon - Autohotkey Console Library]
User avatar
Sjc1000
Posts: 39
Joined: 02 Oct 2013, 02:07

Re: Simple Color Dialog

21 Oct 2013, 19:03

Whoops, one thing lead to another, i ended up making a whole colour picker :P

Code: Select all

guiColor 			:= 0x333333
fontColor 			:= 0xFFFFFF

guiWidth 			:= A_ScreenWidth / 4
controlW 			:= guiWidth - 130

guiX 				:= 10
guiY 				:= 10

timeout 			:= 6000



Random, red, 	0, 255
Random, green, 	0, 255
Random, blue, 	0, 255


Gui, 	Color, % guiColor
Gui,	Add, Progress, w%controlW% vmyRed 	background%guiColor% Range0-255, 	% red 
Gui, 	Add, Progress, w%controlW% vmyGreen background%guiColor% Range0-255,	% green
Gui, 	Add, Progress, w%controlW% vmyBlue 	background%guiColor% Range0-255, 	% blue


hex 			:= SC_RGB( red, green, blue )
Gui, 	Add, Edit, 		w%controlW% vmyHex, % hex


controlW 		+= 10
Gui, 	Add, Progress, w100 h100 vColour xp%controlW% y5  Background%hex%,

Gui, 	Show, w%guiWidth% x%guiX% y%guiY%, Colour picker - Sjc1000


Slide:
	;Gui, Submit, NoHide
	GuiControlGet, myRed,, myRed
	GuiControlGet, myGreen,, myGreen
	GuiControlGet, myBlue,, myBlue
	
	hex 			:= SC_RGB( myRed, myGreen, myBlue )
	
	hexRed 			:= SC_RGB( myRed, 0, 0 )
	hexGreen		:= SC_RGB( 0, myGreen, 0 )
	hexBlue 		:= SC_RGB( 0, 0, myBlue )
	
	GuiControl, +C%hexRed%, myRed
	GuiControl, +C%hexGreen%, myGreen
	GuiControl, +C%hexBlue%, myBlue
	
	GuiControl, +Background%hex%, Colour
	GuiControl, +C%hex%, Colour
	
	GuiControl,, myHex, % hex
Return


#IfWinActive, Colour picker - Sjc1000
WheelUp::
	MouseGetPos, mX, mY, mWin, mControl
	GuiControlGet, myVal,, % mControl
	
	If ( inStr( mControl, "Edit" ) )
		Return
	
	
	If ( myVal < 255 && myVal > -1)
		myVal++
	
	GuiControl,, % mControl, % myVal
	
	Goto, Slide
return

WheelDown::
	MouseGetPos, mX, mY, mWin, mControl
	GuiControlGet, myVal,, % mControl
	
	If ( inStr( mControl, "Edit" ) )
		Return
	If ( myVal > 0 )
		myVal--
	
	GuiControl,, % mControl, % myVal

	Goto, Slide
Return

~LButton::
	While( getKeyState("LButton", "P") )
	{	MouseGetPos, mX, mY, mWin, mControl
		ControlGetPos, cX, cY, cWidth, cHeight, % mControl, A
		GuiControlGet, myVal,, % mControl
		If ( inStr( mControl, "Edit" ) )
			Return
		currentPos 			:= mX / cWidth * 255 - cX - 2
		GuiControl,, % mControl, % currentPos
		SetTimer, Slide, -1
	}
Return
#If



SC_RGB( red, green, blue)
{	oldFormat 			:= A_FormatInteger

	SetFormat, Integer, Hex
	myOutput 			:= ( red << 16 ) + ( green << 8 ) + blue
	SetFormat, Integer, % oldFormat
	Return myOutput
}


Esc::ExitApp

return
Click / drag the progress bars, or scroll when your mouse is over them. :D

Image
Please find me on the IRC if you have any questions, I'm never on the forum anymore.
User avatar
joedf
Posts: 8940
Joined: 29 Sep 2013, 17:08
Location: Canada
Contact:

Re: Simple Color Dialog

21 Oct 2013, 20:18

Haha nice! I love the simple look and design!
Very nice! :D
Image Image Image Image Image
Windows 10 x64 Professional, Intel i5-8500, NVIDIA GTX 1060 6GB, 2x16GB Kingston FURY Beast - DDR4 3200 MHz | [About Me] | [About the AHK Foundation] | [Courses on AutoHotkey]
[ASPDM - StdLib Distribution] | [Qonsole - Quake-like console emulator] | [LibCon - Autohotkey Console Library]
Deletethisaccount
Posts: 13
Joined: 14 Dec 2013, 19:37

Re: Simple Color Dialog

14 Dec 2013, 20:31

Congratulations Script. The idea is very good, and thanks for sharing
Guest10
Posts: 578
Joined: 01 Oct 2013, 02:50

Re: Simple Color Dialog

14 Dec 2013, 23:27

congratulations for the new script! :lol: i also dusted this from my archives: :ugeek:

Code: Select all

/*
GCCP (Color-Picker) ... einfacher CP , per Hotkey Strg+Alt+c
wird der Hex-Wert in die Zwischenablage copiert; mit Strg+Alt+K
landet die Komplementärfarbe im Clipboard.
Es werden beide Farben angezeigt.
gero(Mai2009)
=================================================================
GCCP (Color-Picker) ... its an easy Tool, Hotkey Strg+Alt+c
copy the Hex-Code of the Color under Mouse into Clipbard;
and Strg+Alt+K copy the Complementary Color into Clipboard.
Both Colors are displayed in the Program-Window and the Code too.
gero(May2009)
*/

#NoEnv
#SingleInstance force
SendMode Input
SetBatchLines, -1
SetTitleMatchMode, 3
OnExit, undweg
Menu, Tray, Tip, Strg+Alt+C=copy
GUI +LastFound  +AlwaysOnTop
Gui, Show, x100 y100 w150 h185 , GCCP
Gui, Color, c0c0c0
Gui, Font, s12
Gui, Add, Text, x0  y5    w150 center vMMM , %AAA%
Gui, Font, s10
GUI, Add, Text, x15 y30  w40 center vROT    , %ROT%
GUI, Add, Text, x55 y30  w40 center vGRUEN  , %GRUEN%
GUI, Add, Text, x95 y30  w40 center vBLAU   , %BLAU%
GUI, Add, Text, x15 y155 w40 center vKROT   , %ROT%
GUI, Add, Text, x55 y155 w40 center vKGRUEN , %GRUEN%
GUI, Add, Text, x95 y155 w40 center vKBLAU  , %BLAU%
Gui, Font, s12
Gui, Add, Text, x0 y130 w150 center vCOMP   , %AAA%
Gui, Font, s100 bold, Wingdings
Gui, Add, Text,  x10 y20 h100 w65 c%CCC% vTTT  +BackgroundTrans , n
Gui, Add, Text,  x65 y20 h100 w65 c%PPP% vCCol +BackgroundTrans , n
WinSet, Transparent, 255, GCCP
SetTimer, COLORPIC, 50
return

ACTIVE:
IfWinActive, GCCP
{
setTimer, COLORPIC, OFF
WinWaitNotActive, GCCP
setTimer, COLORPIC, ON
}
return

COLORPIC:
MouseGetPos, X0, Y0,
PixelGetColor, CCC, X0, Y0 , RGB
StringRight, AAA, CCC, 6
GuiControl, Text, MMM, #%AAA%
Gui, Font, c%CCC%
GuiControl, Font, TTT
StringLeft, GR1, CCC, 2
GR2:= SubStr(CCC, 5 , 2)
GRUEN:= GR1 GR2
GRUEN +=0
StringRight, BL1, CCC, 2
BLAU:= GR1 BL1
BLAU +=0
StringLeft, ROT, CCC, 4
ROT +=0
GUICONTROL, Text, ROT, %ROT%
GUICONTROL, Text, GRUEN, %GRUEN%
GUICONTROL, Text, BLAU, %BLAU%
ROT:=255-ROT
GRUEN:=255-GRUEN
BLAU:=255-BLAU
GUICONTROL, Text, KROT, %ROT%
GUICONTROL, Text, KGRUEN, %GRUEN%
GUICONTROL, Text, KBLAU, %BLAU%
SetFormat, Integer, hex
ROT +=0
GRUEN +=0
BLAU +=0
StringTrimLeft, ROT, ROT, 2
StringUpper, KROT, ROT
if StrLen(KROT)=1
{
KROT:=0 KROT
}
StringTrimLeft, GRUEN, GRUEN, 2
StringUpper, KGRUEN, GRUEN
IF StrLen(KGRUEN)=1
{
KGRUEN:=0 KGRUEN
}
StringTrimLeft, BLAU, BLAU, 2
StringUpper, KBLAU, BLAU
if StrLen(KBLAU)=1
{
KBLAU:=0 KBLAU
}
PPP:= GR1 KROT KGRUEN KBLAU
ForClipB:=KROT KGRUEN KBLAU
Gui, Font, c%PPP%
GuiControl, Font, CCOL
GUICONTROL, Text, COMP, #%KROT%%KGRUEN%%KBLAU%
return

!c::
Clipboard=#%AAA%
return

!K::
Clipboard=#%ForClipB%
return

undweg:
GuiClose:
ExitApp
return
Sjc1000 wrote:Whoops, one thing lead to another, i ended up making a whole colour picker :P

Code: Select all

guiColor 			:= 0x333333
fontColor 			:= 0xFFFFFF

guiWidth 			:= A_ScreenWidth / 4
controlW 			:= guiWidth - 130

guiX 				:= 10
guiY 				:= 10

timeout 			:= 6000



Random, red, 	0, 255
Random, green, 	0, 255
Random, blue, 	0, 255


Gui, 	Color, % guiColor
Gui,	Add, Progress, w%controlW% vmyRed 	background%guiColor% Range0-255, 	% red 
Gui, 	Add, Progress, w%controlW% vmyGreen background%guiColor% Range0-255,	% green
Gui, 	Add, Progress, w%controlW% vmyBlue 	background%guiColor% Range0-255, 	% blue


hex 			:= SC_RGB( red, green, blue )
Gui, 	Add, Edit, 		w%controlW% vmyHex, % hex


controlW 		+= 10
Gui, 	Add, Progress, w100 h100 vColour xp%controlW% y5  Background%hex%,

Gui, 	Show, w%guiWidth% x%guiX% y%guiY%, Colour picker - Sjc1000


Slide:
	;Gui, Submit, NoHide
	GuiControlGet, myRed,, myRed
	GuiControlGet, myGreen,, myGreen
	GuiControlGet, myBlue,, myBlue
	
	hex 			:= SC_RGB( myRed, myGreen, myBlue )
	
	hexRed 			:= SC_RGB( myRed, 0, 0 )
	hexGreen		:= SC_RGB( 0, myGreen, 0 )
	hexBlue 		:= SC_RGB( 0, 0, myBlue )
	
	GuiControl, +C%hexRed%, myRed
	GuiControl, +C%hexGreen%, myGreen
	GuiControl, +C%hexBlue%, myBlue
	
	GuiControl, +Background%hex%, Colour
	GuiControl, +C%hex%, Colour
	
	GuiControl,, myHex, % hex
Return


#IfWinActive, Colour picker - Sjc1000
WheelUp::
	MouseGetPos, mX, mY, mWin, mControl
	GuiControlGet, myVal,, % mControl
	
	If ( inStr( mControl, "Edit" ) )
		Return
	
	
	If ( myVal < 255 && myVal > -1)
		myVal++
	
	GuiControl,, % mControl, % myVal
	
	Goto, Slide
return

WheelDown::
	MouseGetPos, mX, mY, mWin, mControl
	GuiControlGet, myVal,, % mControl
	
	If ( inStr( mControl, "Edit" ) )
		Return
	If ( myVal > 0 )
		myVal--
	
	GuiControl,, % mControl, % myVal

	Goto, Slide
Return

~LButton::
	While( getKeyState("LButton", "P") )
	{	MouseGetPos, mX, mY, mWin, mControl
		ControlGetPos, cX, cY, cWidth, cHeight, % mControl, A
		GuiControlGet, myVal,, % mControl
		If ( inStr( mControl, "Edit" ) )
			Return
		currentPos 			:= mX / cWidth * 255 - cX - 2
		GuiControl,, % mControl, % currentPos
		SetTimer, Slide, -1
	}
Return
#If



SC_RGB( red, green, blue)
{	oldFormat 			:= A_FormatInteger

	SetFormat, Integer, Hex
	myOutput 			:= ( red << 16 ) + ( green << 8 ) + blue
	SetFormat, Integer, % oldFormat
	Return myOutput
}


Esc::ExitApp

return
Click / drag the progress bars, or scroll when your mouse is over them. :D

Image
User avatar
Sjc1000
Posts: 39
Joined: 02 Oct 2013, 02:07

Re: Simple Color Dialog

21 Dec 2013, 03:01

@Guest10
Nice script. I like the opposite of what color you're hovering over. Very nice.
Please find me on the IRC if you have any questions, I'm never on the forum anymore.
IMEime
Posts: 750
Joined: 20 Sep 2014, 06:15

Re: Simple Color Dialog

28 Sep 2014, 15:50

Dear JoeDF

I just found your scrip.
And satisfied with it.

Gooood one.. thaaaanks !!
User avatar
joedf
Posts: 8940
Joined: 29 Sep 2013, 17:08
Location: Canada
Contact:

Re: Simple Color Dialog

28 Sep 2014, 21:06

You're welcome! :)
Image Image Image Image Image
Windows 10 x64 Professional, Intel i5-8500, NVIDIA GTX 1060 6GB, 2x16GB Kingston FURY Beast - DDR4 3200 MHz | [About Me] | [About the AHK Foundation] | [Courses on AutoHotkey]
[ASPDM - StdLib Distribution] | [Qonsole - Quake-like console emulator] | [LibCon - Autohotkey Console Library]
freespacing
Posts: 150
Joined: 28 Sep 2016, 11:14
Contact:

Re: Simple Color Dialog

09 Oct 2016, 09:25

This is the kind of inspiration I need to take my AHK to the next level. The more I hang around here, the more I discover that ahk is so much more than hotkeys.
Thank you!
User avatar
joedf
Posts: 8940
Joined: 29 Sep 2013, 17:08
Location: Canada
Contact:

Re: Simple Color Dialog

09 Oct 2016, 10:15

I'm glad. Happy programming! :D
Image Image Image Image Image
Windows 10 x64 Professional, Intel i5-8500, NVIDIA GTX 1060 6GB, 2x16GB Kingston FURY Beast - DDR4 3200 MHz | [About Me] | [About the AHK Foundation] | [Courses on AutoHotkey]
[ASPDM - StdLib Distribution] | [Qonsole - Quake-like console emulator] | [LibCon - Autohotkey Console Library]

Return to “Scripts and Functions (v1)”

Who is online

Users browsing this forum: gwarble and 112 guests