StrSplit() from right? Topic is solved

[Spark]

hello all,
is there any function for StrSplit() from right?

something like this

Code: Select all

input = E:\Folder 1\Sub Folder 2\Sub Folder 3\Sub Folder 4\picture.png
output := StrSplitRight(input ,\)
msgbox, % output[2] ; result : Sub Folder4\picture.png

thanks in advance

[Xtra]

It can be done with regex but it is generally slower for simple string manipulation.

Example function:

Code: Select all

input := "E:\Folder 1\Sub Folder 2\Sub Folder 3\Sub Folder 4\picture.png"
MsgBox % StrSplitRight(input,"\",2)

StrSplitRight(string,delim,count) {
    for i in Arr := StrSplit(string,delim) {
        output := Arr.pop() . (A_Index > 1 ?  delim . output : "")
    } until (A_Index = Count)
    return output
}

[Flipeador]

Code: Select all

input := "E:\Folder 1\Sub Folder 2\Sub Folder 3\Sub Folder 4\picture.png"
output := StrSplit(input, "\")
msgbox % output[output.Length()-1]    ; Sub Folder 4

[jeeswg]

- StrSplit has a MaxParts parameter (since AHK v1.1.28+). E.g.

Code: Select all

;StrSplit MaxParts (v1.1.28+)
MsgBox, % StrSplit("a,b,c,d,e", ",",, 3)[3] ;c,d,e

- You can use that to achieve what you want:

Code: Select all

q:: ;get the last n array items, joined, via StrSplit MaxParts (v1.1.28+)
vPath := "E:\Folder 1\Sub Folder 2\Sub Folder 3\Sub Folder 4\picture.png"
StrReplace(vPath, "\",, vCount)
Loop, % vCount+1
{
	vNum := A_Index
	vOutput .= vNum "`t" StrSplit(vPath, "\",, vCount+2-vNum)[vCount+2-vNum] "`r`n"
}
Clipboard := vOutput
MsgBox, % vOutput
return

- Note: with the mathematics: if there are n delimiters, then there are n+1 parts.
- Also, there's this:
file get part (SplitPath alternative/short-form/long-form/correct case) - AutoHotkey Community
https://autohotkey.com/boards/viewtopic.php?f=6&t=47709

[Spark]

It can be done with regex but it is generally slower for simple string manipulation.

Example function:

Code: Select all

input := "E:\Folder 1\Sub Folder 2\Sub Folder 3\Sub Folder 4\picture.png"
MsgBox % StrSplitRight(input,"\",2)

StrSplitRight(string,delim,count) {
    for i in Arr := StrSplit(string,delim) {
        output := Arr.pop() . (A_Index > 1 ?  delim . output : "")
    } until (A_Index = Count)
    return output
}

this is what i'm looking for...thank you very much

@Flipeador
thank you, very simple and elegant script..I'll need it for next project

@jeeswg
wow ..your script very detail.
but my logic not that expert, maybe i'll need that in the future


thank you for your help, have a good day

[Helgef]

Xtra, this will not work for any count.

Existing key-value pairs may be modified during the loop, but inserting or removing keys may cause some items to be skipped or enumerated multiple times

Example,

Code: Select all

for k in a:=[1,2,3,4,5,6]
	str .= a.pop() "`n" 
msgbox % str

A simpler version,

Code: Select all

StrSplitRight(string, delim, count){
	return substr(string, instr(string, delim,, -1, count) + 1)
}

Cheers.

[jeeswg]

- Here is some code using SubStr.

Code: Select all

q:: ;use SubStr to get the last n parts of a string
vPath := "E:\Folder 1\Sub Folder 2\Sub Folder 3\Sub Folder 4\picture.png"
vNum := 2
vIsV1 := !!InStr(1,1,1,0), vPos := vIsV1 ? -1 : 0
vPos := InStr(vPath, "\", 0, vPos, vNum)
MsgBox, % SubStr(vPath, vPos+1)
return

w:: ;use SubStr to get the last n parts of a string
vPath := "E:\Folder 1\Sub Folder 2\Sub Folder 3\Sub Folder 4\picture.png"
StrReplace(vPath, "\",, vCount)
vIsV1 := !!InStr(1,1,1,0)
Loop, % vCount+1
{
	vNum := A_Index
	vPos := vIsV1 ? -1 : 0
	vPos := InStr(vPath, "\", 0, vPos, vNum)
	vOutput .= vNum "`t" SubStr(vPath, vPos+1) "`r`n"
}
Clipboard := vOutput
MsgBox, % vOutput
return

- Btw with all techniques you should be aware re. what if you ask for the last n parts when there are fewer than n parts in the string.
- [EDIT:] Oh, just noticed, this is the 2018th thread I've appeared in. 2018, the current year!

[Xtra]

fixed:

Code: Select all

input := "E:\Folder 1\Sub Folder 2\Sub Folder 3\Sub Folder 4\picture.png"
MsgBox % StrSplitRight(input,"\",2)

StrSplitRight(string,delim,count) {
    Arr := StrSplit(string,delim)
    Loop % Arr.length() {
        output := Arr.pop() . (A_Index > 1 ?  delim . output : "")
    } until (A_Index = Count)
    return output
}

[Spark]

@Xtra
whoaa ... thanks for making it perfect

A simpler version,

Code: Select all

StrSplitRight(string, delim, count){
	return substr(string, instr(string, "\",, -1, count) + 1)
}

Cheers.

I have a little question about your simpler version,
what is this "delim" for?

if i change it to be

Code: Select all

StrSplitRight(string, count){
	return substr(string, instr(string, "\",, -1, count) + 1)

is there any difference??

best regards

[Helgef]

@ Spark, I fixed it.