Senden von Tasten in Abhängigkeit von bestimmten Fenstern

[festigrat]

Liebe Leute,

ich arbeite mit einem Programm, bei dem es ein Programmfenster und ein Editorfenster gibt. Das Editorfenster ist aber nicht immer da. Das Programmfenster ist immer das aktive Fenster. Nun will ich mit der Taste w das Editorfenster aktivieren (nur wenn auch da ist) und es soll die Taste o gesendet werden.

Ist das Editorfenster aber nicht da, soll die Taste w normal funktionieren. Ich habe das folgendermaßen versucht, aber es klappt nicht.

Code: Select all

w::
IfWinExist, Editor
{
WinActivate, Editor
	send, o
}
IfWinNotExist, Editor
	send, w
return

Die Taste w funktioniert nicht mehr und mit ~w:: funktioniert es auch nicht, da hier ja w gesendet wird, wenn das Editorfenster da ist, was nicht passieren soll. Außerdem entsteht manchmal eine Schleife, weil ich nochmal w sende, was das Skript ja wieder startet.
Über einen Tipp würde ich mich sehr freuen! Viele Grüße.

[gregster]

$ ist der korrekte Modifier, um eine Schleife zu verhindern, nicht ~: also $w::
Vgl. https://ahkde.github.io/docs/Hotkeys.htm#Symbols

[just me]

Code: Select all

#IfWinExist Editor ; oder woran auch immer man das Fenster eindeutig erkennen kann
w::
	WinActivate ; aktiviert das von #IfWinExist gefundene Fenster
	Send, o
Return
#IfWinExist

[festigrat]

Hallo gregster,
vielen Dank für die schnelle Antwort. Das scheint auf den ersten Blick perfekt damit zu funktionieren. Nochmals vielen Dank!

[garry]

oder Beispiel mit Groupadd

Code: Select all

;- send w zum Notepad (Editor)
;- send o zu  Notepad++
;- ( oder send Funktion umkehren )

SetTitleMatchMode, 2
;GroupAdd, myPr, Mozilla Firefox
;GroupAdd, myPr, Google Chrome
GroupAdd, myPr, Editor
;GroupAdd, myPr, Notepad++ 
#IfWinActive, ahk_group myPr
w::
send,{text}w
return
#IfWinActive
;-  
w::
send,{text}o
return

[just me]

Moin,

Du kannst das ja gern wie von gregster vorgeschlagen machen, für das Problem "Senden von Tasten in Abhängigkeit von bestimmten Fenstern" hat AHK aber die kontextabhängigen Hotkeys mit den zugehörigen Direktiven #IfWin[Not]Active / #IfWin[Not]Exist / #If.

Außerdem:
Bei typischen Ja/Nein-Entscheidungen gibt es genau einen If (Ja) und einen Else (Nein) Zweig. Das Innenleben Deiner Hotkeyroutine sollte deshalb so aussehen:

Code: Select all

IfWinExist, Editor
{
	WinActivate, Editor
	send, o
}
Else
	send, w
return

Die zweite Prüfung IfWinNotExist, Editor kannst Du Dir sparen.

[gregster]

Also mein Code-Vorschlag war das offensichtlich nicht - ich habe lediglich einen schnellen Tipp zu den Modifiern gegeben, der auf Basis des existenten Codes eine Verbesserung der Funktion im Sinne der Zielvorstellung des Thread-Erstellers herbeiführen und die Verwechslung von ~ und $ aufklären sollte...
Es war nicht als erschöpfende Antwort gedacht

[just me]

Hi gregster,

mein Hinweis war eher nicht an Dich gerichtet.