Open Folder and Close if already open

[ShYbeR]

Hello I am trying to make a script to open a specific folder and if it is already opened to close it.

Right now I have a script only to open the folder:

^F10::
Run C:\Users\XXX\Desktop\X3 Attachement
Return

[scriptor2016]

Code: Select all

Window=X3 Attachement

^f10::
IfWinExist, %Window%
Winclose, %Window%
else
run, C:\Users\XXX\Desktop\%Window%
Return

[ShYbeR]

thank you very much! it worked like a charm!

[ShYbeR]

So I tried adding onto the script by having it do the same for a different folder and it seem to work the first time but after that it only opens and closes the Estimate folder:

Code: Select all

Window=X3 Attachement

^f10::
IfWinExist, %Window%
Winclose, %Window%
else
run, C:\Users\XXX\Desktop\%Window%
Return

^f9::
Window=Estimates

IfWinExist, %Window%
Winclose, %Window%
else
run, C:\Users\XXX\Desktop\%Window%
Return

[hd0202]

the variable "Window" is set to "X3 Attachment" only at the start of the script (auto-execution section) and not again when you press ^f10. see my change below.

Code: Select all

^f10::
Window=X3 Attachement

IfWinExist, %Window%
Winclose, %Window%
else
run, C:\Users\XXX\Desktop\%Window%
Return

Hubert

[tmplinshi]

Potential issues:

• Different folders path may have the same folder name.
• The window title could be the folder name or path based on user settings.

A more reliable method is to use ComObjCreate("Shell.Application"):

Code: Select all

^f10::FolderToggleOpen("C:\Users\XXX\Desktop\X3 Attachement")
^f9::FolderToggleOpen("C:\Users\XXX\Desktop\Estimates")

FolderToggleOpen(FolderPath) {
	For Window In ComObjCreate("Shell.Application").Windows {
		If (RTrim(Window.Document.Folder.Self.Path, "\") = RTrim(FolderPath, "\"))
			Return Window.Quit
	}
	Run, % FolderPath
}

Edit: Changed window.LocationURL to window.Document.Folder.Self.Path as jeeswg suggested.
Edit2: Changed WinClose, % "ahk_id " window.hWnd to Window.Quit.

[jeeswg]

@tmplinshi: One thing to consider is this. Cheers.
RTrim(window.Document.Folder.Self.Path, "\")

[tmplinshi]

Oh, nice. I didn't know that. Thanks jeeswg!

[teadrinker]

@jeeswg
Is RTrim really needed?

Code: Select all

for window in ComObjCreate("Shell.Application").Windows
   MsgBox, % window.Document.Folder.Self.Path

[jeeswg]

For most paths, there is no trailing backslash.
An exception is the root of the drive e.g. C:\.

[teadrinker]

Right, thanks.

[ShYbeR]

thank you very much everyone!