Create named arrays from rows Topic is solved

[A_Perry_1984]

I have been trying to figure this out. I have a list and want to create arrays from every line, but I want also to name the array for each line after the first column. I am just not sure what I am missing here.

Code: Select all

#SingleInstance, Force
TaskX := []

List =
(
ListA	Info	more Info
ListB	Data	more Data
)

Loop, parse, List, `n
{	

	TaskX%A_Index% := StrSplit(A_LoopField, "`t").1 ; Array name is the first column
	TaskX[A_Index] := StrSplit(A_LoopField, "`t") ;Create an array from each variable name
	
}
For k, v in ListA
	MsgBox, 0x1000,, % v

*esc::
ExitApp

[Chunjee]

Not sure if this matches the exact output you are looking for. output is ["ListA":"Info more Info", "ListB":"Data more Data"]

Code: Select all

List =
(
ListA	Info	more Info
ListB	Data	more Data
)

TaskX := []
Loop, parse, List, `n
{	
    elementArr := StrSplit(A_LoopField, "`t")
	TaskX[elementArr[1]] :=  elementArr[2] " " elementArr[3]
}
; => ["ListA":"Info more Info", "ListB":"Data more Data"]
ExitApp

[A_Perry_1984]

Problem is I actually don't know the number of rows.

[Chunjee]

you mean columns?

[A_Perry_1984]

Sorry. My initial post wasn't exactly clear. I was just using the list above as an example. I am actually reading from a csv file with an indeterminate number of lines. When it reads a line, I want each line to be stored as an array but have that array named after the first column. So basically ListA would be it's own array containing everything on that line as elements.

[Xtra]

Code: Select all

#NoEnv
#SingleInstance, Force

TaskX := []

List =
(
ListA	Info	more Info
ListB	Data	more Data
)

Loop, Parse, List, `n, `r
{	
    row := A_LoopField
	Loop, Parse, row, `t
	    if (A_Index = 1)
		    TaskX[key := A_LoopField] := []
		else
		    TaskX[key].push(A_LoopField)
}

for each, arr in TaskX
	for i, value in arr
	    MsgBox, 0x1000, % each, % "index " . i . "`nvalue " . value

ExitApp

[Chunjee]

You still didn't say how you would like the output to look like.


How I would do it:

Code: Select all

A := new biga()
List =
(
ListA	Info	more Info
ListB	Data	more Data
)
TaskX := []

Loop, parse, List, `n
{	
    elementArr := StrSplit(A_LoopField, "`t")
	TaskX[A.head(elementArr)] := (A.tail(elementArr))
}
clipboard := A.printObj(TaskX)
; => ["ListA": [1:"Info", 2:"more Info"], "ListB": [1:"Data", 2:"more Data"]]
ExitApp

requires https://www.npmjs.com/package/biga.ahk

[flyingDman]

Sorry. My initial post wasn't exactly clear. I was just using the list above as an example. I am actually reading from a csv file with an indeterminate number of lines. When it reads a line, I want each line to be stored as an array but have that array named after the first column. So basically ListA would be it's own array containing everything on that line as elements.

So array ListA contains 3 elements (ListA, Info, more Info) and array ListB contains 3 elements (ListB,Data,more Data).
Try this:

Code: Select all

List =
(
ListA	Info	more Info
ListB	Data	more Data
)

for a,b in strsplit(list,"`n","`r")
	tmp := strsplit(b,"`t"),z := tmp.1, %z% := tmp             ;or z := tmp.RemoveAt(1) to exclude ListX from the arrays

msgbox % listA.1 "`t" listA.2 "`t" listA.3
msgbox % listB.1 "`t" listB.2 "`t" listB.3

[A_Perry_1984]

Okay, mind blown here. Thank you.