PostMessage Not Working on 64-bit Windows 7

[1100++]

My system is running a fresh install of Windows 7 Ultimate SP1 64-bit. The hotkeys in the script right below always operate on a non-active window if the active window belongs to a 32-bit process and may operate on a non-active window if the active window belongs to a 64-bit process.

Code: Select all

#NoEnv
SetBatchLines -1

DllCall("QueryPerformanceFrequency", "Int64*", freq)
GroupAdd ExclWindows, ahk_class Shell_TrayWnd
GroupAdd ExclWindows, ahk_class DV2ControlHost

Loop {
	KeyWait RWin, D
	DllCall("QueryPerformanceCounter", "Int64*", RWinDownTimestamp)
	KeyWait RWin
} return

#If A_PriorKey == "RWin" and DllCall("QueryPerformanceCounter", "Int64*", RWinUpTimestamp) and 2 * (RWinUpTimestamp - RWinDownTimestamp) < freq and WinExist("A",, "ahk_group ExclWindows")

RWin Up:: PostMessage 0x112, 0xF020     ; Should minimize the active window
^RWin Up:: PostMessage 0x112, 0xF060    ; Should close the active window

#If

However, the hotkeys in the script below function properly:

Code: Select all

#NoEnv
SetBatchLines -1

DllCall("QueryPerformanceFrequency", "Int64*", freq)

Loop {
	KeyWait RWin, D
	DllCall("QueryPerformanceCounter", "Int64*", RWinDownTimestamp)
	KeyWait RWin
} return

#If A_PriorKey == "RWin" and DllCall("QueryPerformanceCounter", "Int64*", RWinUpTimestamp) and 2 * (RWinUpTimestamp - RWinDownTimestamp) < freq and DllCall("IsWindowVisible", "Ptr", hWndMin := DllCall("GetForegroundWindow", "Ptr")) and VarSetCapacity(MinWinClass, 257 << (A_IsUnicode = true)) and DllCall("GetClassName", "Ptr", hWndMin, "Str", MinWinClass, "Int", 257) and !in(MinWinClass, "Shell_TrayWnd,DV2ControlHost")

RWin Up:: DllCall("PostMessage", "Ptr", hWndMin, "UInt", 0x112, "UInt", 0xF020, "UInt", 0)
^RWin Up:: DllCall("PostMessage", "Ptr", hWndMin, "UInt", 0x112, "UInt", 0xF060, "UInt", 0)

#If

in(string, list) {
	If string in list
		return true
	return false
}

[just me]

Code: Select all

RWin Up:: PostMessage 0x112, 0xF020     ; Should minimize the active window

No, it should minimize the "Last Found Window", if any. What makes you think that PostMessage is not working?

[Xtra]

If you want to minimize the active window:

Code: Select all

PostMessage 0x112, 0xF020,,, % "ahk_id " . WinExist("A")

[Helgef]

Your problem is this,

If WinTitle is the letter A and the other 3 window parameters (WinText, ExcludeTitle and ExcludeText) are blank or omitted, the active window will be used.

and

ExcludeTitle
Type: String

Windows whose titles include this value will not be considered.

The ExcludeTitle parameter is not a WinTitle parameter, so ahk_xxx is not supported. Specifically, WinExist("A",, "ahk_group ExclWindows") will not set the last found window (to non-zero) unless there is a window which title contains an A and also doesn't contain the text ahk_group ExclWindows.

You can do

Code: Select all

#if !WinActive("ahk_group mygrp") && WinExist("A")
a::postmessage x,y

Cheers.

Spoiler

Code: Select all

DllCall("PostMessage", "Ptr", hWndMin, "UInt", 0x112, "UInt", 0xF020, "UInt", 0)

should be

Code: Select all

DllCall("PostMessage", "Ptr", hWndMin, "UInt", 0x112, "uptr", 0xF020, "ptr", 0)

to be compatible with both AHK 32 bit and 64 bit.