How to quickly generate random strings? Topic is solved

[afe]

How to quickly generate a random string of length 4 containing only numbers and lowercase letters? And allow up to 3 characters to be repeated.

The following code is too verbose, how can I improve it?

Code: Select all

s := "0,1,2,3,4,5,6,7,8,9,a,b,c,d,e,f,g,h,i,j,k,l,m,n,o,p,q,r,s,t,u,v,w,x,y,z"

Loop, 3
   i .= s . ","

i := RTrim(i, ",")
Sort, i, Random D,
i := StrReplace(i, ",")
i := SubStr(i, 1, 4)
msgbox % i

[Odlanir]

Code: Select all

str := "0123456789abcdefghijklmnopqrstuvwxyz"
s := StrSplit(str str str)
Loop, 4 {
   Random, rnd, 1, % s.MaxIndex() 
   i .= s.removeat(rnd) 
}
msgbox % i

[boiler]

Another alternative:

Code: Select all

s := (s := "0123456789abcdefghijklmnopqrstuvwxyz") . s . s
loop, 4 {
	Random, r, 1, StrLen(s)
	i .= (c := SubStr(s, r, 1))
	StrReplace(s, c, "",, 1)
}
MsgBox, % i

[boiler]

Code: Select all

s := (s := "0,1,2,3,4,5,6,7,8,9,a,b,c,d,e,f,g,h,i,j,k,l,m,n,o,p,q,r,s,t,u,v,w,x,y,z") "," s "," s
Sort, s, Random D,
i := SubStr(StrReplace(s, ","), 1, 4)
MsgBox, % i

[Chunjee]

How to quickly generate a random string of length 4 containing only numbers and lowercase letters? And allow up to 3 characters to be repeated.

My take:

Code: Select all

A := new biga() ; requires https://www.npmjs.com/package/biga.ahk

characters := [0,1,2,3,4,5,6,7,8,9,"a","b","c","d","e","f","g","h","i","j","k","l","m","n","o","p","q","r","s","t","u","v","w","x","y","z"]
randomString := A.join(A.sampleSize(characters, 4), "")
msgbox, % randomString
; => "is2a"

My attempt allowing for repeats but no more than 3 spec:

Code: Select all

A := new biga() ; requires https://www.npmjs.com/package/biga.ahk

characters := [0,1,2,3,4,5,6,7,8,9,"a","b","c","d","e","f","g","h","i","j","k","l","m","n","o","p","q","r","s","t","u","v","w","x","y","z"]
randomArr := []
while (randomArr.Count() != 4) {
	randomChar := A.sample(characters)
	if (A.count(randomArr, randomChar) = 3) {
		continue
	}
	randomArr.push(randomChar)
}
randomString := A.join(randomArr, "")
msgbox, % randomString
; => "mqm8"

[boiler]

My attempt following the 'no 3 characters repeat' spec:

You can have 3 repeated. You can't have all 4 be the same.

[SKAN]

Spoiler

Code: Select all

s := (s := "0,1,2,3,4,5,6,7,8,9,a,b,c,d,e,f,g,h,i,j,k,l,m,n,o,p,q,r,s,t,u,v,w,x,y,z") "," s "," s
Sort, s, Random D,
i := SubStr(StrReplace(s, ","), 1, 4)
MsgBox, % i

Excellent!

[boiler]

Excellent!

Thanks!

[malcev]

I think that using autohotkey sort is not quick solution.
My variant:

Code: Select all

setbatchlines -1
a := a_tickcount
str := "0123456789abcdefghijklmnopqrstuvwxyz"
loop 1000000
{
   start:
   Random, rnd, 1, 36
   fin := SubStr(str, rnd, 1)
   Random, rnd, 1, 36
   fin .= SubStr(str, rnd, 1)
   Random, rnd, 1, 36
   fin .= SubStr(str, rnd, 1)
   Random, rnd, 1, 36
   fin .= SubStr(str, rnd, 1)
   if RegexMatch(fin, "^(.)\1+$")
      goto start
}
MsgBox, % a_tickcount - a

[Chunjee]

You can have 3 repeated. You can't have all 4 be the same.

Ah funny enough my code will allow 3 repeats and not 4 by accident

[boiler]

I think that using autohotkey sort is not quick solution.

True that it's not the fastest. Also not the stated goal in this case. He wanted it less verbose.

[malcev]

The topic name is - "How to quickly generate random strings?"
Everyone has their own opinion about "quickly".
My code is nearly 7 times faster than Yours using sort command.

[afe]

Code: Select all

s := "0,1,2,3,4,5,6,7,8,9,a,b,c,d,e,f,g,h,i,j,k,l,m,n,o,p,q,r,s,t,u,v,w,x,y,z"

Loop, 3
   i .= s . ","

Sort, i, Random D,
i := SubStr(i, 1, 7)
i := StrReplace(i, ",")
msgbox % i

I simplified it a little bit.