[Script] Task Manager with Filter and Multi-Kill-Process

Post your working scripts, libraries and tools for AHK v1.1 and older
fenchai
Posts: 292
Joined: 28 Mar 2016, 07:57

[Script] Task Manager with Filter and Multi-Kill-Process

27 May 2020, 08:38

https://github.com/fenchai23/taskManager

I created this script to solve the problem Microsoft could not.

Ooops: I forgot that because I am using Multiple Monitors, the coordinates from the TaskManager.ini are way off the charts, so make sure to delete it in case nothing happens when you launch it. Fixed bug in future versions by adding taskManager.ini to gitignore.
  • Filtering
  • Can kill multiple processes.
  • Stays in the tray for quick access.
Please try and contribute if you enjoyed it or share any ideas for improvements :)

Image

for quick copy paste:
Remember this is v1 and future versions should be downloaded from my https://github.com/fenchai23/taskManager as I am lazy to update here :)

Code: Select all

; --------------------------------------------------
; | Script by fenchai made in September/07/2019|
; --------------------------------------------------
#SingleInstance Force
#Persistent
#NoEnv
Setbatchlines, -1
SetWorkingDir %A_ScriptDir%

; https://docs.microsoft.com/en-us/windows/win32/cimwin32prov/win32-process

AppWindow := "Task Manager with Filter | come on Microsoft, if I could do it..."

LogFile := A_ScriptDir "\TaskManager.ini"

Read_Log()

; Build Tray Menu
Menu, Tray, NoStandard

Menu, Tray, Icon, imageres.dll, 23

Menu, Tray, Add, % AppWindow, Show
Menu, Tray, Icon, % AppWindow, imageres.dll, 23
Menu, Tray, Default, % AppWindow
Menu, Tray, Add
Menu, Tray, Add, Edit, Edit
Menu, Tray, Add, Reload, Reload
Menu, Tray, Add, Exit, Exit

; Build GUI
Gui, +AlwaysOnTop +Resize +ToolWindow
Gui, Add, Edit, w300 Section vYouTyped
Gui, Add, Button, ys w50 gClear default, Clear
Gui, Add, Button, ys gFill_LVP default, Update
Gui, Add, Button, ys gKill, End Task
Gui, Add, Button, ys gjk, Kill Them All
Gui, font, cGreen w700
Gui, Add, Text, Section xs vCpu, CPU Load: 00 `%
Gui, Add, Text, ys vRam, Used RAM: 00 `%
Gui, font, cBlack w400
Gui, Add, Checkbox, ys vShowSystemProcesses gFill_LVP, Show System
Gui, Add, Text, ys vCount, Preparing data...
Gui, Add, ListView, Section xs w480 r25 vLVP hwndLVP gLVP_Events +AltSubmit, Process Name|PID|Creation Time|RAM (MB)|Executable Path
SetWindowTheme(LVP)
; Fill GUI
gosub, Fill_LVP

; Show GUI
; MsgBox, 4096, catching coordinates, x=%GX% y=%GY% h%GH% w=%GW%
GH -= 39
GW -= 15
Gui, Show, x%GX% y%GY% h%GH% w%GW%, % AppWindow

settimer, UpdateStats, 500

return

UpdateStats:
    GuiControl, text, Cpu, % "CPU Load: " cpuload() "%"
    GuiControl, text, Ram, % "Used RAM: " memoryload() "%"
return

Format_Columns:
    
    LV_ModifyCol(1, (A_GuiWidth*(150/701)))
    LV_ModifyCol(2, (A_GuiWidth*(50/701)) " integer")
    LV_ModifyCol(3, (A_GuiWidth*(70/701)) " integer")
    LV_ModifyCol(4, (A_GuiWidth*(75/701)) " Integer SortDesc")
    LV_ModifyCol(5, (A_GuiWidth*(315/701)))
return

Clear:
    GuiControl, Text, YouTyped,
    GuiControl, Focus, YouTyped
    gosub, Fill_LVP
return

Fill_LVP:
    
    GuiControl, -Redraw, LVP
    
    Gui, Submit, NoHide
    
    LV_Delete()
    IL_Destroy(ImageList)
    ImageList := IL_Create()
    LV_SetImageList(ImageList)
    
    count := 0
    
    for process in ComObjGet("winmgmts:").ExecQuery("Select * from Win32_Process") {
        ; Add Icons to the list
        if !(IL_Add(ImageList, ProcessPath(process.Name)))
            IL_Add(ImageList, A_WinDir "\explorer.exe")
        
        ; Fill the list
        If (InStr(process.Name, YouTyped) && ShowSystemProcesses = 1) {
            LV_Add("Icon" A_Index, process.Name, process.processId, ProcessCreationTime(process.processId), Round(process.WorkingSetSize / 1000000, 2), process.ExecutablePath)
            count++
        } Else {
            if (process.ExecutablePath = "")
                Continue
            If (InStr(process.Name, YouTyped)) {
                LV_Add("Icon" A_Index, process.Name, process.processId, ProcessCreationTime(process.processId), Round(process.WorkingSetSize / 1000000, 2), process.ExecutablePath)
                count++
            }
        }
    }
    
    GuiControl, text, Count, % count " Processes"
    GuiControl, +Redraw, LVP
    
    LV_ModifyCol(4, " Integer SortDesc") ; make it sort by RAM usage
    
return

kill:
    RowNumber := 0 ; This causes the first loop iteration to start the search at the top of the list.
    selected := {}
    Loop
    {
        RowNumber := LV_GetNext(RowNumber) ; Resume the search at the row after that found by the previous iteration.
        if not RowNumber ; The above returned zero, so there are no more selected rows.
            break
        LV_GetText(pid, RowNumber, 2)
        LV_GetText(pname, RowNumber, 1)
        selected.Insert(RowNumber " ) " pname, pid)
    }
    
    selected_parsed := "Kill " selected.count() " Items?`n"
    
    for k, v in selected
    {
        selected_parsed .= k " : " v "`n"
    }

    MsgBox, 4131, , % selected_parsed
        IfMsgBox, Yes
        {
            for k, v in selected
            {
                Process, Close, % v
            }
            ; refresh after killing all
            gosub, Fill_LVP
        }
    
    return

LVP_Events:
    If (A_GuiEvent = "DoubleClick") {
        gosub, kill
    ; LV_GetText(xPid, A_EventInfo, 1)
    ; LV_GetText(xNam, A_EventInfo, 2)
    ; MsgBox % "Pid`t" xpid "`nName`t" xNam
}
Return

jk:
    MsgBox, 4096, % "Kill Them All?", "lol jk, are u insane?"
return

GuiClose:
GuiEscape:
Write_Log()
;~ ExitApp
Gui, hide
return

Show:
    Gui, show
return

#If WinActive(AppWindow)
    
Del::
    Send, ^a{Del}
    gosub, Fill_LVP
return

#If
    
ProcessExist(ProcessName) {
    Process, Exist, %ProcessName%
return ErrorLevel
}

ProcessPath(ProcessName) {
    ProcessId := InStr(ProcessName, ".")?ProcessExist(ProcessName):ProcessName
    , hProcess := DllCall("Kernel32.dll\OpenProcess", "UInt", 0x0400|0x0010, "UInt", 0, "UInt", ProcessId)
    , FileNameSize := VarSetCapacity(ModuleFileName, (260 + 1) * 2, 0) / 2
    if !(DllCall("Psapi.dll\GetModuleFileNameExW", "Ptr", hProcess, "Ptr", 0, "Str", ModuleFileName, "UInt", FileNameSize))
        if !(DllCall("Kernel32.dll\K32GetModuleFileNameExW", "Ptr", hProcess, "Ptr", 0, "Str", ModuleFileName, "UInt", FileNameSize))
        DllCall("Kernel32.dll\QueryFullProcessImageNameW", "Ptr", hProcess, "UInt", 1, "Str", ModuleFileName, "UIntP", FileNameSize)
return ModuleFileName, DllCall("Kernel32.dll\CloseHandle", "Ptr", hProcess)
}

ProcessCreationTime( PID ) { 
    hPr := DllCall( "OpenProcess", UInt,1040, Int,0, Int,PID )
    DllCall( "GetProcessTimes", UInt,hPr, Int64P,UTC, Int,0, Int,0, Int,0 )
    DllCall( "CloseHandle", Int,hPr)
    DllCall( "FileTimeToLocalFileTime", Int64P,UTC, Int64P,Local ), AT := 1601
    AT += % Local//10000000, S
    FormatTime, AT, % AT, hh:mm:ss yy-MM-dd
Return AT
}

Reload:
    Reload
return

Exit:
    ExitApp
return

Edit:
    Edit
return

Read_Log() {
    global
    
    LogConfig=
    (
    [Position]
    LogX=20
    LogY=20
    LogH=600
    LogW=500
    )
    
    IfNotExist, %LogFile%
        FileAppend, %LogConfig%, %LogFile%
    
    Iniread, GX, %LogFile%, Position, LogX
    Iniread, GY, %LogFile%, Position, LogY
    Iniread, GH, %LogFile%, Position, LogH
    Iniread, GW, %LogFile%, Position, LogW
}

Write_Log() {
    global
    
    WinGetPos, GX, GY, GW, GH, %AppWindow%
    IniWrite, %GX%, %LogFile%, Position, LogX
    IniWrite, %GY%, %LogFile%, Position, LogY
    IniWrite, %GH%, %LogFile%, Position, LogH
    IniWrite, %GW%, %LogFile%, Position, LogW
    
    ; MsgBox, 4096, catching coordinates, x=%GX% y=%GY% h%GH% w=%GW%
}

GUISize:
GuiControl, -Redraw, LVP
LVwidth := A_GuiWidth - 15
LVheight := A_GuiHeight - 80

GuiControl, move, LVP, w%LVwidth% h%LVheight%
GuiControl, move, LVP, w%LVwidth% h%LVheight%

gosub Format_Columns
GuiControl, +Redraw, LVP
return

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Excerpt from htopmini v0.8.3
; by jNizM
; http://ahkscript.org/boards/viewtopic.php?f=6&t=254
; https://github.com/jNizM/htopmini/blob/master/src/htopmini.ahk
UpdateMemory:
    GMSEx := GlobalMemoryStatusEx()
    GMSExM01 := Round(GMSEx[2] / 1024**2, 1) ; Total Physical Memory in MB
    GMSExM02 := Round(GMSEx[3] / 1024**2, 1) ; Available Physical Memory in MB
    GMSExM03 := Round(GMSExM01 - GMSExM02, 1) ; Used Physical Memory in MB
    GMSExM04 := Round(GMSExM03 / GMSExM01 * 100, 1) ; Used Physical Memory in %
    GMSExS01 := Round(GMSEx[4] / 1024**2, 1) ; Total PageFile in MB
    GMSExS02 := Round(GMSEx[5] / 1024**2, 1) ; Available PageFile in MB
    GMSExS03 := Round(GMSExS01 - GMSExS02, 1) ; Used PageFile in MB
    GMSExS04 := Round(GMSExS03 / GMSExS01 * 100, 1) ; Used PageFile in %
    UsedRAM := GMSExM04 ; save used RAM
    UsedPage := GMSExS04 ; save used Page
    GuiControl,,UsedRAMPercentage,[Used RAM: %GMSExM04%`%]
    GuiControl,,UsedPageFilePercentage,[Used Page: %GMSExS04%`%]
return

GlobalMemoryStatusEx() {
    static MEMORYSTATUSEX, init := VarSetCapacity(MEMORYSTATUSEX, 64, 0) && NumPut(64, MEMORYSTATUSEX, "UInt")
    if (DllCall("Kernel32.dll\GlobalMemoryStatusEx", "Ptr", &MEMORYSTATUSEX))
    {
        return { 2 : NumGet(MEMORYSTATUSEX, 8, "UInt64")
            , 3 : NumGet(MEMORYSTATUSEX, 16, "UInt64")
            , 4 : NumGet(MEMORYSTATUSEX, 24, "UInt64")
        , 5 : NumGet(MEMORYSTATUSEX, 32, "UInt64") }
    }
}

MemoryLoad()
{
    static MEMORYSTATUSEX, init := NumPut(VarSetCapacity(MEMORYSTATUSEX, 64, 0), MEMORYSTATUSEX, "uint")
    if !(DllCall("GlobalMemoryStatusEx", "ptr", &MEMORYSTATUSEX))
        throw Exception("Call to GlobalMemoryStatusEx failed: " A_LastError, -1)
return NumGet(MEMORYSTATUSEX, 4, "UInt")
}

CPULoad() { ; By SKAN, CD:22-Apr-2014 / MD:05-May-2014. Thanks to ejor, Codeproject: http://goo.gl/epYnkO
    Static PIT, PKT, PUT ; http://ahkscript.org/boards/viewtopic.php?p=17166#p17166
IfEqual, PIT,, Return 0, DllCall( "GetSystemTimes", "Int64P",PIT, "Int64P",PKT, "Int64P",PUT )

DllCall( "GetSystemTimes", "Int64P",CIT, "Int64P",CKT, "Int64P",CUT )
, IdleTime := PIT - CIT, KernelTime := PKT - CKT, UserTime := PUT - CUT
, SystemTime := KernelTime + UserTime 

Return ( ( SystemTime - IdleTime ) * 100 ) // SystemTime, PIT := CIT, PKT := CKT, PUT := CUT 
}

AutoStart:
    If A_IsCompiled {
        IfNotExist, %A_Startup%\MemoryHogs.lnk
        {
            FileCreateShortcut, %A_ScriptFullPath%, %A_Startup%\MemoryHogs.lnk
            Menu,Tray,Check,AutoStart
            MsgBox,,,Added to Startup,1
            AutoStart := 1
            IniWrite,%AutoStart%,MemoryHogs.ini,Settings,AutoStart
        }
        else 
            gosub, RemoveFromStartup
    }
return

;remove startup item
RemoveFromStartup:
    If A_IsCompiled {
        IfExist, %A_Startup%\Exercises.lnk
        {
            FileDelete, %A_Startup%\MemoryHogs.lnk
            Menu,Tray,UnCheck,AutoStart
            MsgBox,,,Removed from Startup,1
            AutoStart := 0
            IniWrite,%AutoStart%,MemoryHogs.ini,Settings,AutoStart
        }
    }
return

SetWindowTheme(handle) ; https://msdn.microsoft.com/en-us/library/bb759827(v=vs.85).aspx
{
    if (DllCall("GetVersion") & 0xff >= 10) {
        VarSetCapacity(ClassName, 1024, 0)
        if (DllCall("user32\GetClassName", "ptr", handle, "str", ClassName, "int", 512, "int"))
            if (ClassName = "SysListView32") || (ClassName = "SysTreeView32")
            if !(DllCall("uxtheme\SetWindowTheme", "ptr", handle, "wstr", "Explorer", "ptr", 0))
            return true
    }
return false
}
Changelog: (For New updates please go to my Github page)
  • Added dynamic automatic periodic updates to the list.
  • Added CPU column ( does not work perfectly and requires user to launch script in admin-mode )
  • Improved UX a lot by changing How ENTER, DEL Key and MOUSE CLICKS reacts on the App.
  • Added Context Menu
  • Added Helpful Tooltips and Statusbars
  • Added option to open File Directory
  • Added Restart option in menu
  • Added Show All related processes option in menu
  • Removed CPU column if not on admin mode
  • UI should feel faster on the newest updates
Last edited by fenchai on 03 Jun 2020, 23:24, edited 9 times in total.
fenchai
Posts: 292
Joined: 28 Mar 2016, 07:57

Re: Task Manager with Filter and Multi-Kill-Process

27 May 2020, 08:38

- Reserved.

I had some problems posting this so if it is duplicated, let me know
robodesign
Posts: 934
Joined: 30 Sep 2017, 03:59
Location: Romania
Contact:

Re: [Script] Task Manager with Filter and Multi-Kill-Process

27 May 2020, 08:46

looks pretty neat! however .... can it display when an application was started [time] ? and update list at given interval?... and cpu usage?

does it distinguish between UWP applications started through ApplicationsFrameHost thingy?

Best regards, Marius.
-------------------------
KeyPress OSD v4: GitHub or forum. (presentation video)
Quick Picto Viewer: GitHub or forum.
AHK GDI+ expanded / compilation library (on GitHub)
My home page.
WOlfen
Posts: 61
Joined: 14 Jan 2018, 16:48

Re: [Script] Task Manager with Filter and Multi-Kill-Process

27 May 2020, 10:29

I love Taskmanagers in AHK.
Especially cause i don´t like the built in one from Windows.
So thank you for creating this.
But... how do i activate it?
fenchai
Posts: 292
Joined: 28 Mar 2016, 07:57

Re: [Script] Task Manager with Filter and Multi-Kill-Process

27 May 2020, 12:40

robodesign wrote:
27 May 2020, 08:46
looks pretty neat! however .... can it display when an application was started [time] ? and update list at given interval?... and cpu usage?

does it distinguish between UWP applications started through ApplicationsFrameHost thingy?

Best regards, Marius.
Yes, the start time of app is the creation column, and cpu usage I think it's possible, I will look into it. and the update list at interval is possible, I might add a function for it.

No idea on the UWP thingy, I'm not sure how useful of info it is. But if it's in the process name, it should be easy to identify.
WOlfen wrote:
27 May 2020, 10:29
I love Taskmanagers in AHK.
Especially cause i don´t like the built in one from Windows.
So thank you for creating this.
But... how do i activate it?
You can Activate it by just running it. I haven't set a hotkey for it. But once open it stays on the tray menu so you can double click it to show again.
edit if GUI not showing, delete the the .ini file, because I use multiple monitors, the coordinates are off the charts
Last edited by fenchai on 27 May 2020, 13:45, edited 1 time in total.
robodesign
Posts: 934
Joined: 30 Sep 2017, 03:59
Location: Romania
Contact:

Re: [Script] Task Manager with Filter and Multi-Kill-Process

27 May 2020, 12:47

Nice, thank you . If you get the UWP thingy and regular updates, I will use it daily ^_^
-------------------------
KeyPress OSD v4: GitHub or forum. (presentation video)
Quick Picto Viewer: GitHub or forum.
AHK GDI+ expanded / compilation library (on GitHub)
My home page.
WOlfen
Posts: 61
Joined: 14 Jan 2018, 16:48

Re: [Script] Task Manager with Filter and Multi-Kill-Process

27 May 2020, 15:41

fenchai wrote:
27 May 2020, 12:40
You can Activate it by just running it. I haven't set a hotkey for it. But once open it stays on the tray menu so you can double click it to show again.
edit if GUI not showing, delete the the .ini file, because I use multiple monitors, the coordinates are off the charts
Thank you, that was it.
I really love this.
It´s great that you made it opensource. But still, i have some questions:
- Is there a Button to end a Process like in Windows Task Manager (with delete key)?
- Could you make a feature into it that it shows multiple Processes as a single Process as an option (so instead 16 chrome.exe having only 1)?
- It seems that the Window saves the Position, but not the Size
- Maybe making it more dark? :)
I will take a look into it also myself. Thank you very much again.
fenchai
Posts: 292
Joined: 28 Mar 2016, 07:57

Re: [Script] Task Manager with Filter and Multi-Kill-Process

27 May 2020, 19:57

WOlfen wrote:
27 May 2020, 15:41
fenchai wrote:
27 May 2020, 12:40
You can Activate it by just running it. I haven't set a hotkey for it. But once open it stays on the tray menu so you can double click it to show again.
edit if GUI not showing, delete the the .ini file, because I use multiple monitors, the coordinates are off the charts
Thank you, that was it.
I really love this.
It´s great that you made it opensource. But still, i have some questions:
- Is there a Button to end a Process like in Windows Task Manager (with delete key)?
- Could you make a feature into it that it shows multiple Processes as a single Process as an option (so instead 16 chrome.exe having only 1)?
- It seems that the Window saves the Position, but not the Size
- Maybe making it more dark? :)
I will take a look into it also myself. Thank you very much again.
- Sure, DEL key added as killer
- This can be done as a hack, but ahk currently does not support tree view inside a ListView.
- mmm I can see it working perfectly, the thing is, I have only set to save window positions when user presses ESC or Closes the Window and not if user Exits App. Maybe I should add that function.
- I have no interest on themes atm but it should be very easily done manually.
fenchai
Posts: 292
Joined: 28 Mar 2016, 07:57

Re: [Script] Task Manager with Filter and Multi-Kill-Process

27 May 2020, 20:05

robodesign wrote:
27 May 2020, 12:47
Nice, thank you . If you get the UWP thingy and regular updates, I will use it daily ^_^
I am not sure how to deal with the UWP thing, what do you need from it? or is it that it does not show on the list?
User avatar
Delta Pythagorean
Posts: 627
Joined: 13 Feb 2017, 13:44
Location: Somewhere in the US
Contact:

Re: [Script] Task Manager with Filter and Multi-Kill-Process

27 May 2020, 22:16

Just to be clear, what problem could Microsoft not fix?

[AHK]......: v2.0.12 | 64-bit
[OS].......: Windows 11 | 23H2 (OS Build: 22621.3296)
[GITHUB]...: github.com/DelPyth
[PAYPAL]...: paypal.me/DelPyth
[DISCORD]..: tophatcat

robodesign
Posts: 934
Joined: 30 Sep 2017, 03:59
Location: Romania
Contact:

Re: [Script] Task Manager with Filter and Multi-Kill-Process

28 May 2020, 02:48

fenchai wrote:
27 May 2020, 20:05
robodesign wrote:
27 May 2020, 12:47
Nice, thank you . If you get the UWP thingy and regular updates, I will use it daily ^_^
I am not sure how to deal with the UWP thing, what do you need from it? or is it that it does not show on the list?
Just list the uwp applications, individually. And when I choose one of these to kill, to work.

Best regards, Marius.
-------------------------
KeyPress OSD v4: GitHub or forum. (presentation video)
Quick Picto Viewer: GitHub or forum.
AHK GDI+ expanded / compilation library (on GitHub)
My home page.
User avatar
DataLife
Posts: 445
Joined: 29 Sep 2013, 19:52

Re: [Script] Task Manager with Filter and Multi-Kill-Process

28 May 2020, 06:03

Very nice...

unicode? ansi? Does this support both?

I like the filter, very useful.
Check out my scripts. (MyIpChanger) (ClipBoard Manager) (SavePictureAs)
All my scripts are tested on Windows 10, AutoHotkey 32 bit Ansi unless otherwise stated.
fenchai
Posts: 292
Joined: 28 Mar 2016, 07:57

Re: [Script] Task Manager with Filter and Multi-Kill-Process

28 May 2020, 16:02

Delta Pythagorean wrote:
27 May 2020, 22:16
Just to be clear, what problem could Microsoft not fix?
Task Manager: Ability to Filter, Multi-Kill it's in the title.
DataLife wrote:
28 May 2020, 06:03
Very nice...

unicode? ansi? Does this support both?

I like the filter, very useful.
No Idea, only one way to test. Try and See hahaha. I used AHK x64 and win10. I don't see why it won't work on either.
hasantr
Posts: 933
Joined: 05 Apr 2016, 14:18
Location: İstanbul

Re: [Script] Task Manager with Filter and Multi-Kill-Process

29 May 2020, 12:07

This is beautiful. You must add a context menu.
And launch the interface must have Shortcut to hide it.
The option to restart the selected application must be added.
Sometimes, like "Game Boosters", there may also be support for terminating process stacks.
fenchai
Posts: 292
Joined: 28 Mar 2016, 07:57

Re: [Script] Task Manager with Filter and Multi-Kill-Process

30 May 2020, 21:45

hasantr wrote:
29 May 2020, 12:07
This is beautiful. You must add a context menu.
And launch the interface must have Shortcut to hide it.
The option to restart the selected application must be added.
Sometimes, like "Game Boosters", there may also be support for terminating process stacks.
Context Menu Added 👍
Shortcut to hide is just pressing ESC, hides into tray
restart a process? mmm I don't see how useful it is but by restart is the same as running it again? or kill and run again?
hasantr
Posts: 933
Joined: 05 Apr 2016, 14:18
Location: İstanbul

Re: [Script] Task Manager with Filter and Multi-Kill-Process

31 May 2020, 03:31

fenchai wrote:
30 May 2020, 21:45
hasantr wrote:
29 May 2020, 12:07
This is beautiful. You must add a context menu.
And launch the interface must have Shortcut to hide it.
The option to restart the selected application must be added.
Sometimes, like "Game Boosters", there may also be support for terminating process stacks.
Context Menu Added 👍
Shortcut to hide is just pressing ESC, hides into tray
restart a process? mmm I don't see how useful it is but by restart is the same as running it again? or kill and run again?
Thanks.
For example, Explorer.exe is a frequently crashed and restarted process. Having only the terminate option means we will have to restart again.
fenchai
Posts: 292
Joined: 28 Mar 2016, 07:57

Re: [Script] Task Manager with Filter and Multi-Kill-Process

31 May 2020, 13:43

done, added restart to r-click menu along with a bunch more UI improvements
robodesign
Posts: 934
Joined: 30 Sep 2017, 03:59
Location: Romania
Contact:

Re: [Script] Task Manager with Filter and Multi-Kill-Process

01 Jun 2020, 11:51

I get Continuable Exception Access Violation error on line 397.....

Any idea why?

Best regards, Marius.
-------------------------
KeyPress OSD v4: GitHub or forum. (presentation video)
Quick Picto Viewer: GitHub or forum.
AHK GDI+ expanded / compilation library (on GitHub)
My home page.
fenchai
Posts: 292
Joined: 28 Mar 2016, 07:57

Re: [Script] Task Manager with Filter and Multi-Kill-Process

02 Jun 2020, 13:18

robodesign wrote:
01 Jun 2020, 11:51
I get Continuable Exception Access Violation error on line 397.....

Any idea why?

Best regards, Marius.
Is that by running as admin? I haven't tested much admin mode. Also Make sure you are on the lastest version.

Return to “Scripts and Functions (v1)”

Who is online

Users browsing this forum: gwarble and 113 guests