COM Object Reference

[joedf]

Interesting..

[Menixator]

Related: Automating Foobar Using COM

[kon]

A remake of the index.

Index

COM Object List

• ActiveX Data Objects (ADODB.Connection and Others)
  Work with a variety of databases, such as CSV, Excel xls, and Access mdb.
• HTML File
  Represents an HTML document. Can be used to read, write, and interact with HTML.
• InternetExplorer Application
  Explore websites.
• MSXML2 DOMDocument 6.0
  XML parser. (v6.0 requires XP SP3 or newer. See here for compatibility with older XP.)
  • Format XML Output
• Msxml2.XMLHTTP
  Makes HTTP requests. Unlike UrlDownloadToFile, it doesn't require managing a temporary file. Unlike WinHttpRequest, it can notify us when the request is complete.
• ScriptControl
  Dynamically execute VBScript or JScript.
• Scripting Dictionary
  Object that stores data key-item pairs.
• Scripting FileSystemObject
  Access files and folders.
• Shell Application
  Access Explorer and IE windows and tabs. Open and manipulate windows.
  • Get File Properties
  • Get the Path of a Selected File
  • Rename Files/Folders
  • Unzip a Zip File
• Shell Explorer
  Embed an Explorer/browser control in a Gui. (Internet Explorer - Trident Browser)
• Speech API: SpVoice
  Text to speech. (TTS)
• VBScript RegExp
  VBS regular expressions, including global match.
• Windows Media Player
  Play media files and embed a WMPlayer control in a GUI.
• WinHttpRequest
  Provides simple HTTP client functionality, allowing much more control than UrlDownloadToFile.
• Winmgmt
  Get system information and manage windows services.
  • Get File Properties
  • Manipulating Services
• WScript Shell
  Various administration tasks including many native to AHK.
  • Set Volatile Env Variable

MS Office Applications

• MS Excel
  Perform calculations, analyze information, and visualize data in spreadsheets.
  • SafeArray and Range
  • Excel Workbook
    Hold MS Excel data.
• MS Outlook
  Personal information manager.
  • Access Folders and Items
  • Create New Items
  • Send Email With Attachments
• MS PowerPoint
  Create Powerpoint presentations.
• MS Publisher
  A desktop publishing application with emphasis placed on page layout and design.
• MS Word
  Word processor: create and edit various documents.

Objects Requiring Additional Files/Installation (See also - Register ActiveX Component.)

• Ahk.ComSurrogate.32/64
  Create COM objects of a specified bitness.
• CAPICOM Series [capicom_dc_sdk.msi]
  Digitally sign data, sign code, verify digital signatures, envelop data for privacy, hash data, encrypt/decrypt data and more. (32-bit OS only.)
• Google Desktop [Discontinued]
  Add gadgets to your desktop and easily search your computer like Google.
• GFLAx [GflAx.dll - 1.11 MB]
  Library to load images and photos easily. Read, write, create, and manipulate images, and more.
• ImageMagick [Install]
  Software suite to create, edit, and compose bitmap images. (See here for notes on installation.)
• Windows Image Acquisition (WIA) Automation [WIAAut.dll - 316 KB]
  Acquire images on digital cameras, scanners, and web cameras. Rotate, scale, and annotate image files. (See note regarding WPD Automation Object Model.)
• XStandard.Zip [XZip.dll - 137 KB]
  Zip and unzip with many features.

[kon]

COM Object: Publisher.Application
Purpose: Microsoft Publisher is an entry-level desktop publishing application from Microsoft, differing from Microsoft Word in that the emphasis is placed on page layout and design rather than text composition and proofing.
System Requirements: Microsoft Office Publisher
Documentation Link: Object model reference (Publisher 2013 developer reference)
Other Links: Save the active document as .jpg
Basic Code Example: This example will open Publisher, create a new document, draw a curve and a line, add some text, and SaveAs with two different formats (.jpg and .pub).

Code: Select all

; Constants
msoTrue := -1
pbPictureResolutionCommercialPrint_300dpi := 3
pbTextOrientationHorizontal := 1
VT_R4 := 4  ; 32-bit floating-point number

pbApp := ComObjCreate("Publisher.Application")      ; Create a Publisher application object and store a reference to it in the pbApp variable
pbApp.ActiveWindow.Visible := true                  ; Make the window visible

; Application.NewDocument Method (Publisher)
; http://msdn.microsoft.com/en-us/library/office/ff940013%28v=office.15%29.aspx
pbDoc := pbApp.NewDocument()                        ; Create a new document and store a reference to the object in the pbDoc variable

; Shapes Methods (Publisher)
; http://msdn.microsoft.com/en-us/library/office/dn338310%28v=office.15%29.aspx
pbDoc.Pages(1).Shapes.AddLine(100, 150, 500, 550)   ; Draw a line from the point (100, 150) to point (500, 550)

; Shapes.AddCurve Method (Publisher)
; http://msdn.microsoft.com/en-us/library/office/ff939838%28v=office.15%29.aspx
arrPoints := ComObjArray(VT_R4, 4, 2)
arrPoints[0, 0] := 100
arrPoints[0, 1] := 150
arrPoints[1, 0] := 240
arrPoints[1, 1] := 600
arrPoints[2, 0] := 370
arrPoints[2, 1] := 100
arrPoints[3, 0] := 500
arrPoints[3, 1] := 550
pbDoc.Pages(1).Shapes.AddCurve(arrPoints)           ; Draw a curve using the points specified by the array

; Shapes.AddTextbox Method (Publisher)
; http://msdn.microsoft.com/en-us/library/office/ff939294%28v=office.15%29.aspx
pbTextbox := pbDoc.Pages(1).Shapes.AddTextbox(pbTextOrientationHorizontal, 40, 60, 520, 65)  ; Create a textbox
; Story.TextRange Property (Publisher)
; http://msdn.microsoft.com/en-us/library/office/ff940334%28v=office.15%29.aspx
pbTextRange := pbTextbox.TextFrame.Story.TextRange  ; Store a reference to the range of text inside the textbox
pbTextRange.Text := "AutoHotkey is awesome!"
pbTextRange.Font.Bold := msoTrue
pbTextRange.Font.Size := 40
pbTextRange.Font.Name := "Arial"

; Page.SaveAsPicture Method (Publisher)
; http://msdn.microsoft.com/en-us/library/office/ff939984%28v=office.15%29.aspx
SavePath := A_ScriptDir "\MyTestFile.jpg"           ; Save the picture to the same directory as this script
pbDoc.Pages(1).SaveAsPicture(SavePath, pbPictureResolutionCommercialPrint_300dpi)

; Document.SaveAs Method (Publisher)
; http://msdn.microsoft.com/en-us/library/office/ff940221%28v=office.15%29.aspx
SavePath := A_ScriptDir "\MyTestDocument.pub"       ; Save the document to the same directory as this script
pbDoc.SaveAs(SavePath)
return

[GeekDude]

Wouldn't this be better suited to a GitHub repository or something along those lines? Perhaps under the AhkScript group?

[lexikos]

COM Object: Msxml2.XMLHTTP, a.k.a. XmlHttpRequest object.
Purpose: Making HTTP requests. Unlike UrlDownloadToFile, it doesn't require managing a temporary file. Unlike WinHttpRequest, it can notify us when the request is complete.
System Requirements: IE7+ and AutoHotkey v1.1.17+ to use onreadystatechange.
Documentation Link: XMLHttpRequest object
Basic Code Example:

Code: Select all

req := ComObjCreate("Msxml2.XMLHTTP")
; Open a request with async enabled.
req.open("GET", "https://autohotkey.com/download/1.1/version.txt", true)
; Set our callback function (v1.1.17+).
req.onreadystatechange := Func("Ready")
; Send the request.
req.send()
/*
; If you're going to wait, there's no need for onreadystatechange.
; Setting async=true and waiting like this allows the script to remain
; responsive while the download is taking place, whereas async=false
; will make the script unresponsive.
while req.readyState != 4
    sleep 100
*/
#Persistent

Ready() {
    global req
    if (req.readyState != 4)  ; Not done yet.
        return
    if (req.status == 200 || req.status == 304) ; OK.
        MsgBox % "Latest AutoHotkey version: " req.responseText
    else
        MsgBox 16,, % "Status " req.status
    ExitApp
}

I started looking into this because using WinHttpRequest in synchronous mode causes the script to hang until the request completes, but it turns out you can get around that by opening the request in asynchronous mode and calling WinHttpRequest.WaitForResponse(). The advantages of XMLHTTP are that the API is well known to many web developers, and the events (like onreadystatechange) are compatible with AutoHotkey.

[joedf]

Hello asynchronous downloads!

[Joe Glines]

Any idea what the maximum size that can be stored in this? I read through some of the documentation however I was playing around and was storing a lot more characters than what I saw in the documentation.

COM Object: WScript.Shell
Purpose: Exchange variables between scripts
System Requirements: General
Documentation Link: WshEnvironment Object
Other Links: Environment Variables

[Joe Glines]

Any idea what the maximum size that can be stored in this? I read through some of the documentation however I was playing around and was storing a lot more characters than what I saw in the documentation.

I reached a max of 524,285 charchters on my 64 bit version of Windows 7

[guesto]

COM Object: ImageMagickObject COM+ Object
Purpose: ImageMagick® is a software suite to create, edit, and compose bitmap images.
System Requirements: ImageMagickObject COM+ Object
Documentation Link:
Other Links: http://www.imagemagick.org/script/binar ... hp#windows
Basic Code Example:

I have installed ImageMagick with the COM option in the installer (the checkbox about VBS something, don't remember exactly). I can run the ImageMagickObject .vbs test script that comes with ImageMagick. But I can't get it to work in AHK. The sample script generated "Invalid class string" error on this line

Code: Select all

oI :=	ComObjCreate("ImageMagickObject.MagickImage.1")