[solved] 7-zip dll in AHK

[Masonjar13]

I'm less than decent with dlls, but I'm in need of a dll to replace 7za.exe (command-line 7-Zip). I'm currently trying to use SevenZipSharp.dll with the following test script, with both the test archive and dll in the same directory as the script.

Code: Select all

sevPrc:=dllCall("LoadLibrary","Str","SevenZipSharp.dll","Ptr")
dllCall("SevenZipSharp\SevenZipExtractor",str,"wast.7z",str,"1") ; class constr - SevenZipExtractor(string file,string password)
dllCall("SevenZipSharp.dll\BeginExtractArchive",str,a_scriptdir) ; func - void BeginExtractArchive(string dir)
dllCall("FreeLibrary","Ptr",sevPrc)

I figured this wouldn't work, and it didn't, as the function is a member of a class (SevenZipExtractor). I'm not sure how to instantiate a class and call it's member in ahk, though. Line 2 and 3 both give me ErrorLevel -4. The process is being loaded, as it's ErrorLevel returns 0 and Process Explorer can find it attached to the script while running. There also, unfortunately, isn't a return value; I need to be able to tell if it was successfully extracted or not (maybe Check()?). For convenience, I've attached the help file for the dll.

[jigga]

Maybe try ExtractArchive(String) instead of BeginExtractArchive? I think the function you are using is meant to be asynchronous.

[Masonjar13]

Well, one thing at a time. First, I need to create the object of the class to be able to access either of those two functions. I don't know how to do that from a dll though.

[jigga]

errorlevel -4 means the function could not be found. If it was a permission/path issue it would return errorlevel -3 or N where N is a positive number. I'm not super familiar with DLL stuff though, so idk lol.

[HotKeyIt]

I think you could use it with .NET Framework Interop.

There is also 7-zip32.dll, it's a different dll/project and it works via DllCall.

[LinearSpoon]

Assuming you got the dll from here: https://sevenzipsharp.codeplex.com/
I've looked at it and it doesn't seem to export any functions at all. At least, not in the way DllCall wants them.

I don't know how easy it would be to get it working; I can't find an example of how to use a C# dll that doesn't involve "add a reference to it in visual studio". The actual 7-zip dll has some functions available, but the example provided in the source is too long for me to figure out how to use it in a reasonable amount of time.

Other than continuing to use the command line version, HotKeyIt's post looks most promising (though it probably won't work on 64 bit AHK).

[HotKeyIt]

7-zip64.dll can be found here

[Masonjar13]

I actually have 7-zip32.dll, but I couldn't find support for using a password. Is that what DWORD _dwMode is suppose to be for (presuming SevenZipOpenArchive is the function I should be looking at)?

[Masonjar13]

Got it (stole a function from shajul's library)

Code: Select all

sevPrc:=dllCall("LoadLibrary","Str","7-zip32.dll","Ptr")
file:="wast.7z",pass:=1
7Zip__SevenZip("e """ file """ -p" pass " -y")

dllCall("FreeLibrary","Ptr",sevProc)
exitapp

7Zip__SevenZip(sCommand) {
  nSize := 32768
  VarSetCapacity(tOutBuffer,nSize)
  aRet := DllCall("7-zip32\SevenZip", "Ptr", hWnd
          ,"AStr", sCommand
          ,"Ptr", &tOutBuffer
          ,"Int", nSize)
  If !ErrorLevel
    return StrGet(&tOutBuffer,nSize,"CP0"), ErrorLevel := aRet
  else
    return 0
}

Now, can I make this not show a visible window?

[HotKeyIt]

Use -hide option.

[Masonjar13]

Use -hide option.

That was painfully obvious.. It makes my mouse twitch a bit, but it will do.

Much appreciation to all replies.

[Masonjar13]

Following the suggested methods in the help, I've loaded the library and then got the handle of the function to use directly. Besides that, how can I make it any faster?

Current environment demonstration:

Code: Select all

SetBatchLines -1
Process,Priority,,H
sevPrc:=dllCall("LoadLibrary","Str",tmp "\7-zip64.dll","Ptr")
global sevProc := dllCall("GetProcAddress","Ptr",sevPrc,"AStr","SevenZip","Ptr")

Currently averages at 69ms. If I can get it at atleast below 50ms, it should be okay, but I'd prefer much lower if possible. Any additional code isn't relative as the timings only covered the dll function call. Using Winmm\time[Begin/End]Period doesn't seem to make a difference.

[HotKeyIt]

Can you post the code you used for timings?

[Masonjar13]

Sure. Just use any supported archive with a password that isn't numeric and this'll work just fine.

Code: Select all

#SingleInstance Force
#Persistent
SetBatchLines -1
Process,Priority,,H
sevPrc:=dllCall("LoadLibrary","Str","7-zip64.dll","Ptr")
global sevProc := dllCall("GetProcAddress","Ptr",sevPrc,"AStr","SevenZip","Ptr")
cnt:=100,file:="test.7z"
global dlltme

timing:=a_tickcount
Loop % cnt
    7ZipCLine("e """ file """ -p" a_index " -y -hide")
timing:=a_tickcount - timing
msgbox % "Timing: " timing " Average: " timing//cnt "`nDll timing: " dlltme " Average: " dlltme//cnt
dllCall("FreeLibrary","Ptr",sevPrc)
exitapp

7ZipCLine(sCommand) {
;    DllCall("Winmm\timeBeginPeriod", uint, 3)
    nSize := 32768
    VarSetCapacity(tOutBuffer,nSize)
    tme:=a_tickcount
    aRet := dllCall(sevProc, "Ptr", hWnd,"AStr", sCommand,"Ptr", &tOutBuffer,"Int", nSize)
    dlltme+=a_tickcount - tme
;    DllCall("Winmm\timeEndPeriod", UInt, 3)
    if(!ErrorLevel)
        return ErrorLevel := aRet
    return 0
}

[jigga]

You could always buy a beastly mac pro and run windows on it. The programmer at my work bought the stock version and runs windows in VM. It out performs my new high end gaming PC by a large margin :\

[HotKeyIt]

Try this:

Code: Select all

#SingleInstance Force
#Persistent
SetBatchLines -1
Process,Priority,,H
global sevProc:=dllCall("GetProcAddress","Ptr",dllCall("LoadLibrary","Str","7-zip64.dll","Ptr"),"AStr","SevenZip","Ptr")
cnt:=100,file:="test.7z",timing:=a_tickcount
Loop % cnt
    dllCall(sevProc, "Ptr", A_ScriptHwnd,"AStr"
        ; command line
        , "e """ file """ -p" a_index " -y -hide"
        ,"Ptr", 0,"Int", 0)
timing:=a_tickcount - timing
msgbox % "Timing: " timing " Average: " timing//cnt "`nDll timing: " dlltme " Average: " dlltme//cnt
exitapp

[Masonjar13]

You could always buy a beastly mac pro and run windows on it. The programmer at my work bought the stock version and runs windows in VM. It out performs my new high end gaming PC by a large margin :\

Never. I have not and will not purchase an Apple product, under any circumstance.

I'm running an i7-4820k at 4.3GHz, with 16GB RAM at 2.4GHz. Those are both at safe, standard-usage clocks.

[Masonjar13]

Try this

Little to no difference. Notes: running in real-time seems to make it slower (?), upon doubling the iterations, it becomes slightly slower (both versions).

[jigga]

You could always buy a beastly mac pro and run windows on it. The programmer at my work bought the stock version and runs windows in VM. It out performs my new high end gaming PC by a large margin :\

Never. I have not and will not purchase an Apple product, under any circumstance.

I'm running an i7-4820k at 4.3GHz, with 16GB RAM at 2.4GHz. Those are both at safe, standard-usage clocks.

I hate apple as well, but that machine is just a beast. Of course it costs the same as 4 of my cars :\

[zotune]

Try this:

Code: Select all

#SingleInstance Force
#Persistent
SetBatchLines -1
Process,Priority,,H
global sevProc:=dllCall("GetProcAddress","Ptr",dllCall("LoadLibrary","Str","7-zip64.dll","Ptr"),"AStr","SevenZip","Ptr")
cnt:=100,file:="test.7z",timing:=a_tickcount
Loop % cnt
    dllCall(sevProc, "Ptr", A_ScriptHwnd,"AStr"
        ; command line
        , "e """ file """ -p" a_index " -y -hide"
        ,"Ptr", 0,"Int", 0)
timing:=a_tickcount - timing
msgbox % "Timing: " timing " Average: " timing//cnt "`nDll timing: " dlltme " Average: " dlltme//cnt
exitapp

Does this work to extract a file? I can't seem to get it to work.
Also, do you by any chance have an example for compressing a file with ultra compression?