Error trying to download the V1 and V2 files with current version number

[joedf]

I feel that... 99% of my stuff is still v1.1

[lmstearn]

All the files e.g this one won't work with URLDownloadToFile.
https://www.autohotkey.com/assets/images/ahk_wallpaper_reduced.jpg
Think it's related to this issue with the challenge pages from Cloudflare, one way around it might be a different user agent.

[tank]

I havent forgotten this. I even tried with the autohotkey user agent in postman and it worked fine. For the life of me I cannot tell what it is. unless this is something much lower level like how AHK actually impliments under the hood that is now being subverted by OS. but thats pretty difficult to accept.

[joedf]

@lexikos Any ideas? We're not sure if it's the server configs or if it's AHK...

[JoeWinograd]

Hi @tank and @joedf,
Thanks for your continuing efforts on this...much appreciated! Hopefully, @lexikos can provide some ideas to help resolve the problem. Regards, Joe

[lexikos]

What would I know? Download just uses a few Internet functions from wininet, as anyone can see.

[Descolada]

This problem affects the download prompt caused by #Requires AutoHotkey ... as well, which fails with error "Download failed."

The failure is caused by InternetOpenUrl which fails with error ERROR_INTERNET_CLIENT_AUTH_CERT_NEEDED, so it appears there is some kind of problem with the certificate.
Downloading via a GET request with Msxml2.XMLHTTP doesn't seem to be affected.

[TAC109]

I’m also having problems using UrlDownloadToFile on https://www.autohotkey.com/mpress/mpress.219.zip, used in the Ahk2Exe Updater.

I’ve since made changes to the Ahk2Exe Updater to avoid this problem. Mpress is now downloaded from GitHub.

Cheers

[JoeWinograd]

Downloading via a GET request with Msxml2.XMLHTTP doesn't seem to be affected.

Hi Descolada,
Could you post a V1 and/or V2 code snippet with that method? Thanks much, Joe

[Descolada]

@JoeWinograd
If you only need the version number without downloading a file:

Code: Select all

req := ComObject("Msxml2.XMLHTTP")
req.open("GET", "https://www.autohotkey.com/download/2.0/version.txt", 0)
req.send()

if req.status == 200
  MsgBox "AHK 2.0 version: " req.responseText
else
  MsgBox "Failed to get AHK version"

Download to file (variant 1):

Code: Select all

DownloadURL("https://www.autohotkey.com/download/2.1/AutoHotkey_2.1-alpha.12_setup.exe")
ExitApp

DownloadURL(url, filename?) {
    local oStream, req := ComObject("Msxml2.XMLHTTP")
    req.open("GET", url, true)
    req.send()
    while req.readyState != 4
        Sleep 100

    if req.status == 200 {
        oStream := ComObject("ADODB.Stream")
        oStream.Open()
        oStream.Type := 1
        oStream.Write(req.responseBody)
        oStream.SaveToFile(filename ?? StrSplit(url, "/")[-1], 2)
        oStream.Close()
    } else
        throw Error("Download failed",, url)
}

Download to file (variant 2):

Code: Select all

DownloadURL("https://www.autohotkey.com/download/2.1/AutoHotkey_2.1-alpha.12_setup.exe")
ExitApp

DownloadURL(url, filename?) {
    local f, req := ComObject("Msxml2.XMLHTTP")
    req.open("GET", url, true)
    req.send()
    while req.readyState != 4
        Sleep 100

    if req.status == 200 {
        f := FileOpen(filename ?? StrSplit(url, "/")[-1], "w")
        f.RawWrite(NumGet(req.responseBody.ptr + 8 + A_PtrSize, "ptr"), req.responseBody.MaxIndex()+1)
        f.Close()
    } else
        throw Error("Download failed",, url)
}

EDIT: improved variant 2 speed.

[lexikos]

The failure is caused by InternetOpenUrl which fails with error ERROR_INTERNET_CLIENT_AUTH_CERT_NEEDED, so it appears there is some kind of problem with the certificate.

That error means "The server is requesting client authentication." as in "give me a certificate that proves your identity". Apparently, if the server does not require authentication but requests it, you must send the request again with the same handles to "authenticate" anonymously.

[joedf]

For reference: https://learn.microsoft.com/en-us/windows/win32/api/wininet/nf-wininet-interneterrordlg#parameters

[Descolada]

@lexikos can confirm, changing script_autoit.cpp from

Code: Select all

	// Open the required URL
	HINTERNET hFile = InternetOpenUrl(hInet, aURL, NULL, 0, flags_for_open_url, 0);
	if (!hFile)
	{
		DWORD last_error = GetLastError(); // Save this before calling InternetCloseHandle, otherwise it is set to 0.
		InternetCloseHandle(hInet);
		return FR_E_WIN32(last_error);
	}

to

Code: Select all

	// Open the required URL
	HINTERNET hFile = InternetOpenUrl(hInet, aURL, NULL, 0, flags_for_open_url, 0);
	if (!hFile)
	{
		hFile = InternetOpenUrl(hInet, aURL, NULL, 0, flags_for_open_url, 0);
		if (!hFile)
		{
			DWORD last_error = GetLastError(); // Save this before calling InternetCloseHandle, otherwise it is set to 0.
			InternetCloseHandle(hInet);
			return FR_E_WIN32(last_error);
		}
	}

fixes the issue.

[joedf]

Thanks for figuring this out @Descolada

[JoeWinograd]

Hi @Descolada,
I can't speak to your fix of changing script_autoit.cpp, but I can say that your three scripts (version number without downloading a file, download variant 1, download variant 2) all work perfectly! Thank you very much for writing and posting them...I really appreciate it! Regards, Joe

[lexikos]

@Descolada When I tested yesterday, both the first and second call returned error 12044. Today it works.

[lexikos]

v2.0.16 implements the workaround for ERROR_INTERNET_CLIENT_AUTH_CERT_NEEDED.

[joedf]

v2.0.16 implements the workaround for ERROR_INTERNET_CLIENT_AUTH_CERT_NEEDED.

[Descolada]

@Descolada When I tested yesterday, both the first and second call returned error 12044. Today it works.

Now it doesn't work again, fails with error 12044. Weird...

EDIT: and it started working again. It failed in 2.0.16, then I installed 2.1-alpha.13 and it suddenly started working. I uninstalled 2.1-alpha.13 and went back to 2.0.16, it continued working (even after rebooting). I'm guessing there is some kind of issue remaining, but I have no clue what may be causing it.